ASMB,R,L,C
      HED DPURG 91700-16118 REV A 751222 * (C) HEWLETT PACKARD CO. 1976 
      NAM DPURG,7 91700-16118 REV A 751222
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT DPURG 
      EXT PURGE 
      EXT .ENTR 
      SPC 5 
* 
* DPURG 
* SOURCE:91700-18118
* BINARY:91700-16118
* SHANE DICKEY
* JULY 31,1974
* 
PRAMS REP 5 
      NOP 
DPURG NOP 
      JSB .ENTR 
      DEF PRAMS 
* 
      LDA PRAMS+4   IS THE DESTINATION SPECIFIED? 
      SZA,RSS 
      JMP MORE      NO DEFAULT TO CENTRAL CALL
* 
      INA           STEP PAST CART.LABEL
      LDA A,I       TO DESTINATION CODE 
      SZA           CENTRAL CALL
      JMP ERROR     NO ABORT THE USER 
MORE  LDA D3        SET UP DEFAULT # OF PARAMETERS
      STA #PRMS 
* 
      DLD PRAMS     MOVE DEFS FOR 1ST TWO 
      DST PRAM1 
* 
      DLD PRAMS+2   MOVE 2ND TWO
      DST PRAM1+2 
* 
* 
      SZB,RSS       WAS THE 4TH ONE THERE?
      JMP DONE      NO DONE 
* 
      ISZ #PRMS     YES INCREMENT COUNT 
      LDA PRAMS+4   MOVE POSSIBLE 5TH 
* 
      SZA,RSS       THERE?
      JMP DONE      NO FINISHED 
      ISZ #PRMS     YES BUMP COUNT & STORE AWAY 
      STA PRAM1+4 
DONE  LDA #PRMS     CALCULATE RETURN
      ADA ADDS
      STA DRTN      & PUT IN CONSTRUCTED CALL 
* 
      JSB RFASR 
      JSB CLEAR     CLEAR PARAMETER ARRAY 
      LDA PRAMS+1,I GET IERR
      JMP DPURG,I   FINISHED RETURN TO USER 
      SPC 5 
* CLEAR ARRAY & CALL CONSOLE OUTPUT 
ERROR JSB CLEAR 
      LDA MD18      RETURN ERROR CODE 
      STA PRAMS+1,I TO USER & 
      JMP DPURG,I   EXIT
      SPC 5 
RFASR NOP 
      JSB PURGE 
DRTN  NOP 
PRAM1 REP 5 
      NOP 
      JMP RFASR,I 
      SPC 5 
CLEAR NOP 
      CLA           CLEAR OPTIONAL PARAMETER DEFS 
      CLB 
      DST PRAMS+3 
      DST PRAM1+3 
* 
      JMP CLEAR,I 
      SPC 5 
* CONSTANTS 
A     EQU 0 
D3    DEC 3 
ADDS  DEF DRTN+1
#PRMS NOP 
MD18  DEC -18 
      END 
* AN ERROR EXISTS 
                                                                                                                                                                                