ASMB,R,L,C,Q
*     NAME:   .CACT 
*     SOURCE: 92067-18089 
*     RELPC:  92067-16125 
*     PGMR:   G.L.M 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM .CACT,7 92067-16125 REV.1903 780921 
* 
* 
* 
      ENT .CACT 
* 
      EXT $DSCS,ISMVE,$SMD# 
* 
* 
A     EQU 0 
B     EQU 1 
XEQT  EQU 1717B 
* 
* 
*  PURPOSE: RETURN DIRECTORY ENTRY # OF CURRENT SESSION 
* 
* 
* 
*  CALLING SEQUENCE: JSB .CACT
*            RTN (A) 0= NOT IN SESSION
*                   >0= DIRECTORY ENTRY # 
*                   -1= SESSION NOT INSTALLED OR INITIALIZED
*                   -2= SESSION IN SHUTDOWN MODE
* 
* 
      SPC 5 
.CACT NOP 
      LDA $DSCS     FETCH STATUS FLAG 
      SSA           IF NEGATIVE,
      JMP .CACT,I   RETURN BAD STATUS FOUND 
* 
      LDA XEQT      FETCH MY ID ADDR
      ADA D32       ADVANCE TO SESSION POINTER
      XLB A,I       FETCH IT
      CLA           PRESET FOR NOT IN SESSION RETURN
      SZB 
      SSB           IF NOT SESSION
      JMP .CACT,I   RETURN (A)=0
* 
      STB TMP       SAVE SESSION POINTER
* 
      JSB ISMVE 
      DEF IRTN
      DEF TMP       FROM LOCATION DEFINED BY TMP
      DEF $SMD#     WITH THIS OFFSET
      DEF TMP       PUT VALUE HERE
      DEF .1        MOVE ONE WORD 
IRTN  EQU * 
* 
      LDA TMP       FETCH DIRECTORY ENTRY NUMBER
      JMP .CACT,I   RETURN
* 
D32   DEC 32
TMP   NOP 
.1    DEC 1 
* 
      END 
                                                                                                                                                                                                                                        