ASMB,R,L,C
*     NAME  : $MMES 
*     SOURCE: 92064-18016 
*     RELOC:  92064-16081 
*     PROGMR: E.J.W.
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM $MMES,7  92064-16081  REV.1940  790717
      ENT MESSS 
      EXT $LIBR,$LIBX,$MESS,.ENTP,$WORK,$PVCN 
* 
A     EQU 0 
B     EQU 1 
* 
BUFFR NOP 
LNGTH NOP 
P1    NOP           LU OF MTM TERMINAL
MESSS NOP 
      JSB $LIBR     GO PRIVILEGED 
CNTR  NOP 
      JSB .ENTP     GET PARAMETERS
       DEF BUFFR
      LDA MESSS 
      LDB HERE
      SZB           DON'T HANDLE MORE THAN ONE REQUEST
      JMP EXIT2      AT A TIME, IGNORE OTHERS TIL DONE
* 
THERE STA RTN 
      STA HERE
      LDA DEFEF 
      STA MESSS 
      CLA 
      STA $PVCN 
      LDA BUFFR 
      LDB LNGTH,I 
      JSB $MESS     PASS MESSAGE TO SYSTEM
      ISZ $PVCN 
      SZA,RSS       ANY MESSAGES RETURNED?
      JMP ONRU       NO, CHECK FOR SPECIAL COMMANDS 
* 
      LDB A,I        YES, PROCESS MESSAGE 
      STB LNGTH 
      BRS 
      STB CNTR
LOOP  INA 
      LDB A,I 
      STB BUFFR,I 
      ISZ BUFFR 
      ISZ CNTR
      JMP LOOP
* 
      LDA LNGTH 
EXIT  CLB           ALL DONE.  CLEAR MESSS BUSY FLAGS 
      STB HERE
      STB P1
EXIT1 JSB $LIBX     EXIT
DEF    DEF RTN
* 
RTN   NOP 
HERE  NOP 
DEFEF DEF DEF 
* 
ONRU  EQU * 
      LDA BUFFR,I   TEST FOR ON,RUN 
      CPA =AON      COMMANDS
      JMP DP1        TEST 1ST PRAM
      CPA =ARU
      JMP DP1 
      CPA =ALO      TEST ALSO FOR LO,PL 
      JMP DP2        TO SET UP MTM TABLE
      CPA =APL
      JMP DP2 
      JMP EXIT2      NEITHER RUN NOR ON-EXIT2 
* 
DP1   EQU * 
      LDB $WORK     GET ID SEG ADDR OF SCHEDULED PROG 
      INB 
      LDA B,I 
      SZA,RSS       IS FIRST PARAM = 0? 
      LDA P1,I       YES, FILL IN MTM LU
      STA B,I 
* 
DP2   LDB $WORK 
      ADB D28       SET UP MTM TABLE
      LDA B,I        AT ID SEG WORD 29
      AND C77       MERGE MTM LU
      IOR P1,I       INTO BITS 0-5
      STA B,I        KEEPING OTHERS UNCHANGED 
* 
EXIT2 CLA           ZERO OUT 'A' REG FOR RETURN 
      JMP EXIT
* 
D28   DEC 28
C77   OCT 177700
      END 
                                                                                                                                                                                                                                                              