ASMB,R,L,C
      HED DNAME 91700-16115 REV A 751222 * (C) HEWLETT PACKARD CO. 1976 
      NAM DNAME,7 91700-16115 REV A 751222
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT DNAME 
      EXT NAMF
      EXT .ENTR 
      SPC 5 
* 
* DNAME 
* SOURCE:91700-18115
* BINARY:91700-16115
* SHANE DICKEY
* AUGUST 29,1974
* 
PRAMS REP 6 
      NOP 
DNAME NOP 
      JSB .ENTR 
      DEF PRAMS 
* 
      LDA PRAMS+5   IS THE DEST CODE SPECIFIED? 
      SZA,RSS 
      JMP MORE      CONTINUE
* 
      INA           STEP PAST CART. LABEL 
      LDA A,I       TO DESTINATION CODE 
      SZA           CENTRAL CALL? 
      JMP ERROR     NO ABORT USER 
MORE  LDA D4        SET UP DEFAULT # OF PRAMS.
      STA #PRMS 
* 
* 
      DLD PRAMS     MOVE DEFS FOR 1ST TWO 
      DST PRAM1 
* 
      DLD PRAMS+2 
      DST PRAM1+2   MOVE 2ND TWO
* 
      DLD PRAMS+4   MOVE POSSIBLE 5TH & 6TH 
      DST PRAM1+4 
* 
      SZA,RSS       WAS THE 5TH ONE THERE?
      JMP DONE      NO-DONE 
* 
      ISZ #PRMS     YES INCREMENT COUNT 
* 
      SZB,RSS       THERE?
      JMP DONE      NO FINISHED 
      ISZ #PRMS     YES BUMP COUNT & STORE AWAY 
DONE  LDA #PRMS     CALCULATE RETURN
      ADA ADDS
      STA DRTN      & PUT IN CONSTRUCTED CALL 
* 
      JSB RFASR 
      JSB CLEAR     CLEAR PARAMETER ARRAY 
      LDA PRAMS+1,I GET IERR
      JMP DNAME,I   FINISHED RETURN TO USER 
      SPC 5 
* CLEAR ARRAY & CALL CONSOLE OUTPUT 
ERROR JSB CLEAR 
      LDA MD18      PICK UP & RETURN
      STA PRAMS+1,I ERROR CODE
      JMP DNAME,I   & RETURN TO USER
      SPC 5 
RFASR NOP 
      JSB NAMF
DRTN  NOP 
PRAM1 REP 6 
      NOP 
      JMP RFASR,I 
      SPC 5 
CLEAR NOP 
      CLA           CLEAR DEFS TO OPTIONAL PARAMS.
      CLB 
      DST PRAMS+4 
      DST PRAM1+4 
* 
      JMP CLEAR,I 
      SPC 5 
* CONSTANTS 
A     EQU 0 
D4    DEC 4 
ADDS  DEF DRTN+1
#PRMS NOP 
MD18  DEC -18 
      END 
                                                                                                                                                                                                          