ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".TFTD" - FLOAT DOUBLE INTEGER TO 4-WORD FLOATING.
      NAM .TFTD,7 24998-1X185 REV.2001 780424 
* 
      ENT .TFTD 
      EXT .XPAK 
* 
A     EQU 0 
B     EQU 1 
* 
*     .TFTD CONVERTS A TWO-WORD INTEGER TO A 4-WORD 
*     FLOATING-POINT NUMBER.
* 
*     CALLING SEQUENCE: 
* 
*                   DLD <ARG> 
*                   JSB .TFTD 
*                   DEF <RESULT>
      SPC 4 
.TFTD NOP 
      STB TEMP      SAVE B-REG
      LDB .TFTD     GET ADDR RESULT 
      ISZ .TFTD 
      LDB B,I       RESOLVE INDIRECTS 
      RBL,CLE,SLB,ERB 
      JMP *-2 
      STB RESLT 
      STA B,I       COPY ARG
      INB 
      LDA TEMP
      STA B,I 
      INB 
      CLA           THIRD WORD = 0
      STA B,I 
      STB TEMP      TEMP = ADDR(RESULT) + 2 
      LDA =D31      FLOAT TO 3-WORD 
      JSB .XPAK 
RESLT DEF *-* 
      LDA TEMP,I    EXTEND TO 4-WORD
      CLB 
      STB TEMP,I    3RD WD = 0
      ISZ TEMP
      STA TEMP,I    4TH WD = OLD 3RD WD 
      JMP .TFTD,I   EXIT
* 
TEMP  BSS 1 
      END 
                                                                                                                                            