ASMB,L
      NAM FFPVF 91711-16009  REV 1926  790421 
      ENT FFPVF 
      EXT .ENTR 
**********************************************************************
*                                                                    *
*     FAST FORTRAN PROCESSOR VERIFICATION SUBROUTINE                 *
*                                                                    *
*     CALL FFPVF(ICODE)                                              *
*                                                                    *
*     RETURNS:   ICODE = 0     FFP NOT INSTALLED                     *
*                ICODE < 0     FFP VERIFICATION FAILURE              *
*                ICODE > 0     ICODE = FIRMWARE REV. NUMBER          *
*                                                                    *
**********************************************************************
ICODE BSS 1 
* 
FFPVF NOP           ENTRY POINT 
      JSB .ENTR     GET ADDRESSES 
      DEF ICODE 
      CLA           SET A = 0 
      CAX           SET X = 0 
* 
      CCB           SET B = 177777B 
      OCT 105226    .FLUN 
      SZA,RSS       SKIP IF A # 0 
      JMP DONE      JUMP IF NOT INSTALLED 
      ISX           FFP INSTALLED, SET REV = 1
* 
      LIB 1         SET B = S-REGISTER
      STB TEMP      SAVE S-REGISTER IN TEMP 
      CLA           SET A = 0 
      OTA 1         SET S = 0 
      OCT 105200    FFP SELF-TEST 
      NOP           SELF-TEST ERROR RETURN
      LIA 1         SET A = TEST RESULT 
      LDB TEMP      SET B = TEMP
      OTB 1         RESTORE S-REGISTER
* 
      CXB           SET B = X 
      CPB =D1       DID TEST EXECUTE? 
      JMP DONE      NO, ALL DONE
      CPA HLT77     YES, CHECK RESULT 
      JMP DONE      FFP OK, ALL DONE
      LDX =D-1      FFP FAILURE, ERROR CODE 
* 
DONE  STX ICODE,I   RETURN ICODE
      JMP FFPVF,I   RETURN
* 
TEMP  BSS 1 
HLT77 HLT 77B 
* 
      END 
                                                                                                