ASMB,L,C
*     NAME  :  FIXMP--MULTIPOINT POWER-FAIL FIXUP SUBROUTINE
*     SOURCE:  91730-18008  1901
*     RELOC:   91730-16008  1901
*     PROGMR: G.W.J.
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM FIXMP,7 91730-16008 REV 1901 781026 
      ENT FIXMP 
      EXT $LIBR,$LIBX 
A     EQU 0 
B     EQU 1 
* 
* 
FIXMP NOP 
      JSB $LIBR      TURN OFF MEMORY PRT. 
      NOP 
      LDA 1651B      GET THE NUMBER OF EQT'S
      CMA,INA        MAKE NEG.
      STA CNT        PUT IN COUNTER 
      LDB 1650B      GET POINTER TO EQT'S 
      STB PNT        PUT IN POINTER 
LP    ADB =D3        GET EQ4
      LDA B,I 
      STA SC         SAVE IT
      INB            BUMP TO EQ5
      LDA B,I        GET EQ5
      AND =B37400    MASK DRIVER TYPE 
      CPA =B3400     COMP. DV TYPE 7
      RSS            YES, GO ON 
      JMP NEXT       NO, GO TO NEXT EQT 
      ADB =D6        BUMP TO EQ11 
      LDA B,I        GET EQ11 
      SZA,RSS        NON ZERO (ACTIVE)? 
      JMP NEXT       NO, GO TO NEXT EQT 
      ADB =D2        BUMP TO EQ13 
      LDA B,I        GET EQ13 
      LDA A,I        GET FIRST WOR OF EXT 
      SSA,RSS        BIT 15 SET? LINE EQ? 
      JMP NEXT       NO, GO TO NEXT EQT 
      LDA SC         BUILD STC INST 
      AND =B77
      IOR STFC       FORCE THE IFC TO RUN 
      STA I.00        ITS DIAGNOSTIC AGAIN. 
      IOR CLCC  
      STA I.01
      XOR STCC
      STA I.02
I.00  NOP            --HERE IS WHERE WE DO IT 
I.01  NOP 
I.02  NOP 
NEXT  ISZ CNT        DONE ALL EQT'S?
      JMP NEX1       NO GO ON 
      ISZ FIXMP      BUMP RETURN POINT. 
      JSB $LIBX      YES, ON MEMORY PRT.
      DEF FIXMP      AND RETURN 
NEX1  LDB PNT        PUMP PNT TO NEXT EQT 
      ADB =D15
      STB PNT 
      JMP LP         DO IT ALL AGAIN
* 
* 
CNT   NOP 
PNT   NOP 
SC    NOP 
STFC  OCT 102100     STF COMMAND TO IFC 
CLCC  OCT   4600     MAKE STC INTO CLC
STCC  OCT   5000     MAKE CLC INTO STC,C
      END 
                                                                                                                                                                      