ASMB,R,L,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".CHEB" CHEBY. COEFF'S ROUTINE
      NAM .CHEB,6 24998-1X032 REV.2001 750701 
      ENT .CHEB 
      EXT .ZRNT 
* 
* 
*      CALL.. 
* 
*      DLD X         (FLOATING) 
*      JSB .CHEB     (RESULT FLOATING)
*      DEF C         (TABLE OF CHEBY. COEFF'S., FLOATING) 
* 
.CHEB NOP 
      JSB .ZRNT 
      DEF LIBX
      STA X2
      STB X2+1     X2=X 
      FAD X2
      STA X2
      STB X2+1     X2=2*X 
      LDB .CHEB 
      LDA .CHEB+1 
      SSA,RSS 
      STB TDB+2 
      LDA TDB+2 
      LDA .A.,I 
      RAL,CLE,SLA,ERA 
      JMP *-2       TRACK DOWN INDIRECTS
      STA C        C POINTS TO COEFFICIENT TABLE
      DLD C,I       GET FIRST COEFF.
      STA D 
      STB D+1       D=C(N)
      CLA 
      STA B 
      STA B+1       B=0 
LOOP  ISZ C 
      ISZ C         N=N-1 
      LDA C,I 
      SZA,RSS       C(N)=0 ?
      JMP OUT       ZERO FLAGS END OF TABLE 
      LDA B         NO
      LDB B+1 
      STA A 
      STB A+1       A=B 
      LDA D 
      LDB D+1 
      STA B 
      STB B+1       B=D 
      FMP X2
      FSB A 
      FAD C,I 
      STA D 
      STB D+1       D=C(N)-A+B*X2 
      JMP LOOP
OUT   LDA D 
      LDB D+1 
      FSB A 
      FMP HLF 
      ISZ TDB+2 
LIBX  JMP TDB+2,I 
      DEF TDB 
      DEC 0 
      SPC 1 
HLF   DEC .5
TDB   NOP 
      DEC 12
      NOP 
X2    REP 2 
      NOP 
C     NOP 
D     REP 2 
      NOP 
B     REP 2 
      NOP 
A     REP 2 
      NOP 
.A.  EQU 0
      END 
* 
* 
* 
* 
                                                                                                                                                                                        