ASMB,L
      NAM VISVF 91711-16014  REV 1926  790421 
      ENT VISVF 
      EXT .ENTR 
**********************************************************************
*                                                                    *
*     VECTOR INSTRUCTION SET VERIFICATION SUBROUTINE                 *
*                                                                    *
*     CALL VISVF(ICODE)                                              *
*                                                                    *
*     RETURNS:   ICODE = 0     VIS NOT INSTALLED                     *
*                ICODE < 0     VIS VERIFICATION FAILURE              *
*                ICODE > 0     ICODE = FIRMWARE REV. NUMBER          *
*                                                                    *
**********************************************************************
ICODE BSS 1 
* 
VISVF NOP           ENTRY POINT 
      JSB .ENTR     GET ADDRESSES 
      DEF ICODE 
      CLA           SET A = 0 
      CAX           SET X = 0 
* 
      LIB 1         SET B = S-REGISTER
      STB TEMP      SAVE S-REGISTER IN TEMP 
      CLA           SET A = 0 
      OTA 1         SET S = 0 
      OCT 105477    VIS SELF-TEST 
      NOP           SELF-TEST ERROR RETURN
      LIA 1         SET A = TEST RESULT 
      LDB TEMP      SET B = TEMP
      OTB 1         RESTORE S-REGISTER
* 
      CXB           SET B = X 
      SZB,RSS       DID TEST EXECUTE? 
      JMP DONE      NO, ALL DONE
      CPA HLT77     YES, CHECK RESULT 
      JMP DONE      VIS OK, ALL DONE
      LDX =D-1      VIS FAILURE, ERROR CODE 
* 
DONE  STX ICODE,I   RETURN ICODE
      JMP VISVF,I   RETURN
* 
TEMP  BSS 1 
HLT77 HLT 77B 
* 
      END 
                                      