ASMB,R,L,C
      HED OPERM 91740-16006 REV 2026 * (C) HEWLETT-PACKARD CO. 1977 
      NAM OPERM,19,30 91740-16006 REV 2026 800429 
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 1 
      ENT OPERM 
      EXT MESSS,EXEC,D65SV,D65GT
      EXT #NODE 
      IFZ 
      EXT DBUG
      XIF 
      SUP 
* 
* OPERM 
* SOURCE: 91740-18006 
* BINARY: 91740-16006 
* PRGMR: BOB SHATZER
* DATE: 29 DEC 75 
* MODIFIED BY JEAN-PIERRE BAUDOUIN
* DATE: JULY 1976 
* MODIFIED BY GAB 
* DATE: JULY 1979 
* 
*     OPERM IS THE CCE MONITOR WHICH RECEIVES OPERATOR REQUESTS INIT- 
*     IATED BY A REMOTE CPU. THIS MONITOR OPERATES ON STREAM 7. 
* 
OPERM LDA B,I       GET INPUT PARAMETER 
      IFZ 
      SZA,RSS       IS IT A ZERO? 
      JMP *+3       YES - CALL DEBUG
      XIF 
      STA CLSN      NO - NORMAL SCHEDULE - SAVE CLASS NUMBER
      JMP OPER1     GO TO GET THE FIRST REQUEST 
* 
      IFZ 
      JSB DBUG      CALL DEBUG IF P1 WAS 0
      DEF *+1 
      JSB EXEC      TERMINATE...SAVE RESOURCES
      DEF *+4 
      DEF B6
      DEF B0
      DEF B1
      JMP OPERM     TRY AGAIN 
      XIF 
* 
OPER1 JSB D65GT     WAIT FOR REQUEST
      DEF *+6 
      DEF CLSN      CLASS # 
      DEF PARMB     REQUEST BUFFER
      DEF D25       MAX LENGTH =25
      DEF B0        NO DATA ASSOCIATED
      DEF B0
      JMP OPER1     IGNORE THE COMMUNICATION ERROR
* 
      LDA PARMB+4   GET LENGTH
      SZA,RSS       IF ZERO...SEND BACK ZERO TO THEM
      JMP DONE
* 
      JSB MESSS     CALL SYSTEM MSG PROCESSOR WITH MESSAGE
      DEF *+3 
      DEF PARMB+5   THE REPLY WILL COME IN THE SAME AREA
      DEF PARMB+4 
* 
      CMA,INA       MAKE SYSTEM REPLY LENGTH POSITIVE BYTES 
      CLE,ERA       MAKE THIS POSITIVE WORDS
      SEZ 
      INA 
DONE  STA RPLY+7   SAVE LENGTH IN WORDS INTO REPLY
      ADA D8        ADD STANDARD LENGTH OF PARMB
      STA LEN       SAVE AS REPLY LENGTH
* 
      DLD PARMB     GET STREAM TYPE & SEQUENCE NO.
      IOR BIT14     SET IN FOR REPLY
      DST RPLY      SAVE AS REPLY STREAM & SEQ. NO. 
* 
      DLD PARMB+2 
      DST RPLY+2    MOVE THE REQUEST HEADER 
      CLA           CLEAR 
      CLB            ERROR
      DST RPLY+4      LOCATIONS.
      LDA #NODE     GET LOCAL NODE #
      STA RPLY+6
* 
      JSB D65SV     SEND REPLY
      DEF *+5 
      DEF RPLY
      DEF LEN 
      DEF B0
      DEF B0
      NOP           IGNORE THE ERROR RETURN 
* 
      JMP OPER1     WAIT FOR ANOTHER REQUEST
* 
B     EQU 1 
B0    OCT 0 
B1    OCT 1 
B6    OCT 6 
D8    DEC 8 
D25   DEC 25
BIT14 OCT 40000 
CLSN  NOP 
RPLY  BSS 3         DO NOT REARANGE THIS AREA 
PARMB BSS 28
LEN   NOP 
* 
      END OPERM 
                                                                                                                                                                                                                        