ASMB,R,L
* 
* 
********************************************************************
* 
* 
*          DECST (DECODE STATUS)
* 
*  HAS AS INPUTS STATUS WORDS ONE AND TWO. THESE ARE BROKEN DOWN
*  AND STORED IN A 5 WORD BUFFER. WORD 1 GETS THE SPD BITS, WORD 2
*  GETS THE IDC STATUS, 3  GETS THE "E" BIT, 4 THE DRIVE TYPE AND 
*  WORD 5 GETS THE DRIVE STATUS. ALL INFORMATION IS RIGHT JUSTIFIED.
* 
* 
********************************************************************
      NAM DGLB2 91711-1X109 REV.2001 791120 
* 
*     CHANGE MADE 791105 TO CORRECT THE PART NUMBER ONLY
*     CHANGE MADE 791120 TO CHANGE NAM TO DGLB2 
* 
* 
* 
*  THIS PART NO.  WILL MERGE INTO 91711-12110 RELOCATABLE.
* 
* 
* 
* 
      ENT DECST 
      ENT ODPAR 
      EXT .ENTR 
IS1   NOP 
ID1   NOP 
DECST NOP 
      JSB .ENTR 
      DEF IS1 
      LDA IS1,I 
      ALF,ARS 
      AND =B7 
      STA ID1,I 
      ISZ ID1 
      LDA IS1,I 
      ALF,ALF 
      AND =B37
      STA ID1,I 
      ISZ ID1 
      ISZ IS1 
      LDA IS1,I 
      CLB 
      CLE,ELA 
      ELB 
      STB ID1,I 
      ISZ ID1 
      RAL,RAL 
      ALF 
      AND =B17
      STA ID1,I 
      ISZ ID1 
      LDA IS1,I 
      AND =B377 
      STA ID1,I 
      JMP DECST,I 
* 
* 
* 
* 
* 
* 
* THIS SUB WILL ADD THE PARITY BIT TO VALUE 
* STORED IN ADRS. 
* 
* 
ADRS  NOP 
ODPAR NOP 
      JSB .ENTR 
      DEF ADRS
      LDA ADRS,I
      STA SAVEA 
      STB SAVEB 
      ERB 
      STB SAVEE 
      LDB BM7 
      CCE 
      SLA,RAR 
      CME 
      ISZ B 
      JMP *-3 
      LDA SAVEA 
      SEZ 
      IOR BIT7
      LDB SAVEE 
      ELB 
      LDB SAVEB 
      STA ADRS,I
      JMP ODPAR,I 
* 
* 
SAVEA OCT 0 
SAVEB OCT 0 
SAVEE OCT 0 
BM7   OCT -7
BIT7  OCT 200 
* 
* 
B     EQU 1 
      END 
      END$
                                                                                                                                                                                      