ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".BLE" - CONVERT SINGLE TO TRIPLE.
      NAM .BLE,7 24998-1X170 REV.2001 780424
* 
      ENT .BLE
      EXT .ENTR 
* 
A     EQU 0 
B     EQU 1 
* 
*     .BLE CONVERTS A SINGLE-PRECISION NUMBER TO A TRIPLE-PRECISION 
*     NUMBER. THE CONVERSION IS EXACT.
* 
*     CALLING SEQUENCE: 
* 
*                   JSB .BLE
*                   DEF *+3 
*                   DEF <RESULT>
*                   DEF <ARG> 
*                   <RETURN>
      SPC 4 
RESLT DEF *-* 
ARG   DEF *-* 
.BLE  NOP 
      JSB .ENTR 
      DEF RESLT 
      DLD ARG,I     RESLT(1) = ARG(1) 
      STA RESLT,I 
      ISZ RESLT 
      LDA B         RESLT(2) = ARG(2)<15:8> & 0 
      AND =B177400
      STA RESLT,I 
      ISZ RESLT 
      XOR B 
      CLB           RESLT(3) = 0
      STB RESLT,I 
      ISZ RESLT 
      STA RESLT,I   RESLT(4) = 0 & ARG(2)<7:0>
      JMP .BLE,I
      END 
                                        