ASMB,R,L,C
      HED REDIT 91740-16023 REV 1740 * (C) HEWLETT-PACKARD CO. 1977 * 
      NAM REDIT,19,50 91740-16023 REV 1740 770518 
      SPC 3 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SUP 
      SPC 2 
*  NAME:   REDIT
*  SOURCE: 91740-18023
*  RELOC.: 91740-16023
*  PGMR.:  C.C.H. 
      SPC 2 
* 
      ENT REDIT 
* 
      EXT DEXEC,EXEC,#NODE,$LIBR,$LIBX,$CVT1
      SPC 2 
* 
* THIS IS A DS/1000 PROGRAM USED TO SCHEDULE "EDITR" AT A 
* REMOTE DISC-BASED NODE OF THE DS/1000 NETWORK.
* 
* CALLING SEQUENCE: 
* 
* *ON,REDIT,TTYLU,RECSZ,NODE,,CHARS   SCHEDULE EDITR AT ANY NODE IN NETWORK 
* 
* WHERE:
* 
*   TTYLU = INTERACTIVE TERMINAL LU NO. (LOCAL NODE) [DEFAULT =1] 
* 
*   RECSZ = + MAXIMUM CHARACTERS PER LINE [DEFAULT =150]
* 
*   NODE  = NODE AT WHICH <EDITR> IS TO BE SCHEDULED. 
* 
*   CHARS = OPTIONAL NAME CHARACTERS, FOR ALTERNATE PROGRAM NAME: "EDIXX".
*           [THE SUPPLIED CHARACTERS MODIFY THE SCHEDULED-PROGRAM NAME  IF
*            NOT SUPPLIED, "EDITR" WILL BE SCHEDULED.]
* 
      SKP 
* 
REDIT STB P1        SAVE TTYLU ADDRESS IN CALLING SEQUENCE
      INB 
      STB P2         & RECORD SIZE ADDRESS
      INB 
      STB P3           & OPERATING NODE ADDRESS 
      STB DNODE     DEFINE RECIPIENT OF <DEXEC> REQUEST.
* 
      ADB K2        POINT TO P5.
      LDA B,I       GET OPTIONAL-NAME CHARS.--IF ANY. 
      STA TEMP      SAVE TEMPORARILY. 
      SZA           ALTERNATE NAME SPECIFIED? 
      JMP CKASC      YES. CHECK TYPE OF PARAMETER.
* 
      DLD ASCTR      NO. RESTORE DEFAULT CHARACTERS "TR". 
      DST EMSG+5
      JMP SCHED     GO TO SCHEDULE "EDITR". 
* 
CKASC ADA M.100     SUBTRACT 100 FOR ASCII CHECK. 
      CCE,SSA,RSS   ASCII PARAMETER SUPPLIED? 
      JMP CONFG      YES--NO NEED FOR CONVERSION. 
* 
      LDA TEMP      GET THE PARAMETER.
      JSB $LIBR 
      NOP 
      JSB $CVT1     CONVERT DECIMAL TO ASCII. 
      STA TEMP      SAVE THE RESULT.
      JSB $LIBX 
      DEF *+1 
      DEF CONFG 
* 
CONFG LDA TMPBA     GET BYTE ADDRESS OF CHARACTERS. 
      LDB NAMBA     GET BYTE ADDRESS OF PROG. NAME. 
      MBT K2        MOVE THE CHARACTERS TO THE NAME.
* 
SCHED JSB DEXEC 
      DEF *+9 
DNODE NOP           <EDITR> LOCATION NODAL ADDRESS. 
      DEF K10       SCHEDULE W/O WAIT.
      DEF EMSG+4    PROGRAM NAME: "EDI??".
P1    NOP           LOCAL INTERACTIVE LOGICAL UNIT NO.
P2    NOP           NUMBER OF CHARACTERS PER LINE.
P3    NOP           REMOTE NODAL ADDRESS OF <EDITR>.
      DEF #NODE     DEFINE (LOCAL) OPERATOR'S NODAL ADDRESS.
      DEF K1        NON-ZER0: DETECTION OF DESTINATION =0.
* 
      SZA,RSS 
      JMP TERM      SCHEDULED OK
* 
      JSB EXEC      GIVE FAILURE MESSAGE
      DEF *+5 
      DEF K2
      DEF K1
      DEF EMSG
      DEF ELENG 
* 
TERM  JSB EXEC      TERMINATE 
      DEF *+2 
      DEF K6
* 
* 
A     EQU 0 
B     EQU 1 
K1    DEC 1 
K2    DEC 2 
K6    DEC 6 
K10   DEC 10
M.100 DEC -100
ASCTR ASC 2,ITR 
TEMP  NOP 
TMPBA DBL TEMP
NAMBA DBR EMSG+5
* 
ELENG DEC 13
EMSG  ASC 13,REMOTE EDITR UNAVAILABLE! 
* 
      END REDIT 
                                                              