ASMB,R,L,C
      HED POST - CLEAR THE DCB BUFFER 
*     NAME:   POST
*     SOURCE: 92067-18138 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM POST,7 92067-16125 REV.1903 740801
      ENT POST
      EXT .ENTR,R/W$
* 
* 
*     THE POST ROUTINE CLEARS THE DCB BUFFER BY POSTING ANY 
*     DATA THAT NEEDS TO BE WRITTEN ON THE DISC.  IT WILL IN
*     ALL CASES CLEAR THE INCORE FLAG SO THE NEXT FILE
*     ACCESS WILL FOURCE A DISC READ. 
* 
*     POST IS TO BE USE WITH THE RN LOCK FEATURE AS 
*     FOLLOWS:
* 
*     POST
*     LOCK
* 
*     DO YOUR THING 
* 
*     POST
*     UNLOCK
* 
*     CALLING SEQUENCE: 
* 
*     CALL POST(DCB,ER) 
* 
*     WHERE:
* 
*     DCB IS THE DCB ARRAY
*     ER  IS THE OPTIONAL RETURN ERROR CODE 
* 
DCB   NOP 
ER    NOP 
POST  NOP           ENTRY POINT 
      JSB .ENTR     GET THE PRAM ADDRESSES
      DEF DCB 
      LDB DCB       CHECK 
      ADB D9        THAT THE DCB
      LDA B,I       IS OPEN 
      CPA XEQT      YES?
      JMP OK        YES!
* 
      LDA N11       NO   RETURN ERROR 
EREX  STA ER,I      SET THE ERROR CODE
      CLB           SET ER ADDRESS
      STB ER        FOR NEXT TIME 
      JMP POST,I    EXIT
* 
OK    LDB DCB       GET THE DCB ADDRESS 
      CLE           SET E FOR WRITE 
      JSB R/W$      GO POST THE BUFFER
      JMP EREX      DISC ERROR GO EXIT
* 
      CLA           ALL IS GOOD SET OK ERROR CODE 
      JMP EREX      AND GO EXIT 
* 
D9    DEC 9 
N11   DEC -11 
XEQT  EQU 1717B 
A     EQU 0 
B     EQU 1 
      END 
                                                              