ASMB,R,L,T,C,B  ** REMOTE: SWITCH BUS TO REMOTE ROUTINE **
      HED ** REMOT: SWITCH BUS TO REMOTE **                  REV A
      NAM REMOT 
      ENT REMOT 
      EXT .ENTR,.IOC.,CMD 
      SKP 
UREF# OCT 0 
MODE  DEF ZERO
* 
REMOT NOP           ENTRY 
      JSB .ENTR     GET PARAM 
      DEF UREF#          ADDR'S FROM USER CALL
* 
*     CONFIGURE IOC REQUEST 
* 
      LDA UREF#,I   GET UNIT REFERENCE #
      AND =B000077  LIMIT TO 2 OCTAL DIGITS 
      IOR RMTRC     ADD IN REQUEST CODE FOR REMOTE
      STA RCODE     PUT IT INTO CALLING SEQ. TO IOC 
* 
*     EXECUTE CONTROL REQUEST TO IOC
* 
      JSB .IOC.     CALL IOC
RCODE OCT 030300    RCODE = 0303 CONFIGURED 
      JMP *-2       REPEAT IF REJECTED
* 
*     CHECK MODE
* 
      LDA MODE,I    GET <MODE> FROM USER CALL 
      SZA,RSS       TEST IT 
      JMP END       O:"SOFT REMOTE",EXIT
*                                   >0:"LOCAL LOCK OUT,CONTINUE 
* 
*     OUTPUT COMMAND FOR LOCAL LOCK OUT 
* 
      JSB CMD       CALL COMMAND ROTINE 
      DEF *+3       PNTR TO RETURN
      DEF UREF#,I   ODDR OF BUS UREF# 
      DEF LLO       ADDR OF BUFFER CONTAINING 
*                                  LOCAL LOCK OUT COMMAND 
* 
*     SET MODE PARAMER TO ZERO FOR DEFALT CASE
* 
END   LDA ZEROA     GET ADDR OF VALUE OF 0
      STA MODE      PUT IT INTO PARAM ADDR LIST 
      JMP REMOT,I   EXIT
* 
*     CONSTANTS 
* 
LLO   OCT 1         BUFFER LENGTH 
      OCT 010400    LLO CMD IN UPPER HALF WD
*                                   LLO CMD = 021 OCTAL 
*                                   0 001 000 100 000 000 
ZEROA DEF ZERO      ADDR OF ZERO
ZERO  OCT 0         VALUE ZERO
RMTRC OCT 030300    REQ. CODE FOR SW TO REMOTE
      END 
                                    