ASMB,R,L,C
      HED #CLWT 91700-16156 REV A 751226 * (C) HEWLETT-PACKARD CO. 1976 
      NAM #CLWT,6 91700-16156 REV.A 751226
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT #CLWT 
      EXT $LIBR,$LIBX,.ENTP,EXEC
* 
* 
* #CLWT 
* SOURCE: 91700-18156 
* BINARY: 91700-16156 
* PRGMR: BOB SHATZER
* DATE: 26 SEP 75 
* 
* 
*     #CLWT IS A RE-ENTRANT SUBROUTINE WHICH IS USED BY QUEUE,
*     GRPM, AND SRPM TO HANDLE CLASS I/O WRITE-READS FROM ONE TO
*     ANOTHER AND TO WRITE CONTROL AND CLEAN-UP INFORMATION TO
*     QCUM, THE QUEUEING CLEAN-UP MODULE. 
* 
* 
*     CALLING SEQUENCE: 
* 
*                   JSB #CLWT 
*                   DEF *+6 
*                   DEF CLSNO     USER-SUPPLIED CLASS NUMBER
*                   DEF BUFAD     USER-SUPPLIED BUFFER ADDR 
*                   DEF BUFLN     USER-SUPPLIED BUFFER LEN
*                   DEF PARM1     CLASS-CALL OR DUMMY PARAMETER 
*                   DEF PARM2     CLASS-CALL OR DUMMY PARAMETER 
*                   <ERROR RETURN>
*                   <NORMAL RETURN> 
* 
* 
TDB   NOP           TEMPORY DATA BLOCK HEADER 
      DEC 8         TDB LENGTH
      NOP 
CLSNO NOP           USER-SUPPLIED CLASS NUMBER
BUFAD NOP           USER-SUPPLIED BUFFER ADDRESS
BUFLN NOP           USER-SUPPLIED BUFFER LENGTH 
PARM1 NOP           OPTIONAL CLASS-CALL PARAMETER 
PARM2 NOP           OPTIONAL CLASS-CALL PARAMETER 
* 
#CLWT NOP           PRIMARY ENTRY POINT 
      JSB $LIBR 
      DEF TDB 
      JSB .ENTP     CALL .ENTP TO RETREIVE PARAMETERS 
      DEF CLSNO 
      STA TDB+2     SAVE RETURN ADDRESS 
* 
      JSB EXEC      PERFORM CLASS WRITE/READ
      DEF *+8 
      DEF D20I
      DEF ZERO
      DEF BUFAD,I 
      DEF BUFLN,I 
      DEF PARM1,I 
      DEF PARM2,I 
      DEF CLSNO,I 
      CLA,RSS       SET <A>=0 IF ERROR RETURN 
      CLA,INA       SET <A>=1 FOR NO ERROR
      STA RTRN      AND USE TO SET RETURN POINT 
* 
      JSB $LIBX     RETURN TO CALLER
      DEF TDB 
RTRN  NOP 
* 
ZERO  OCT 0 
D20I  ABS 100000B+20
* 
      END 
                                                                                    