ASMB,R,L,C    ** LOGLU - RETURNS LU FROM $CON ENTRY POINT 
      HED - LOGLU - FIND LU THAT THIS PROGRAM ORIGINATED FROM.
*     NAME:   LOGLU 
*     SOURCE: 92064-18257 
*     RELOC:  92064-16081 
*     PGMR:   R.T.S.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LOGLU,7  92064-16081  REV.1940  790717
      ENT LOGLU 
      EXT $CON
* 
*     ROUTINE TO FIND THE LOGICAL UNIT NUMBER THAT THIS 
*     PROGRAM ORIGINATED FROM.
*          CALLED AS FOLLOWS: 
* 
* LU = LOGLU(IDUMY)           JSB LOGLU 
*                             DEF *+2 
*                             DEF IDUMY 
* 
* 
*    LU = A REG = LU #     OF LU AT WHICH 'RU'  OR  'ON' WAS ENTERED. 
*                          OR IF SCHEDULED BY A FATHER, THE LU AT WHICH 
*                          THE FATHER WAS SCHEDULED.
*               = 1        IF PROGRAM SCHEDULED BY INTERUPT OR TIME LIST
*         B REG = ASCII LU #
*         IDUMY = -1  SET TO NON-SESSION MODE SINCE RTE-M 
*                     DOES NOT SUPPORT SESSION MONITOR
* 
* 
LOGLU NOP           ENTRY 
      DLD LOGLU,I   GET RETURN ADDRESS & DUMMY ADDRESS
      STB DUMMY     SAVE DUMMY ADDRESS
      STA LOGLU     &RETURN ADDRESS 
      CCA           SO SET SESSION INDICATOR
      STB DUMMY,I   GIVE ANSWER TO CALLER 
* 
      SPC 1 
*************************************************************** 
*     SESSION MONITOR LU RETRIEVAL CODE TO BE INSERTED HERE   * 
*************************************************************** 
      SPC 1 
* 
      LDA $CON,I    .FETCH TERM LU #
      AND B77       .MASK OUT LU
      STA LU# 
* 
      CLB           .SET UP FOR INTEGER DIVIDE
      DIV D10       NOW CONVERT LU TO ASCII 
      ALF,ALF 
      ADB A 
      ADB ASC00     B = ASCII LU #
      LDA LU#       A = BINARY LU # 
      JMP LOGLU,I   RETURN
* 
* 
* 
D10   DEC 10
B77   OCT 77
DUMMY NOP 
LU#   NOP 
ASC00 ASC 1,00
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                                                                                                                              