ASMB,L,R,C  
      HED OPERM 91700-16105 REV A 751229 * (C) HEWLETT-PACKARD CO. 1976 
      NAM OPERM,2,30 91700-16105 REV A 751229 
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT OPERM 
      EXT MESSS,EXEC,D65SV,#MBRK
      IFZ 
      EXT DBUG
      XIF 
* 
* 
* OPERM 
* SOURCE: 91700-18105 
* BINARY: 91700-16105 
* PRGMR: BOB SHATZER
* DATE: 29 DEC 75 
* 
* 
* 
*     OPERM IS THE CCE MONITOR WHICH RECEIVES OPERATOR REQUESTS INIT- 
*     IATED BY A REMOTE CPU. THIS MONITOR OPERATES ON STREAM 7. 
* 
* 
OPERM LDA B,I       GET INPUT PARAMETER 
      IFZ 
      SZA,RSS       IS IT A ZERO? 
      JMP *+3       YES - CALL DEBUG
      XIF 
      STA CLSN      NO - NORMAL SCHEDULE - SAVE CLASS NUMBER
      JMP OPER1     GO TO GET THE FIRST REQUEST 
* 
      IFZ 
      JSB DBUG      CALL DEBUG IF P1 WAS 0
      DEF *+1 
      JSB EXEC      TERMINATE...SAVE RESOURCES
      DEF *+4 
      DEF B6
      DEF B0
      DEF B1
      JMP OPERM     TRY AGAIN 
      XIF 
* 
OPER1 JSB EXEC      DO A CLASS GET AND WAIT FOR REQUEST 
      DEF *+5 
      DEF D21 
      DEF CLSN      CLASS # 
      DEF PARMB     REQUEST BUFFER
      DEF D35       MAX LENGTH =35
* 
      LDA LNGTH     GET LENGTH
      SZA,RSS       IF ZERO...SEND BACK ZERO TO THEM
      JMP DONE
* 
      JSB #MBRK     GO CHECK THE BREAK FLAG 
      DEF *+4 
      DEF D7        STREAM
      DEF RLU       REQUESTING LU 
      DEF TTAGS     TIME TAGS 
      JMP OPER1     <ERROR RETURN>
      JMP OPER1     <BREAK RETURN>
* 
      JSB MESSS     CALL SYSTEM MSG PROCESSOR WITH MESSAGE
      DEF *+3 
      DEF SMESG 
      DEF LNGTH 
      CMA,INA       MAKE SYSTEM REPLY LENGTH POSITIVE BYTES 
      STA LNGTH     SAVE LENGTH 
* 
DONE  LDA PARMB     GET STREAM TYPE 
      IOR BIT14     SET IN FOR REPLY
      STA PARMB     SAVE AS REPLY STREAM
      LDB D35       GET 35 WORD REPLY LENGTH
      ALF           ROTATE FRIENDLY BIT (BIT 11) TO BIT 15
      SSA,RSS      IS IT SET? (REUEST FROM SCE/4 OR /5) 
      LDB D25       NO - SET REPLY LENGTH TO 25 WORDS 
      STB RPYLN     AND SAVE IT 
      JSB D65SV     SEND REPLY
      DEF *+7 
      DEF B2
      DEF RLU 
      DEF PARMB 
      DEF RPYLN 
      DEF B0
      DEF B0
      NOP           ERROR RETURN POINT
      JMP OPER1     WAIT FOR ANOTHER REQUEST
* 
B     EQU 1 
B0    OCT 0 
B1    OCT 1 
B2    OCT 2 
B6    OCT 6 
D7    DEC 7 
D21   DEC 21
D25   DEC 25
D35   DEC 35
RPYLN NOP 
BIT14 OCT 40000 
CLSN  NOP 
PARMB BSS 35
LNGTH EQU PARMB+5 
SMESG EQU PARMB+6 
RLU   EQU PARMB+24
TTAGS EQU PARMB+33
* 
      END OPERM 
                        