ASMB,R,Q,C
      HED <#LVSC> REROUTING ROUTINE * (C) HEWLETT-PACKARD CO. 1979* 
      NAM #LVSC,30 91750-1X014 REV 2013 800107 ALL W/ RR
      SPC 1 
      ENT #LVSC 
      SPC 1 
      EXT #LV,#LCNT 
      EXT $OPSY,$LIBR,$LIBX 
* 
*    NAME:   #LVSC
*    SOURCE: 91750-18014
*    RELOC:  91750-1X014
*    PGMR:   DOUG W. TSUI   JULY 1979 
**
* 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
* 
* 
*  #LVSC CALLING SEQUENCE:
* 
*     < A REG. = LU TO BE FOUND > 
*     JSB #LVSC 
*     <ERROR RETURN>
*     <NORMAL RETURN--A REG = LINK INDEX, B REG = SAM ADDRESS>
* 
* 
      SKP 
#LVSC NOP 
      JSB $LIBR 
       NOP
      STA LU
NOP   JSB CONFG 
      CLA,INA       SET UP
      STA LIX        POSITION COUNTER 
      LDB #LV       GET LV ADDRESS
LOOP  EQU * 
      JSB LDWD      GET LV.LU 
      AND =B377     MASK OFF FLAGS
      CPA LU        FOUND?
      JMP FOUND     .YES
      LDA LIX       .NO, END OF 
      CPA #LCNT      LV TABLE?
      JMP RETRN     .YES, ERROR RETURN
      ISZ LIX       .NO, UP LIX 
      ADB LVSZ      UP LV ADDRESS 
      JMP LOOP
FOUND EQU * 
      LDA LIX       LOAD LIX FOR RETURN 
      ISZ #LVSC     ADJUST RETURN ADDRESS 
RETRN JSB $LIBX     NORMAL RETURN 
       DEF #LVSC
      SKP 
* 
*  CONFIGURE THE SYSTEM ENVIRONMENT 
* 
CONFG NOP 
      CLB 
      STB NOP       CLEAR CALL TO THIS ROUTINE
      LDA $OPSY     GET O/S TYPE
      RAR,SLA       DMS?
      STB LDMOD     .YES, MOD INST
      JMP CONFG,I 
*** 
* 
*  LDWD LOADS ONE WORD FROM SAME TO LOCAL 
* 
*  CALLING SEQUENCE:
* 
*     <A> = RETURN WORD 
*     <B> ==> SAM BUFFER
* 
LDWD  NOP 
LDMOD JMP LDLDA 
      XLA 1,I 
      JMP LDWD,I
LDLDA LDA 1,I 
      JMP LDWD,I
* 
*** 
      SKP 
* 
*  DATA AREA
* 
LU    NOP 
LIX   NOP 
LVSZ  DEC 6         LENGTH OF LV ENTRIES
      END 
                                                                    