ASMB,R,L,C
      HED SRQ.P-SPECIAL SRQ/TRAP SERVICE PROGRAM FOR BASIC
      NAM SRQ.P,17,30  59310-16005  REV 1805  780110
* 
      EXT EXEC,RMPAR,SRQ.T,TRPNT
* 
****************************************************
* 
*      SRQ.P-SPECIAL SRQ/TRAP SERVICE PROGRAM 
* 
*      THIS PROGRAM WHEN ACTIVATED BY DVR37 WILL
*      SEARCH THE SRQ/TRAP TABLE MAINTAINED WITHIN
*      THE DRIVER & INVOKE ANY TRAPS ARMED BY THE 
*      BASIC USER. NOTE THIS ROUTINE IS USED IN 
*      CONJUNCTION WITH THE SRQSN CALL IN BASIC.
* 
*     RELOC:  59310-16005 
*     SOURCE: 59310-18007 
* 
****************************************************
* 
S     JSB RMPAR     RECOVER SCHEDULE PARMS
       DEF *+2
       DEF T1 
      LDA T3        GET EQT ADDR
      ADA .3         & INDEX TO WORD4 
      LDA 0,I       EXTRACT CHANNEL 
      AND B77 
      LDB T2        GET SUB-CHANNEL 
      BLF,BLF       POSITION TO HI BITS 
      IOR 1 
      STA T1
* 
      LDA SRQ.T     SET TO
      STA T2         SCAN 
      LDA M16         SRQ/TRAP
      STA T3           TABLE
S1    LDA T2,I       & DO IT
      CPA T1        MATCH?
      JMP S3         YES, INVOKE TRAP 
S2    ISZ T2
      ISZ T3        END TABLE?
      JMP S1         NO, CONTINUE 
      JSB EXEC       YES, QUIT
       DEF *+2      *NO RETURN* 
       DEF .6 
* 
S3    LDA T3        ENTRY FOUND,
      ADA .17       (A)=TRAP #
      JSB TRPNT      GO TRAP
       NOP
      JMP S2
* 
*     STORAGE 
* 
T1    BSS 1 
T2    BSS 1 
T3    BSS 1 
      BSS 2 
.3    DEC 3 
.6    DEC 6 
.17   DEC 17
M16   DEC -16 
B77   OCT 77
* 
      END S 
                                                                                                                                                  