ASMB,R,L,C
      HED <#MAQS> MA QUIESCENCE * (C) HEWLETT-PACKARD CO. 1980
      NAM #MAQS,7 91750-1X207 REV 2013 800304 ALL (MA)
      EXT EXEC,#MCTR,#MTBL,$OPSY
      ENT #MAQS 
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980. ALL RIGHTS      *
*  * RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.   *
******************************************************************
      SPC 1 
*         #MAQS 
*     --------------- 
*     SOURCE PART # 91750-18207 
*     REL PART #    91750-1X207 
*     WRITTEN BY:   TOM MILNER
*     DATE WRITTEN  DEC 1979
* 
      SPC 2 
*     #MAQS IS USED DURING QUIESCENCE TO DETERMINE IF THERE ARE 
*     ANY MESSAGES THAT HAVE NOT BEEN ACKNOWLEDGED BY MESSAGE 
*     ACCOUNTING.  IF THERE ARE NO OUTSTANDING MESSAGES THIS
*     ROUTINE WILL RETURN TO THE CALLER.
* 
*     IF THERE ARE ANY OUTSTANDING MESSAGES (ON ANY CHANNEL), #MAQS 
*     WILL SLEEP FOR 1 SECOND, THEN REPEAT THE SEARCH OF THE MA 
*     TABLE.
      SKP 
#MAQS NOP 
* 
TOP   DLD #MCTR     GET # OF ENTRIES AND PTR
      ADA N1        CTR:=CTR-1; 
      ADB N9        <B> --> MA TABLE-9
      DST CTR 
* 
*     TERMINATE WHEN ENTIRE LIST HAS NO UNACK'ED MSGS 
* 
NEXT  ISZ CTR       ALL DONE? 
      RSS           . NO LOOK AT NEXT TABLE ENTRY 
      JMP #MAQS,I   . YES RETURN
* 
      LDB PTR 
      ADB D10        <B> --> CURRENT STATE WORD 
      STB PTR 
      JSB LODWD 
      CLA 
      LSR 12        ISOLATE VSO 
      SZA,RSS       ANY UNACK'ED? 
      JMP NEXT      . NO! LOOK @ NEXT ENTRY 
* 
      JSB EXEC      SLEEP FOR 1 SECOND
      DEF *+6 
      DEF D12 
      DEF D0
      DEF D2
      DEF D0
      DEF N1
      JMP TOP       START AT TOP OF LIST
      SPC 1 
* LODWD-   GETS WORD FROM SAM 
LODWD NOP 
      LDA $OPSY     CHECK IF MEMORY MAPPED
      RAR,SLA       MAPPED? 
      JMP *+3       . YES 
      LDA 1,I       . NO JUST GET INDIRECT
      JMP LODWD,I 
      XLA 1,I 
      JMP LODWD,I 
      SPC 2 
N1    DEC -1
N9    DEC -9
D0    DEC 0 
D2    DEC 2 
D10   DEC 10
D12   DEC 12
CTR   BSS 1 
PTR   BSS 1 
      END 
                                                                                                                                                                                                                    