ASMB,R,Q,C
      HED <#RR6> REROUTING SETUP ROUTINE * (C) HEWLETT-PACKARD CO. 1979*
      NAM #RR6,7 91750-1X032 REV 2013 791206 ALL W/ RR
      SPC 1 
      EXT XLUEX,$OPSY,$LIBR,$LIBX 
      EXT .LDX,.MVW 
      EXT #LV,#LCNT,#NCNT,#CM 
      ENT #RR6
* 
*    NAME:   #RR6 
*    SOURCE: 91750-18032
*    RELOC:  91750-1X032
*    PGMR:   DOUG W. TSUI   JULY 1979 
**
* 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
* 
* 
* 
*  #RR6 CALLING SEQUENCE: 
* 
* 
*     JSB #RR6      ENABLE ALL RR LINKS 
* 
#RR6  NOP 
      LDA #LCNT 
      SZA,RSS 
      JMP #RR6,I
NOP   JSB CONFG 
* 
*  SET CM VALUE TO MAX
* 
      LDA #NCNT 
      STA I         SET UP LOOP COUNTER 
      CMA,INA 
      STA MAX+1     SET UP MAX HOP COUNT
      LDB #CM 
      STB @CM       SET UP CM ADDR
LOOP  EQU * 
      LDB @CM 
      JSB LDWD
      SZA,RSS       ZERO COST?
      CCA           .YES, SET FLAG
      STA ZFLAG 
      LDA #LCNT 
      CMA,INA 
      STA J 
LOOP1 LDA @MAX
      LDB @CM 
      ISZ ZFLAG     SKIP STORE IF ZERO COST 
      JSB STWS
      ISZ @CM 
      ISZ @CM 
      ISZ J 
      JMP LOOP1 
      ISZ I 
      JMP LOOP
* 
*  ENABLE ALL RR LINKS
* 
      LDA #LCNT 
      CMA,INA 
      STA J         SET UP LOOP INDEX 
      LDB #LV 
      STB @LV       SET UP LV ADDR
LOOP2 EQU * 
      JSB LDWD      GET LU WORD 
      AND =B377 
      STA OPT 
      IOR =B100000
      STA CONWD 
      JSB XLUEX     ENABLE CALL 
       DEF *+4
       DEF D3 
       DEF CONWD
       DEF OPT
      ISZ J 
      RSS 
      JMP #RR6,I
      LDB @LV 
      ADB LVSZ
      STB @LV 
      JMP LOOP2 
      JMP #RR6,I
      JMP #RR6,I
      SKP 
*** 
* 
*  LDWD LOADS ONE WORD FROM SAME TO LOCAL 
* 
*  CALLING SEQUENCE:
* 
*     <A> = RETURN WORD 
*     <B> ==> SAM BUFFER
* 
LDWD  NOP 
LDMOD JMP LDLDA 
      XLA 1,I 
      JMP LDWD,I
LDLDA LDA 1,I 
      JMP LDWD,I
* 
*** 
*** 
* 
*  STWS MOVES WORDS FROM LOCAL BUFFER TO SAM BUFFER 
* 
*  CALLING SEQUENCE:
* 
*     <A> ==> LOCAL BUFFER
*     <B> ==> SAM BUFFER
* 
STWS  NOP 
      JSB $LIBR 
       NOP
SSMOD JMP SSMVW 
      JSB .LDX
       DEF SSLEN
      MWI 
      JMP SSJSB 
SSMVW JSB .MVW
       DEF SSLEN
      NOP 
SSJSB JSB $LIBX 
       DEF STWS 
* 
SSLEN DEC 2         2 WORD MOVE 
* 
*** 
* 
*  CONFIGURE THE SYSTEM ENVIRONMENT 
* 
CONFG NOP 
      CLB 
      STB NOP 
      LDA $OPSY 
      RAR 
      SLA,RSS 
      JMP CONFG,I 
      STB LDMOD 
      STB SSMOD 
      JMP CONFG,I 
      SKP 
* 
*  DATA AREA
* 
CONWD NOP 
      OCT 3000
OPT   NOP 
J     NOP 
D3    DEC 3 
@LV   NOP 
LVSZ  DEC 6 
I     NOP 
@CM   NOP 
ZFLAG NOP 
MAX   OCT 77777 
      NOP 
@MAX DEF MAX
      END 
                                                                                                                                                                            