ASMB,R,L,C
      HED DLOCF 91700-16114 REV A 751222 * (C) HEWLETT PACKARD CO. 1976 
      NAM DLOCF,7 91700-16114 REV A 751222
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT DLOCF 
      EXT LOCF
      EXT .ENTR 
      SPC 5 
* 
* DLOCF 
* SOURCE:91700-18114
* BINARY:91700-16114
* SHANE DICKEY
* JULY 31,1974
* 
PRAMS REP 9 
      NOP 
DLOCF NOP 
      JSB .ENTR 
      DEF PRAMS 
* 
      LDA APRMS     SET UP SOURCE ADDRESS 
      STA PRMSA 
* 
      LDA APRM1     SET UP DESTINATION ADDRESS
      STA APRM2 
* 
      LDA MD9       SET UP LOOP COUNTER 
      STA CONTR 
* 
      CLB           CLEAR PARAMETER COUNTER 
* 
LOOP  LDA PRMSA,I   MOVE PARAMETERS TO 2NDARY 
      SZA,RSS 
      JMP OUT 
      STA APRM2,I   ARRAY COUNTING AS YOU GO
      INB 
      ISZ PRMSA     INCREMENT POINTERS
      ISZ APRM2 
      ISZ CONTR     DONE YET? 
      JMP LOOP      NO-CONTINUE 
* 
* 
OUT   ADB ADDS
      STB DRTN      & PUT IN CONSTRUCTED CALL 
* 
      JSB RFASR 
      JSB CLEAR     CLEAR PARAMETER ARRAY 
      JMP DLOCF,I   FINISHED RETURN TO USER 
      SPC 5 
RFASR NOP 
      JSB LOCF
DRTN  NOP 
PRAM1 REP 9 
      NOP 
      JMP RFASR,I 
      SPC 5 
CLEAR NOP 
      LDB APRMS     SET UP CLEAR ADDRESS
      STB PRMSA 
* 
      LDB PRM1
      STB PR1 
* 
      LDB MD9       BUILD LOOP COUNTER
      STB CONTR 
* 
      CLB 
LOOP1 STB PRMSA,I   CLEAR A WORD
      STB PR1,I 
      ISZ PRMSA     INCREMENT POINTERS
      ISZ PR1 
      ISZ CONTR 
      JMP LOOP1 
* 
      JMP CLEAR,I 
      SPC 5 
* CONSTANTS 
CONTR NOP 
APRMS DEF PRAMS 
PRMSA NOP 
ADDS  DEF DRTN+1
MD9   DEC -9
APRM1 DEF PRAM1 
APRM2 NOP 
PRM1  DEF PRAM1 
PR1   NOP 
      END 
* AN ERROR EXISTS 
                                                                                                                                              