ASMB,R,L,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".ENTC" GET PRAMS ADDRESS WITHOUT RETURN DEF. (DLB) 
      NAM .ENTC,6 24998-1X155 REV.2001 750701 
      ENT .ENTC 
      EXT .ZPRV 
      SPC 1 
* 
*  THIS ROUTINE IS THE SAME AS THE ".ENTP" ROUTINE EXCEPT 
*  THE RETURN "DEF *+1+N" IS NOT NEEDED.  IT WILL GET THE 
*  DIRECT ADDRESSES AND DETERMINE THE NUMBET OF PARAMETER 
*  ADDRESSES BY THE NUMBER ASKED FOR BY THE DESTINATION 
*  ROUTINE.  CAUTION! THE NUMBET OF PARAMETER ADDRESSES 
*  PASSED BY THE CALLING ROUTINE MUST AGREE WITH THE NUMBER 
*  REQUESTED BY THE RECEIVING ROUTINE.
*  CALLER ROUTINE:              DESTINATION ROUTINE:
* 
*       JSB .SUB                 P1    NOP
*       DEF P1<,I>               P2    NOP
*       DEF P2<,I>               P3    NOP
*       DEF P2<,I>               .SUB  NOP
*       <RETURN>                       JSB .ZRNT -OR- .ZRPV 
*                                      DEF LIBX 
*                                      JSB .ENTC
*                                      DEF P1 
*                                      STA TDB+2 (IF RE-ENTERENT) 
* 
*  TIME:  APPORX. 26 + 18/PARAM + 7/INDIRECT + PRIV. PROCESSING 
*         2100 CYCLES.
      SPC 1 
.ENTC NOP           ENTRY = .SUB+4
      JSB .ZPRV     PRIVLEGED ROUTINE 
      DEF LIBX
      LDA .ENTC     GET .SUB+4 ADDRESS
      ADA DM4       GET .SUB ADDRESS
      STA DONEA     SAVE AS DONE POINTER
      LDA A,I       GET .SUB'S NOP CONTENTS 
      STA SORCA     AND SAVE AS SOURCE LIST POINTER 
      LDA .ENTC,I   GET DESTINATION LIST POINTER
LOOP  LDB SORCA     GET NEXT SOURCE ADDRESS 
      LDB B,I       GET IT'S CONTENTS 
      RBL,CLE,SLB,ERB INDIRECT? 
      JMP *-2       YES, TRY NEXT LEVEL 
      STB A,I       NO, PUT IS .SUB'S LIST
      INA           BUMP DEST'S ADDRESS 
      ISZ SORCA     BUMP SOURCES'S ADDRESS
      CPA DONEA     DONE? 
      RSS           YES 
      JMP LOOP      NO, GET NEXT ADDRESS
      LDA SORCA     YES, GET RETURN ADDRESS FOR .SUB'S
      STA DONEA,I   NOP & SET FOR PROPER RETURN ADDRESS 
      ISZ .ENTC     P+2 RETURN
LIBX  JMP .ENTC,I   RETURN
      DEF .ENTC 
      SPC 1 
DM4   DEC -4
DONEA NOP 
SORCA NOP 
A     EQU 0 
B     EQU 1 
      END 
* 
        