100  REM
110  REM DVS SUBSYSTEM RTE-B VERIFICATION TEST
120  REM LISTING:     A-29100-18002-2 
125  REM ERS:         A-29100-18002-1 
130  REM SOURCE:      29100-18002 
135  REM
140  REM        W.M.PARRISH 7/74
145  REM
148  PRINT  
150  PRINT "DVS SUBSYSTEM VERIFICATION" 
152  PRINT  
200  REM CHECK S/S STATUS 
205  PRINT "**CHECKING DVS SUBSYSTEM FOR AVAILABILITY**"
210  DCVRS(I1,I2,I3,I4) 
220  IF I1=0 THEN 300 
230  PRINT "SUBSYSTEM IS NOT READY -- CODE ="I1 
240  PAUSE  
250  GOTO 200 
300  REM CHECK CLEAR CALL 
305  PRINT "SUBSYSTEM AVAILABLE"
307  PRINT  
310  PRINT "**CLEARING DVS SUBSYSTEM**" 
315  PRINT "A TIME-OUT ERROR MEANS AT LEAST ONE DVS NOT RESPONDING" 
317  PRINT "OR TIME-OUT NOT PROPERLY SPECIFIED" 
320  DCVCL  
330  PRINT "DVS SYSTEM CLEARED" 
340  PRINT  
400  PRINT "**CHECK VOLTAGE PROGRAMMING CALLS**"
410  PRINT "USE 0 FOR UNIT NUMBER TO STOP PROGRAM"
420  PRINT  
430  PRINT "ENTER UNIT NUMBER, VOLTAGE (VDC) AND CURRENT LIMIT (MA)"; 
440  INPUT U,V,C
450  IF U=0 THEN 800
460  IF (ABS(V)-16)>0 THEN 600
500  REM LOW RANGE
510  DCVSL(U,V,C) 
520  WAIT (100) 
530  DCVRS(J1,J2,J3,J4) 
540  IF J2=0 THEN 430 
550  GOSUB 1000 
560  GOTO 430 
600  REM HIGH RANGE 
610  DCVSH(U,V,C) 
620  GOTO 520 
800  REM STATUS HISTORY CHECK 
805  REM NOTE REVERSED ORDER ON CALL
810  DCVRS(J1,J2,J4,J3) 
815  PRINT "LATCH HISTORY"
820  GOSUB 1020 
830  PRINT "CLEARING DVS SUBSYSTEM" 
840  DCVCL  
850  STOP 
1000  REM CHECK LATCH STATUS
1010  PRINT "AT LEAST ONE DVS LATCHED CODE=";J2 
1015  PRINT "LATCH STATUS FOR DVS UNITS"
1020  GOSUB 2000
1030  FOR I=0 TO 7
1040  IBTST(J3,I,Z) 
1050  PRINT Z" "; 
1060  NEXT I
1070  RETURN  
2000  REM DISPLAY NUMBERS OVER LATCH STATUS OR HISTORY ARRAYS 
2010  FOR I=1 TO 8
2020  PRINT I" "; 
2030  NEXT I
2040  PRINT 
2050  RETURN  
3000  END 
                                                                                                                                                                                