ASMB,R,L,C
      HED SMON 91700-16159 REV.A 760111 * (C) HEWLETT PACKARD CO. 1976* 
      NAM SMON,2,29 91700-16159 REV.A 760111
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 1 
*  <SMON> IS THE DISTRIBUTED SYSTEMS MONITOR WHICH PROCESSES ALL
*   INCOMING STREAM-0 REQUESTS. AT PRESENT, ONLY 'GETLU' SATELLITE
*   REQUESTS ARE CLASSIFIED UNDER THE STREAM-0 CATEGORY. <SMON> WILL
*   TRANSFER THE RESPONDING CCE LOGICAL UNIT NO. (AS SUPPLIED BY THE
*   QUEUEING PROCESSOR) FROM <PARMB+24> TO <PARMB+2>, PRIOR TO  
*   TRANSMITTING THE REPLY TO THE SATELLITE. THE REPLY LENGTH WILL
*   BE 35 WORDS FOR FRIENDLY SATELLITES, AND 3 WORDS FOR ALIENS.
* 
      ENT SMON
      EXT EXEC,D65SV
* 
SMON  LDA B,I       GET THE <LSTEN>-SUPPLIED CLASS NUMBER,
      STA CLASN       AND SAVE IT FOR REQUEST PROCESSING. 
* 
GET   JSB EXEC      GO TO 
      DEF *+5        THE RTE SYSTEM 
      DEF CLS21       TO GET
      DEF CLASN        THE USER'S 
      DEF PBUF          PARAMETER 
      DEF PBLN           BUFFER.
      JMP ERROR     * REPORT THE SYSTEM-LEVEL ERROR! *
* 
      LDA PBUF      GET THE STREAM WORD.
      IOR BIT14     INCLUDE THE REPLY BIT(#14). 
      STA PBUF      RESTORE THE STREAM WORD.
      LDB PBLN      GET FRIENDLY REPLY LENGTH (35 WORDS). 
      ALF           POSITION FRIENDLY BIT(#11) TO SIGN. 
      SSA,RSS       IF THE REQUEST WAS FROM AN ALIEN, 
      LDB THREE       PREPARE FOR A SHORT REPLY (3 WORDS).
      STB RPLEN     SAVE THE CONFIGURED REPLY LENGTH. 
* 
      LDA PBUF+24   GET THE CCE LU NUMBER,
      STA PBUF+2     AND TRANSFER IT TO 2ND WORD OF REPLY.
      STA CONWD     USE IT ALSO, FOR <D65SV> CONTROL WORD.
* 
      JSB D65SV     CALL THE
      DEF *+7        SLAVE-REPLY
      DEF IRWW        PROCESSOR 
      DEF CONWD        TO 
      DEF PBUF          TRANSMIT
      DEF RPLEN          THE USER'S 
      DEF ZERO            REQUESTED 
      DEF ZERO             INFORMATION. 
      JMP ERROR     * REPORT THE SYSTEM-LEVEL ERROR! *
* 
      JMP GET       GO TO AWAIT THE NEXT REQUEST. 
* 
ERROR DST SMESG+4   CONFIGURE MESSAGE W/SYSTEM ERROR CODES. 
      JSB EXEC      INFORM
      DEF *+5        THE USER 
      DEF WRITE       OF A
      DEF ONE          SYSTEM-  
      DEF SMESG         LEVEL 
      DEF SMSIZ          PROBLEM. 
* 
      JSB EXEC      TERMINATE, IN ORDER TO ALLOW
      DEF *+2        <UPLIN> TO RESTORE THE 
      DEF SIX         NORMAL CONDITIONS FOR <SMON>. 
      SUP 
SMESG ASC 14, /SMON: XXXX  ERROR-ABORTED! 
SMSIZ DEC 14
* 
B     EQU 1 
IRWW  OCT 100002
BIT14 OCT 040000
CONWD NOP 
CLASN NOP 
RPLEN NOP 
CLS21 OCT 100025
ONE   OCT 1 
THREE OCT 3 
SIX   OCT 6 
WRITE OCT 2 
ZERO  OCT 0 
PBLN  DEC 35
PBUF  BSS 35
      END SMON
                                                                                                                                                                  