ASMB,R,L,C    ** IFBRK ** 
      HED R/T IFBRK MODULE
*     NAME:   MIFBR 
*     SOURCE: 92064-18215 
*     RELOC:  92064-16081 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1975.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM MIFBR,7  92064-16081  REV.1709  741120
* 
      ENT IFBRK 
      EXT $LIBR,$LIBX 
      SPC 2 
*   CALLING SEQUENCE: 
* 
*     IF(IFBRK(IDMY)) 10,20 
* 
*   WHERE: 10  BRANCH WILL BE TAKEN IF SET & WILL CLEAR IT. 
*          20  BRANCH WILL BE TAKEN IF NOT SET
* 
*      JSB IFBRK
*      DEF *+1
*     <RETURN>   A-REG. = -1 IF SET, ELSE A-REG = 0 
*                BREAK BIT WILL ALWAYS BE CLEARED IF SET! 
      SPC 1 
IFBRK NOP          ENTRY FROM FTN 
      LDA IFBRK,I  GET P+1 ADDRESS
      STA IFBRK    SET RETURN ADDRESS 
      LDB XEQT     GET IDSEG ADDRESS OF THIS PROG 
      ADB D20      GET ID(21) ADDRESS 
      LDA B,I      GET CONTENTS 
      AND BIT12    MASK DOWN TO BIT 12
      SZA,RSS      SET? 
      JMP IFBRK,I  NO, RETURN A=0 
      JSB $LIBR    TURN OFF INTERRUPTS
      NOP 
      XOR B,I       YES, CLEAR IT 
      STA B,I      RESTORE WORD 21
      CCA          RETURN A-REG. = -1 
      JSB $LIBX 
      DEF IFBRK 
      SPC 1 
D20   DEC 20
BIT12 OCT 10000 
XEQT  EQU 1717B 
B     EQU 1 
      END 
                                                                                                                                              