ASMB,L
      NAM HFPVF 91711-16010  REV 1926  790423 
      ENT HFPVF 
      EXT .ENTR 
**********************************************************************
*                                                                    *
*     HARDWARE FLOATING POINT VERIFICATION SUBROUTINE                *
*                                                                    *
*     CALL HFPVF(ICODE)                                              *
*                                                                    *
*     RETURNS:   ICODE = 0     HFP NOT INSTALLED                     *
*                ICODE < 0     HFP VERIFICATION FAILURE              *
*                ICODE > 0     ICODE = FIRMWARE REV. NUMBER          *
*                                                                    *
**********************************************************************
ICODE BSS 1 
* 
HFPVF NOP           ENTRY POINT 
      JSB .ENTR     GET ADDRESSES 
      DEF ICODE 
      CLA           SET A = 0 
      CAX           SET X = 0 
      CLB,INB       SET B = 1 
* 
      OCT 105124    .FLTD 
      SZA,RSS       SKIP IF HFP INSTALLED 
      JMP DONE      E-SERIES, ALL DONE
* 
      ISX           HFP INSTALLED, SET REV = 1
      LIB 1         SET B = S-REGISTER
      STB TEMP      SAVE S-REGISTER IN TEMP 
      CLA           SET A = 0 
      OTA 1         SET S = 0 
      OCT 105004    HFP SELF-TEST 
      NOP           SELF-TEST ERROR RETURN
      LIA 1         SET A = TEST RESULT 
      LDB TEMP      SET B = TEMP
      OTB 1         RESTORE S-REGISTER
* 
      CXB           SET B = X 
      CPB =D1       DID TEST EXECUTE? 
      JMP DONE      NO, ALL DONE
      CPA HLT77     YES, CHECK RESULT 
      JMP DONE      HFP OK, ALL DONE
      LDX =D-1      HFP FAILURE, ERROR CODE 
* 
DONE  STX ICODE,I   RETURN ICODE
      JMP HFPVF,I   RETURN
* 
TEMP  BSS 1 
HLT77 HLT 77B 
* 
      END 
                                                                                                  