ASMB,L,R,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED ".ABS" - TRIPLE PRECISION ABSOLUTE VALUE. 
      NAM .ABS,7 24998-1X030 REV.2001 781016
* 
      ENT .ABS
      EXT .CFER,.TSUB,.4ZRO,.ENTR 
* 
*     ABS TAKES THE TRIPLE-PRECISION ABSOLUTE VALUE OF
*     A TRIPLE-PRECISION ARGUMENT.
* 
*     CALLING SEQUENCE: 
* 
*                   JSB .ABS
*                   DEF *+3 
*                   DEF <RESULT>
*                   DEF <ARG> 
* 
*     IF THE ARGUMENT IS -2**127, THE VALUE  (1-2**-55)*2**127  IS
*     RETURNED AND THE OVERFLOW BIT IS SET. 
      SPC 4 
RESLT DEF *-* 
ARG   DEF *-* 
.ABS  NOP 
      JSB .ENTR     COPY ADDRESSES
      DEF RESLT 
      LDB ARG,I     FIRST WORD ARG
      SSB,RSS       POS?
      JMP ABS1      YES 
      JSB .TSUB     NO, NEGATE
      DEF RESLT,I 
      DEF .4ZRO+0 
      DEF ARG,I 
      JMP .ABS,I    EXIT
ABS1  JSB .CFER     POS, JUST COPY
      DEF RESLT,I 
      DEF ARG,I 
      CLO 
      JMP .ABS,I    EXIT
* 
      END 
                                                                                                                                                                                                                                        