ASMB,R,L,C
*     NAME:   DTTY
*     SOURCE: 91740-18062 
*     RELOC:  91740-16062 
*     PGMR:   MIKE SCHOENDORF 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM DTTY,8 91740-16062 REV 1805 771118
* 
*     DTTY   DETERMINE IF THE REFERENCED LU IS ASSOCIATED 
*     WITH AN INTERACTIVE DEVICE (DVR00 OR DVR05 SUB 0).
*     [MODIFIED NOV 18, 1977, TO CHECK FOR DVR07 SUB 0. DMT]
* 
*     DTTY CALLING SEQUENCE:
* 
*       LDA LU OF DEVICE TO BE CHECKED
*       JSB DTTY
* 
* 
*     RETURN  
* 
*     A=0 IF NOT INTERACTIVE
*     A#0 IF INTERACTIVE
* 
* 
* 
      EXT EXEC
      ENT DTTY
* 
* 
* 
DTTY  NOP 
      SSA 
      CMA,INA 
      STA LU
* 
      JSB EXEC       REQUEST STATUS 
      DEF RT1 
      DEF .13 
      DEF LU
      DEF EQ5 
      DEF EQ4 
      DEF SPC 
* 
* 
RT1   LDA EQ5        CHECK FOR DVR00
      AND TYPE
      SZA,RSS 
      JMP GOOD       YEP--TAKE GOOD EXIT
* 
      CPA B2400      CHECK FOR DVR05
      JMP SBCNL      YEP--GO CHECK FOR SUB CHNL 0 
      CPA B3400      CHECK FOR DVR07
      JMP SBCNL      YEP--GO CHECK FOR SUB CHNL 0 
* 
BAD   CLA            TAKE FALSE EXIT
      JMP DTTY,I
* 
SBCNL LDA SPC        FETCH SUB CHNL 
      AND B77 
      SZA 
      JMP BAD        NOT ZERO 
GOOD  CLA,INA        ALL RIGHT--TAKE INTERACTIVE EXIT 
      JMP DTTY,I
* 
* 
* 
* 
SPC   NOP 
.13   DEC 13
EQ5   NOP 
EQ4   NOP 
LU    NOP 
TYPE  OCT 37400 
B2400 OCT 2400
B3400 OCT 3400
B77   OCT 77
* 
      END 
* 
                                                                                                                                                      