ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".TCPX" - CONVERT TRIPLE TO COMPLEX.
      NAM .TCPX,7 24998-1X069 REV.2001 780424 
* 
      ENT .TCPX 
      EXT .NGL
* 
A     EQU 0 
B     EQU 1 
* 
*     .TCPX CONVERTS A TRIPLE-PRECISION NUMBER TO A COMPLEX NUMBER
*     BY SETTING THE REAL PART TO THE ROUNDED SINGLE-PRECISION
*     APPROXIMATION OF THE ARGUMENT AND SETTING THE IMAGINARY PART
*     TO ZERO.
* 
*     CALLING SEQUENCE: 
* 
*                   JSB .TCPX 
*                   DEF <RESULT>
*                   DEF <ARG> 
* 
.TCPX NOP 
      LDA .TCPX     ADDR ADDR RESULT
      ISZ .TCPX 
      LDA A,I       RESOLVE INDIRECTS 
      RAL,CLE,SLA,ERA 
      JMP *-2 
      STA RESLT     DIRECT RESULT ADDR
      LDA .TCPX,I   ADDR ARG
      ISZ .TCPX 
      STA ARG 
      JSB .NGL      CONVERT TO SINGLE 
      DEF *+2 
ARG   DEF *-* 
      STA RESLT,I   STORE REAL PART 
      ISZ RESLT 
      STB RESLT,I 
      ISZ RESLT 
      CLA           STORE IMAGINARY PART = 0
      STA RESLT,I 
      ISZ RESLT 
      STA RESLT,I 
      JMP .TCPX,I   EXIT
* 
RESLT BSS 1         DIRECT RESULT ADDR
* 
      END 
                                                                            