ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED "/ATLG" - COMMON CODE FOR .ATAN, .LOG . 
      NAM /ATLG,7 24998-1X173 REV.2001 780424 
* 
      ENT /ATLG 
      EXT .TADD,.TSUB,.TDIV 
* 
A     EQU 0 
B     EQU 1 
* 
*     /ATLG COMPUTES THE EXPRESSION:  (1-X)/(1+X)  WHICH
*     IS USED IN .ATAN AND .LOG . 
* 
*     CALLING SEQUENCE: 
* 
*                   JSB /ATLG 
*                   DEF <ARG,RESLT>  DIRECT ADDRESS.
*                   <RETURN>
      SPC 4 
/ATLG NOP 
      LDA /ATLG,I   ADDR ARG
      ISZ /ATLG 
      JSB .TSUB     FORM (1-X)
      DEF TEMP1 
      DEF ONE 
      DEF A,I 
      JSB .TADD     FORM (1+X)
      DEF TEMP2 
      DEF ONE 
      DEF A,I 
      JSB .TDIV     FORM (1-X)/(1+X)
      DEF A,I 
      DEF TEMP1 
      DEF TEMP2 
      JMP /ATLG,I   EXIT
      SPC 3 
TEMP1 BSS 4         TEMP FOR (1-X)
TEMP2 BSS 4         TEMP FOR (1+X)
ONE   OCT 040000,0,0,2  4-WD 1.0
      SPC 2 
      END 
                  