ASMB,R,L,C   ** EMAST **
      HED EMAST ROUTINE RETURNS INFORMATION OF AN EMA 
*     SOURCE: 92067-18061 
*     RELOC:  PART OF 92067-16035 
*     PGMR:   S.P.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
      NAM EMAST,7 92067-16035 REV.1805 770913 
      ENT EMAST 
* 
* 
*  ROUTINE TO GIVE INFORMATION FOR AN EMA PROGRAM 
*  CALLING SEQUENCE:  JSB EMAST 
*                     DEF *+4      RETURN  ADDRESS
*                     DEF NEMA     SIZE OF EMA
*                     DEF NMSEG    SIZE OF MSEG 
*                     DEF IMSEG    START LOGICAL PAGE MSEG
*  RETURNS: 
*           A REG = 0 IF NORMAL RETURN
*                 =-1 IF ERROR RETURN 
*           ERROR RETURN IS MADE IF CALLING PROGRAM DOES NOT
*           HAVE AN EMA DEFINED 
* 
* 
* 
EMAST NOP 
      LDA EMAST,I 
      STA RETRN     SAVE RETURN ADDRESS 
      LDA XIDEX     EMA PROGRAM?
      SZA,RSS 
      JMP ERROR     NO THEN ERROR 
* 
      LDA XEQT      YES 
      ADA .28       GET WORD 28 OF THE ID SEG 
      XLA A,I 
      AND B1777     MASK OUT EMA SIZE 
      JSB PRMST     STORE EMA SIZEL IN RETURN PARAMETER 
      XLA XIDEX,I   GET FIRST WORD OF ID SEG EXT
      AND B37       MASK MSEG SIZE
      JSB PRMST     STORE IT IN RETURN PARAMETERS 
      LDA XIDEX     ID SEG EXT ADDRESS
      INA 
      XLA A,I       GET SECOND WORD OF ID SEG EXT 
      ALF,RAL       MOVE START LG PAGE OF MSEG TO LOW BITS
      AND B37       MASK IT 
      JSB PRMST     STORE IT IFN RETURN PARAMETER 
      CLA,RSS       NORMAL RETURN 
ERROR CCA           ERROR RETURN A REG=-1 
      JMP RETRN,I   RETURN
* 
PRMST NOP           ROUTINE TO STORE VALUES INTO PARAMETERS 
      ISZ EMAST 
      LDB EMAST,I 
      STA B,I 
      JMP PRMST,I   RETURN
* 
RETRN NOP 
.28   DEC 28
B1777 OCT 1777
B37   OCT 37
A     EQU 0 
B     EQU 1 
XEQT  EQU 1717B 
XIDEX EQU 1645B 
      END 
                        