ASMB,R,Q,C
      HED SPOPN ROUTINE 
*     NAME:   SPOPN 
*     SOURCE: 92067-18146 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS      *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM SPOPN,7 92067-16125 REV.1940 790802 
* 
*     CHANGE: 780413 TO MAKE CROSS MAP ACCESS OF MP1
*                    IF IN A DMS ENVIRONMENT. (GL 
* 
      ENT SPOPN 
* 
      EXT .ENTR,EXEC,$OPSY
* 
*  THE FOLLOWING ROUTINE DOES A SETUP REQUEST 
*  TO THE SMP AND PASSES THE BUFFER TO IT.
* 
BUFFR BSS 1 
LUNO  BSS 1 
* 
SPOPN NOP 
      JSB .ENTR 
      DEF BUFFR 
      LDA BUFFR 
      STA BUFR
      CLA 
      STA CLASS 
      JSB EXEC      ALLOCATE CLASS NUMBER 
      DEF *+8 
      DEF D20 
      DEF ZERO
BUFR  BSS 1 
      DEF D16 
      DEF ZERO
      DEF ZERO
      DEF CLASS 
      LDA BUFFR,I 
      SZA 
      LDA B1717 
      STA BCHK
      JSB EXEC      SCHEDULE SMP TO SET UP SPOOL FILE 
      DEF *+6 
      DEF DS23
      DEF SMPA
      DEF ZERO
      DEF CLASS 
      DEF BCHK
      JMP ERM48     SMP PROGRAM NOT FOUND 
* 
      LDA $OPSY     FETCH OP SYS IDENT            *780413*
      ARS           POSITION DMS BIT TO BIT 0     *780413*
      SLA,RSS       IF BIT 1 CLEAR (NOT DMS)      *780413*
      JMP NDMS         DO A STRAIGHT LOAD         *780413*
* 
      XLA B,I       ELSE, DO A CROSS MAP LOAD     *780413*
      RSS              TO FETCH RTN PARM          *780413*
NDMS  LDA B,I       FETCH RETURN PARM FROM SMP    *780413*
* 
SPOEX STA LUNO,I
      JMP SPOPN,I 
* 
ERM48 LDA M48       NO SPOOL FILES AVAILABLE
      JMP SPOEX     EXIT
* 
ZERO  DEC 0 
DS23  OCT 100027
D16   DEC 16
D20   DEC 20
M48   DEC -48 
B1717 EQU 1717B 
CLASS BSS 1 
BCHK  BSS 1 
SMPA  ASC 3,SMP 
B     EQU 1 
* 
      END 
                                                                                                                                          