ASMB,R,L,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".CFER" COMPLEX VARIABLE "4 WORD LOAD/STORE"
      NAM .CFER,6 24998-1X196 REV.2001 790523 
      ENT .CFER 
      EXT .ZPRV 
      SPC 1 
* 
*     THIS ROUTINE PASSES TRIPLE PRECISION ARGUMENTS
*     BETWEEN EXTENDED PRECISION ROUTINES.
*     CALLING SEQUENCE: 
*     JSB .CFER 
*     DEF (DESTINATION) 
*     DEF (SOURCE)
*     <RETURN>    A-REG. = DIRECT SOURCE ADDRESS + 4
*                 B-REG. = DIRECT DESTINATION + 4 
*                 E-REG  = 0
* 
      SPC 1 
.CFER NOP 
      JSB .ZPRV 
      DEF LIBX1 
      LDB .CFER     DESTINATION ADDRESS 
      ISZ .CFER 
      LDA .CFER     SOURCE ADDRESS
      ISZ .CFER 
      LDA A,I       PICK UP NEXT LEVEL INDIRECT 
      RAL,CLE,SLA,ERA 
      JMP *-2 
      STA TEMP
      LDB B,I       PICK UP NEXT LEVEL INDIRECT 
      RBL,CLE,SLB,ERB 
      JMP *-2 
      LDA TEMP,I
      STA B,I 
      ISZ TEMP
      INB 
      LDA TEMP,I
      STA B,I 
      ISZ TEMP
      INB 
      LDA TEMP,I
      STA B,I 
      ISZ TEMP
      INB 
      LDA TEMP,I
      STA B,I 
      INB           BUMP B=B+4(DIRECT)
      LDA TEMP
      CLE,INA       BUMP A=A+4(DIRECT)
LIBX1 JMP .CFER,I 
      DEF .CFER 
      SPC 1 
A     EQU 0 
B     EQU 1 
TEMP  NOP 
* 
      END 
* 
* 
* 
                                                                                                                                                                        