ASMB
      NAM SDCAR,7 24306-60001 REV.2026 791205 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    24306-18008
*     RELOC:     24306-60001
* 
* 
* 
******************************************************************
* 
* 
* 
* 
* 
*FUNCTION - SDCAR PERFORMS THE SAME FUNCTION SCARY, 
*EXCEPT DCARY OPERATES ON A CHARACTER STRING IN D1 FORMAT 
* 
*CALLING SEQUENCE - CALL SDCAR(JSTR,J,JLAST,KARRY)
*WHERE J AND JLAST INDICATE THE FIRST AND LAST WORDS IN JSTR
* TO BE CARRIED 
* 
      ENT SDCAR 
      EXT .ENTR 
PARAM BSS 4 
SDCAR NOP 
      JSB .ENTR     TRANSFER PARAMETERS 
      DEF PARAM 
      CLA           NCARY=O 
      STA NCARY 
      LDA PARAM+2,I JNOW=JLAST
      STA JNOW
GET   LDB JNOW      JCHAR=JSTR(JNOW)
      ADB PARAM 
      LDA 1,I 
      STA JCHAR 
      LDA NCARY     JTEST=JCHAR+NCARY 
      ADA JCHAR 
      MPY ONE 
      DIV TEN 
      STA NCARY     NCARY=JTEST/10
      STB JTEST     JTEST=JTEST-10*NCARY
      SSB,RSS       IS JTEST<0? 
      JMP PUT       IF N0T
      ADB TEN       JTEST=JTEST+10
      STB JTEST 
      ADA NEG1      NCARY=NCARY-1 
      STA NCARY 
PUT   LDA JNOW      JSTR(JNOW)=JTEST
      ADA PARAM 
      STB 0,I 
      LDA JNOW      JNOW=JNOW-1 
      ADA NEG1
      STA JNOW
      LDB PARAM+1,I REG B=-J
      CMB,INB 
      ADA 1 
      SSA,RSS       IS JNOW-J<O?
      JMP GET       IF NOT
      LDA NCARY     KARRY=NCARY 
      STA PARAM+3,I 
      JMP SDCAR,I   RETURN
NCARY OCT 0 
JNOW  OCT 0 
JCHAR OCT 0 
JTEST OCT 0 
TEN   DEC 10
NEG1  DEC -1
ONE   OCT 1 
      END 
      END$
                                                                          