ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".SIGN" - TRIPLE PRECISION TRANSFER OF SIGN.
      NAM .SIGN,7 24998-1X066 REV.2001 781016 
* 
      ENT .SIGN 
      EXT .CFER,.TSUB,.4ZRO,.ENTR 
* 
*     .SIGN TRANSFERS THE SIGN OF ONE NUMBER (ANY PRECISION) TO A 
*     TRIPLE-PRECISION NUMBER.
* 
*     CALLING SEQUENCE: 
* 
*                   JSB .SIGN 
*                   DEF *+4 
*                   DEF <RESULT>
*                   DEF <VALUE> 
*                   DEF <SIGN>
      SPC 4 
RESLT BSS 1 
VALUE BSS 1 
SIGN  BSS 1 
.SIGN NOP 
      JSB .ENTR     COPY ADDRESSES
      DEF RESLT 
      LDA VALUE,I   FIRST WORD VALUE
      XOR SIGN,I    IS SIGN CORRECT ? 
      SSA,RSS 
      JMP SIGN1     YES.
      JSB .TSUB     NO, NEGATE
      DEF RESLT,I 
      DEF .4ZRO+0 
      DEF VALUE,I 
      JMP .SIGN,I   EXIT
SIGN1 JSB .CFER     SIGN CORRECT, JUST COPY 
      DEF RESLT,I 
      DEF VALUE,I 
      CLO           NO OFL ON JUST COPY.
      JMP .SIGN,I   EXIT
* 
      END 
                                                                                                                                                                                                                      