ASMB,L,C
*     NAME  : PRMPT 
*     SOURCE: 92064-18094 
*     RELOC:  92064-16035 
*     PROGMR: E.J.W.  BASED ON RTE-III VERSIONS G.A.A.
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
       NAM PRMPT,1,10  92064-16035  REV.1650  761020  
       SUP PRESS ALL EXTRANEOUS  LISTING
       EXT EXEC,EQLU
A      EQU 0
B      EQU 1
* THIS INTERRUPT ROUTINE REPLACES (AUXTY IN RTE) WITH (PRMPT IN RTE II).
* IT IS SCHEDULED ON INTERRUPT BY DVR00 IF THAT TERMINAL HAS BEEN 
* PROPERLY ENABLED (ON,CNTRL,LU,20) 
* PRMPT : DETERMINES LU IN ASCII & BINARY 
*         OUTPUTS A ZERO LENGTH RECORD
*         OUTPUTS "LU>_"
*         REQUESTS A CLASS READ TO THE INTERRUPTING LU
*         SCHEDULES R$PN$,2,10 WITH :CLASS #,EQT4,LU,ASCII LU 
*                   W/O WAIT
*         TERMINATES,SAVING RESOURCES 
      SPC 2 
PRMPT EQU * 
      STB EQT4      SAVE INTERRUPTING DEVICE'S EQT WORD 4 ADDRESS 
      JSB EQLU      OBTAIN LU IN BINARY & ASCII 
      DEF *+1 
      SZA,RSS       FOUND ONE ? 
      JMP EXIT      NO,TERMINATE. 
      STA LU        YES,SAVE LU <BINARY>
      IOR B400      READY PRINT BACK
      STA RLU       SAVE READ LU + CNTRL IN RLU 
      STB ASCLU     SAVE ASCII LU 
      XOR B2500 
      STA CONWD 
      JSB EXEC
      DEF *+1+2 
      DEF D3
      DEF CONWD 
CRLF  JSB EXEC      RESPOND WITH
      DEF *+1+4      ZERO LENGTH RECORD 
      DEF DS2 
      DEF LU
      DEF BUFF
      DEF D0
      NOP 
PROMT JSB EXEC      RESPOND WITH
      DEF *+1+4      "LU>_" 
      DEF DS2 
      DEF LU
      DEF BUFF
      DEF D2
      NOP 
      SPC 1 
INPUT JSB EXEC      PERFORM CLASS I/O READ
      DEF *+1+7 
      DEF DS17
      DEF RLU 
      DEF * 
      DEF DM52
      DEF LU
      DEF EQT4
      DEF CLASS 
      NOP 
      SSA           ERROR RETURN? 
      JMP EXIT      YES-BEAT IT ! 
      SPC 1 
SCHED JSB EXEC      SCHEDULE R$PN$ W/O WAIT 
      DEF *+1+3 
      DEF D10 
      DEF R$PN$ 
      DEF CLASS 
* 
* IGNORE NOT SCHEDULED ERRORS SINCE R$PN$ IS CLASS GET SUSPENDED
* 
EXIT  JSB EXEC      TERMINATE 
      DEF *+1+3      & SAVE 
      DEF D6          RESOURCES 
      DEF D0
      DEF D1
      JMP PRMPT     RESTART HERE ON INTERRUPT 
      SPC 2 
EQT4  BSS 1 
LU    BSS 1 
B400  OCT 400 
B2500 OCT 2500
RLU   BSS 1 
DS2   OCT 100002
D2    OCT 2 
D3    DEC 3 
CONWD NOP 
BUFF  EQU * 
ASCLU ASC 2,00>_    PROMPT MESSAGE
D6    DEC 6 
D0    DEC 0 
D1    DEC 1 
CLASS NOP 
DM52  DEC -52 
D10   DEC 10
R$PN$ ASC 3,R$PN$ 
DS17  OCT 100021
EOP   EQU * 
      SPC 2 
      END PRMPT 
                                                                          