ASMB,R,Q,C
      HED <#LOGR> DS LOG SUBROUTINE * (C) HEWLETT-PACKARD CO. 1980
      NAM #LOGR,7 91750-1X013 REV 2013 800110 ALL 
      SPC 1 
      ENT #LOGR 
      SPC 1 
      EXT #GETR,#RSAX,#RQUE,#PLOG 
* 
*    NAME:   #LOGR
*    SOURCE: 91750-18013
*    RELOC:  91750-1X013
*    PGMR:   DOUG W. TSUI    APR 1979 
**
* 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
* 
* 
*  #LOGR CALLING SEQUENCE:
* 
*     < B REG. = CLASS # TO BE RETHREADED TO PLOG > 
*     JSB #LOGR 
*  <ERROR RETURN >    BUFFER NOT LOG TO #PLOG 
*  <NORMAL RETURN>    BUFFER LOG TO #PLOG 
* 
* 
*  #LOGR OPERATION: 
* 
*     #LOGR LOGS A CLASS BUFFER TO #PLOG. 
*     IT ALSO CHECKS TO SEE IF THE BUFFER IS AN INCOMING
*     REQUEST. IF IT IS A REQUEST, THIS MEANS THAT GRPM HAS 
*     CHANGED THE ORIGINAL SEQUENCE NUMBER TO THE LOCAL SEQUENCE
*     NUMBER.  IN THIS CASE, A CALL TO #RSAX IS NECESSARY TO LOOK 
*     UP THE ORIGINAL SEQ# AND 'STUFF IT' INTO THE MESSAGE HEADER 
*     (IN SAM) BEFORE RETHREADING IT TO PLOG'S CLASS. 
* 
#LOGR NOP 
      STB CLASS 
      JSB #GETR     GET STREAM WORD AND SEQ. #
       DEF *+4
       DEF CLASS
       DEF DSHDR
       DEF D2       2 WORDS GET 
       JMP #LOGR,I  ERROR RETRUN
      LDA STREM     LOAD STREAM WORD
      AND REPLY 
      SZA           INCOMING REQUEST? 
      JMP REQU       NO, JUST REQU
* 
      JSB #RSAX     CALL RSAX TO GET ORIGINATOR'S 
       DEF *+4         SEQUENCE # AS GRPM HAS PUT A 
       DEF D5            LOCAL SEQUENCE # IN REQUEST HEADER 
       DEF SEQ# 
       DEF STREM
      STA SEQ#      RESTORE ORIGINATOR'S SEQ. # 
* 
REQU  JSB #RQUE     RETHREAD TO PLOG
       DEF *+9
       DEF NA20 
       DEF B10K     REQUE W/ Z BIT SET
       DEF D0 
       DEF D0 
       DEF DSHDR
       DEF D2       LEN OF OVERLAY
       DEF #PLOG
       DEF CLASS
       JMP #LOGR,I  ERROR RETURN
      ISZ #LOGR 
      JMP #LOGR,I   RETURN
* 
* 
CLASS NOP 
DSHDR BSS 2         ASSUME FIRST TWO WORDS IS 
STREM EQU DSHDR      STREAM WORD &
SEQ#  EQU DSHDR+1    SEQ. # 
REPLY OCT 40000 
B10K  OCT 010000
NA20  OCT 100024
D0    DEC 0 
D2    DEC 2 
D5    DEC 5 
      END 
  