ASMB,R,L,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED "DBLE" STANDARD TO EXTENDED PRECISION CONVERSION
      NAM DBLE,6 24998-1X178 REV.2001 750701
      ENT DBLE
      EXT .ZPRV 
      SPC 1 
* 
*     TWO WORD FLOATING POINT NUMBERS ARE CONVERTED TO
*     THREE WORD FLOATING POINT NUMBERS BY THIS ROUTINE 
*     CALLING SEQUENCE: 
*         JSB DBLE
*         DEF *+3 
*     DEF Y    (RESULT:3 WORDS) 
*     DEF X    (ARGUMENT:2 WORDS) 
* 
*     TIME:  APPROX 50  2100 CYCLES + PRIVLEDGE PROCESSING
      SPC 2 
Y     NOP 
DBLE  NOP 
      JSB .ZPRV 
      DEF LIBX
      ISZ DBLE      BUMP TO P+2 
      LDA DBLE      GET ADDRESS OF P+2
      LDA A,I       GET CONTENTS
      RAL,CLE,SLA,ERA INDIRECT BIT SET? 
      JMP *-2       YES, TRY AGAIN
      STA Y         SAVE ADDRESS OF Y 
      ISZ DBLE      GET ADDRESS OF P+3
      LDA DBLE,I
      DLD A,I       GET VALUE OF X
      STA Y,I       PUT IN HI-MANTISSA
      ISZ Y         BUMP TO MID-MANTISSA
      LDA B         GET LO-MAN + EXP. OF REAL 
      AND OM400     OBTAIN LO-MAN 
      STA Y,I       PUT IN DBL MID-MANTISSA 
      XOR B         GET EXPONENT
      ISZ Y         BUMP TO DBL LO-MAN+EXP. 
      STA Y,I       AND SET 
      ISZ DBLE      SET FOR P+4 RETURN
LIBX  JMP DBLE,I
      DEF DBLE
      SPC 1 
OM400 OCT -400
A     EQU 0 
B     EQU 1 
      END 
* 
                                                                                                                                