ASMB,R,Q,C
      HED <#RR4> REROUTING INIT. ROUTINE * (C) HEWLETT-PACKARD CO. 1979*
      NAM #RR4,7 91750-1X030 REV 2013 791206 ALL W/ RR
      SPC 1 
      EXT XLUEX,#GRPM 
      ENT #RR4
* 
*    NAME:   #RR4 
*    SOURCE: 91750-18030
*    RELOC:  91750-1X030
*    PGMR:   DOUG W. TSUI   JULY 1979 
**
* 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
* 
* 
* 
* 
* 
*  #RR4 CALLING SEQUENCE: 
* 
* 
*    < A REG. = LU >
*     JSB #RR4      SEND UP INDICATION TO GRPM IF OLD LINK
* 
#RR4  NOP 
      STA LU        SET UP LU WORDS 
      IOR =B100000  SET NO SST BIT
      STA CONWD 
      CLA 
      STA CONWD+1 
      JSB XLUEX     GET DRIVER TYPE 
       DEF *+4
       DEF D13
       DEF CONWD  
       DEF DTYPE    RETURN VALUE HERE 
      LDA DTYPE 
      ALF,ALF 
      AND =B77      ISOLATE DRIVER TYPE 
      CPA =B65      OLD DRIVER? 
      RSS           .YES, SKIP NEXT INST. 
      JMP #RR4,I    .NO, NO FURTHER ACTION
      LDA LU
      IOR =B400 
      STA LU+1
      CLA 
      STA CONWD 
      LDA =B10000 
      STA CONWD+1 
      JSB XLUEX     SEND UP INDICATION TO GRPM
       DEF *+8
       DEF D20
       DEF CONWD
       DEF D0 
       DEF D0 
       DEF LU 
       DEF D2 
       DEF #GRPM
      JMP #RR4,I
* 
*  DATA AREA
* 
B10K  OCT 10000 
CONWD BSS 2 
D0    DEC 0 
D2    DEC 2 
D13   DEC 13
D20   DEC 20
LU    BSS 2 
DTYPE NOP 
      END 
                                                                                                                                                                                                                                                          