ASMB
      HED GETKY UTILITY SUBROUTINE FOR RDBAP
      NAM GETKY,7 91750-1X215 REV.2013 790130 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    91750-18215
*     RELOC:     91750-1X215
* 
*     PRGMR:     CEJ
* 
* 
******************************************************************* 
* 
* 
* 
*  GET KeY is a utility subroutine for the use of RDBAP servicing a remote
*  DBOPN.  Its function is to determine the length of the key item be-
*  longing to the master data set whose number is the only parameter. 
*  This key item length is returned in the A register.
* 
      ENT GETKY 
      EXT .ENTR,AIRUN,DBFDI,DBFDS 
* 
B     EQU 1 
* 
SET   NOP 
* 
GETKY NOP 
      JSB .ENTR     Retrieve the data set 
       DEF SET        number's address. 
* 
      JSB DBFDS     Ask DBFDS to calculate the set's
       DEF *+5
       DEF SET,I      DSCB relative address.
       DEF DUMMY
       DEF DUMMY
       DEF ADDRS
* 
      LDB ADDRS     Add the relative addr. to the 
      ADB AIRUN       Run Table addr. to get true addr. 
* 
      ADB DSCCT     Get the key item's number 
      LDA B,I         from the high order byte of 
      ALF,ALF         the 11th word of the DSCB.
      AND LOBYT 
      STA KEY 
* 
      JSB DBFDI     Ask DBFDI to calculate
       DEF *+5        the item's Data Item
       DEF KEY        Table relative address. 
       DEF DUMMY
       DEF DUMMY
       DEF ADDRS
* 
      LDB ADDRS     Add to Run Table address to 
      ADB AIRUN       get true address. 
      ADB ITLNG     Get item's length from the 7th
      LDA B,I         word of the entry 
* 
      JMP GETKY,I     and return. 
* 
*  Constants and variables. 
* 
ITLNG DEC 6 
DSCCT DEC 10
* 
LOBYT OCT 377 
* 
ADDRS NOP 
KEY   NOP 
DUMMY NOP 
      END GETKY 
                                                                                                                        