      HED 12936 PRIVILEGED INT DIAG - SUBROUTINES 
* 
*     LHSU SETS THE LO/HI SC TO INT 
* 
LHSU  NOP 
HSC00 STC HSC       SET HI SC 
HSC01 STF HSC                 TO INT
LSC00 STC LSC       SET LO SC 
LSC01 STF LSC                 TO INT
      JMP LHSU,I    EXIT
      SPC 3 
* 
*     TOS TURNS OFF LO/HI/FENCE CH'S
* 
TOS   NOP 
FSC41 CLC FCH       TURN
FSC42 CLF FCH            OFF
HSC14 CLC HSC                HI/LO/FENCE
LSC07 CLC LSC                            SC'S 
      JMP TOS,I     EXIT
      SPC 3 
* 
*     SCCS CONFIGURES I/O INSTRUCTIONS TO 
*          THE CURRENT SELECT CODE
* 
SCCS  NOP 
      STA SCS       SAVE SELECT CODE
      STB CSC       SAVE SC TABLE 
SCCS1 LDB CSC,I     LOAD FIRST ADDRESS
      CPB M1        IS IT THE END OF LIST 
      JMP SCCS,I    YES, EXIT 
      LDA B,I       NO, LOAD INSTRUCTION
      AND SCMK      MASK OFF SC 
      IOR SCS       OR IN CURRENT SC
      STA B,I       RESTORE 
      ISZ CSC       MOVE PTR TO NEXT ADDRESS
      JMP SCCS1     CONTINUE
SCS   OCT 0 
CSC   OCT 0 
SCMK  OCT 177700
M1    DEC -1
      HED 12936 PRIVILEGED INT DIAG - CONFIGURATION 
* 
*     PCFG PERFORMS CONFIGURATION ON LO/HI SC 
*          I/O INSTRUCTIONS 
* 
PCFG  DEF FCFG
FCFG  EQU * 
CF1   LIA SW        LOAD SWITCH REGISTER
      AND MKSC      MASK OFF HI SC
      STA LSCS      SAVE
      LDB A         CHECK 
      CMB,INB             THAT
      ADB B7                   SC 
      SSB                         > 7 
      JMP CF2       YES 
E073  HLT 73B       NO
      JMP CF1 
CF2   LIA SW
      ALF,ALF       POSITION HI SC
      RAL,RAL 
      AND MKSC      MASK OFF HI SC
      STA HSCS      SAVE
      LDB A         CHECK 
      CMB,INB             THAT
      ADB B7                   SC 
      SSB                         > 7 
      JMP CF3       YES 
      JMP E073      NO
      JMP CF1 
CF3   LDB LSCS      CHECK THAT HIGH SC
      CMA,INA          IS AT LEAST
      INA                 LOW SC + 2
      ADA B 
      SSA 
      JMP CF4       YES, CONTINUE 
E071  HLT 71B       NO, RETURN FOR ANOTHER TRY
      JMP CF1 
CF4   LDA LSCS
      LDB LOOIP 
      JSB SCCS      CONFIGURE LO SC INSTR 
      LDA HSCS
      LDB HIOIP 
      JSB SCCS      CONFIGURE HI SC INSTR 
      CLA           CLEAR S-REG. FOR INPUT
      OTA 01B 
      HLT 70B       ENTER FENCE SC TO SWR 
      JMP CFIG,I    GO TO FENCE CONFIGURATION 
LSCS  OCT 0 
HSCS  OCT 0 
B7    OCT 7 
MKSC  OCT 77
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 0
*     INITIATION SECTION
* 
*     HI SC SET TO INT
* 
TST00 EQU * 
HIT   NOP 
      LDA HITJ      SET UP
HSC15 STA HSC              RETURN POINT 
HSC16 STC HSC       SET HI SC 
HSC17 STF HSC                 TO INT
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E035  JSB ERMS,I    REPORT ERROR
      DEF MS035 
      JMP HIT,I     EXIT
MS035 ASC 19,E035 HI SC SET TO INT BUT DID NOT INT/ 
* 
* 
*     COMPLETION SECTION
* 
*     INTERRUPT SEQUENCE
*         1. LOW
*         2. NOT HIGH 
*         3. NOT FENCE
* 
HITR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP HIT,I     EXIT
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 1
*     INITIATION SECTION
* 
*     LO SC SET TO INT
* 
TST01 EQU * 
LOT   NOP 
      LDA LOTJ      SET UP
LSC10 STA LSC              RETURN POINT 
LSC11 STC LSC       SET LO SC 
LSC12 STF LSC                 TO INT
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E036  JSB ERMS,I    REPORT ERROR
      DEF MS036 
      JMP LOT,I     EXIT
MS036 ASC 19,E036 LO SC SET TO INT BUT DID NOT INT/ 
* 
      SPC 2 
* 
*     COMPLETION SECTION
* 
*     INTERRUPT SEQUENCE
* 
*         1. HIGH 
*         2. NOT FENCE
*         3. NOT LOW
* 
LOTR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP LOT,I     EXIT
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 2
* 
*     INITIATION SECTION
* 
*        CNTL.FLGF
*     HI SC SET TO INTERRUPT
* 
TST02 EQU * 
CCT   NOP 
      LDA HCCJ      SET 
HSC04 STA HSC           UP
      LDA FCCJ             INT
FSC04 STA FCH                  RETURN 
HSC12 STC HSC       SET HI SC 
HSC13 STF HSC                 TO INT
FSC05 CLF FCH       SET FENCE TO
FSC06 STC FCH                    LOWER PRIORITY 
      STF INTP      TURN ON INTS
FSC24 CLC FCH       CLEAR FENCE CONTROL 
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E030  JSB ERMS,I    REPORT ERROR
      DEF MS030 
      JMP CCT,I     EXIT
MS030 ASC 19,E030 CLC SC FAILED TO CLEAR CONTROL OR 
      OCT 6412
      ASC 14,     PRIORITY CHAIN BROKEN/
      SPC 2 
* 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
*             1. HIGH 
*             2. NOT LOW
*             3. NOT FENCE
* 
FCCR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E031  JSB ERMS,I    REPORT ERROR
      DEF MS031 
      JMP CCT,I     EXIT
MS031 ASC 16,E031 CLC SC CAUSED FLAG TO SET/
      SPC 2 
HCCR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP CCT,I     EXIT
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 3
* 
*     INITIATION SECTION
* 
*     CNTL.FLG
*     HI SC SET TO INT
* 
TST03 EQU * 
PST   NOP 
      LDB BTCK      CHECK FOR 
      JSB SWRT,I              TEST SUPPRESS 
      JMP PST,I     YES 
      LDA HPSJ      SET 
HSC07 STA HSC           UP
      LDA FPSJ             INT
FSC07 STA FCH                  RETURN 
FSC02 OTA FCH       SET FENCE TO
FSC03 STC FCH                    LOWER PRIORITY 
L032  JSB MSGH,I    TELL OPERATOR TO
      DEF MS032      " PRESS PRESET, RUN "
HSC02 STF HSC       SET HI SC 
HSC03 STC HSC                 TO INT
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E033  JSB ERMS,I    REPORT ERROR
      DEF MS033 
      JMP PST,I     EXIT
MS032 ASC 14,H032 PRESS PRESET(EXT), RUN/ 
MS033 ASC 20,E033 PRESET(EXT) FAILED TO CLEAR CONTROL 
      OCT 6412
      ASC 21,     AND-OR FLAG OR PRIORITY CHAIN BROKEN/ 
      SKP 
* 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
*             1. HIGH 
*             2. NOT LOW
*             3. NOT FENCE
* 
FPSR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E034  JSB ERMS,I    REPORT ERROR
      DEF MS034 
      JMP PST,I     EXIT
MS034 ASC 18,E034 FENCE INT'D AFTER PRESET(EXT)/
      SPC 3 
HPSR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP PST,I     EXIT
BTCK  OCT 10400 
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 4
* 
*     INITIATION SECTION
* 
*        CNTLF.FLGF 
*        LO/HI SC SET TO INTERRUPT
* 
TST04 EQU * 
CNAFN NOP 
      LDA H00J      SET 
HSC20 STA HSC           UP
      LDA F00J             INT
FSC20 STA FCH                  RETURN 
      LDA L00J                        POINTS
LSC20 STA LSC                                *
      CLA           CLEAR LOW 
      STA L00P,I            RETURN FLAG 
      JSB LHSU      SET UP HI/LO SC'S 
FSC10 CLF FCH       SET FENCE CH
FSC11 CLC FCH                    FOR NO ACTION
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E040  JSB ERMS,I    REPORT ERROR
      DEF MS040        " NO INT RECEIVED FROM LO/HI"
      JMP CNAFN,I   EXIT
* 
MS040 ASC 19,E040 NO INT RECEIVED FROM LO OR HI SC/ 
      SPC 2 
* 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
* 
*             1. LOW
*             2. HIGH 
*             3. NOT FENCE
* 
L00R  NOP 
      CLF INTP      TURN OFF INTS 
LSC04 CLC LSC       CLEAR HI CH 
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E041  JSB ERMS,I    REPORT ERROR
      DEF MS041 
      JMP CNAFN,I   EXIT
MS041 ASC 21,E041 HI SC DID NOT INTERRUPT AFTER LO SC/
      SKP 
* 
F00R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L00R
      SZA           TEST FOR HI INT ? 
      JMP E043      YES 
E042  JSB ERMS,I    NO, REPORT ERROR
      DEF MS042 
      JMP CNAFN,I   EXIT
E043  JSB ERMS,I    REPORT ERROR
      DEF MS043 
      JMP CNAFN,I   EXIT
MS042 ASC 20,E042 FENCE INT'D BEFORE LO SC INT'D BUT
      OCT 6412
      ASC 12,     FENCE FLAG NOT SET/ 
MS043 ASC 19,E043 FENCE INT'D AFTER LO SC INT'D BUT 
      OCT 6412
      ASC 12,     FENCE FLAG NOT SET/ 
      SPC 2 
* 
H00R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L00R
      SZA           TEST FOR LO INT ? 
      JMP CNAFN,I   YES, EXIT 
E044  JSB ERMS,I    NO, REPORT ERROR
      DEF MS044 
      JMP CNAFN,I   EXIT
MS044 ASC 15,E044 HI SC INT'D BEFORE LO SC/ 
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 5
* 
*     INITIATION SECTION
* 
*        CNTL.FLGF
*        LO/HI SC SET TO INTERRUPT
* 
      ORG 4000B 
TST05 EQU * 
CAFN  NOP 
      LDA H10J      SET 
HSC21 STA HSC           UP
      LDA F10J             INT
FSC21 STA FCH                  RETURN 
      LDA L10J                        POINTS
LSC21 STA LSC                                *
      CLA           CLEAR LOW 
      STA L10P,I          RETURN POINT FLAG 
      JSB LHSU      SET UP HI/LO SC'S 
FSC12 CLF FCH       SET FENCE TO
FSC13 STC FCH               LOWER PRIORITY
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E050  JSB ERMS,I    REPORT ERROR
      DEF MS050 
      JMP CAFN,I    EXIT
MS050 ASC 16,E050 NO INT RECEIVED FROM LO SC/ 
* 
      SPC 2 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
* 
*            1. LOW 
*            2. NOT FENCE 
*            3. NOT HIGH
* 
L10R  NOP 
      CLF INTP      TURN OFF INTS 
LSC05 CLC LSC       CLEAR LOW SC
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP CAFN,I    EXIT
      SKP 
F10R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L10R
      SZA           TEST FOR LO INT ? 
      JMP E052      YES 
E051  JSB ERMS,I    REPORT ERROR
      DEF MS051 
      JMP CAFN,I    EXIT
E052  JSB ERMS,I    REPORT ERROR
      DEF MS052 
      JMP CAFN,I         EXIT 
MS051 ASC 18,E051 FENCE INT'D BEFORE LO SC WITH 
      OCT 6412
      ASC 12,     FENCE CONTROL SET/
MS052 ASC 17,E052 FENCE INT'D AFTER LO SC INT'D 
      OCT 6412
      ASC 14,     WITH FENCE CONTROL SET/ 
      SPC 3 
* 
* 
* 
H10R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L10R
      SZA           TEST FOR LO INT ? 
      JMP E054      YES 
E053  JSB ERMS,I    NO, REPORT ERROR
      DEF MS053 
      JMP CAFN,I    EXIT
E054  JSB ERMS,I    REPORT ERROR
      DEF MS054 
      JMP CAFN,I    EXIT
MS053 ASC 19,E053 LO SC DID NOT INT BUT HI SC INT'D 
      OCT 6412
      ASC 10,     WITH FENCE UP/
MS054 ASC 17,E054 HI SC INT'D AFTER LO SC INT'D 
      OCT 6412
      ASC 11,     BUT FENCE WAS UP/ 
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 6
* 
*     INITIATION SECTION
* 
*        CNTL.FLG 
*        LO/HI SC SET TO INTERRUPT
* 
TST06 EQU * 
CAF   NOP 
      LDA H11J      SET 
HSC22 STA HSC           UP
      LDA F11J             INT
FSC22 STA FCH                  RETURN 
      LDA L11J                        POINTS
LSC22 STA LSC                                *
      CLA           CLEAR LOW 
      STA L11P,I          RETURN POINT FLAG 
      JSB LHSU      SET UP HI/LO SC'S 
FSC14 STC FCH       SET FENCE TO
FSC15 OTA FCH               LOWER PRIORITY
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E060  JSB ERMS,I    REPORT ERROR
      DEF MS060 
      JMP CAF,I     EXIT
MS060 ASC 16,E060 NO INT RECEIVED FROM LO SC/ 
* 
      SKP 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
* 
*            1. LOW 
*            2. NOT FENCE 
*            3. NOT HIGH
* 
L11R  NOP 
      CLF INTP      TURN OFF INTS 
LSC06 CLC LSC       CLEAR LO SC 
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      JMP CAF,I     EXIT
      SPC 1 
* 
F11R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L11R
      SZA           TEST FOR LO INT ? 
      JMP E062      YES 
E061  JSB ERMS,I    REPORT ERROR
      DEF MS061 
      JMP CAF,I     EXIT
E062  JSB ERMS,I    REPORT ERROR
      DEF MS062 
      JMP CAF,I     EXIT
MS061 ASC 20,E061 FENCE INT'D BEFORE LO SC BUT FENCE
      OCT 6412
      ASC 13,     FLAG AND CONTROL SET/ 
MS062 ASC 17,E062 FENCE INT'D AFTER LO SC INT'D 
      OCT 6412
      ASC 15,     BUT FLAG AND CONTROL SET/ 
      SPC 1 
* 
H11R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA L11R
      SZA 
      JMP E064      YES 
E063  JSB ERMS,I    NO, REPORT ERROR
      DEF MS063 
      JMP CAF,I     EXIT
E064  JSB ERMS,I    REPORT ERROR
      DEF MS064 
      JMP CAF,I     EXIT
MS063 ASC 19,E063 LO SC DID NOT INT BUT HI SC INT'D 
      OCT 6412
      ASC 10,     WITH FENCE UP/
MS064 ASC 17,E064 HI SC INT'D AFTER LO SC INT'D 
      OCT 6412
      ASC 09,     BUT FENCE UP/ 
      HED 12936 PRIVILEGED INT DIAG - TEST 7
* 
*     INITIATION SECTION
* 
*        CNTLF.FLG
*        HI/FENCE SC SET TO INT 
*     LO SET TO INT AFTER FENCE INT 
* 
TST07 EQU * 
CNAF  NOP 
      LDA H01J      SET 
HSC23 STA HSC           UP
      LDA F01J             INT
FSC23 STA FCH                  RETURN 
      LDA L01J                        POINTS
LSC23 STA LSC                                *
      CLA           CLEAR HI/FENCE
      STA L01P,I          RETURN POINT FLAG 
      STA F01P,I
HSC10 STC HSC       SET HI SC 
HSC11 STF HSC                 TO INT
FSC16 CLC FCH       SET FENCE TO INT
FSC17 OTA FCH                 AND LOWER PRIORITY
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E100  JSB ERMS,I    REPORT ERROR
      DEF MS100 
      JMP CNAF,I    EXIT
MS100 ASC 21,E100 NO INT RECEIVED FROM FENCE OR HI SC/
* 
      SKP 2 
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
* 
*            1. FENCE 
*            2. LOW 
*            3. HIGH
* 
L01R  NOP 
      CLF INTP      TURN OFF INTS 
      LDA F01R
      SZA,RSS       TEST FOR FENCE INT ?
      JMP E102-1    NO
LSC13 CLC LSC       CLEAR LO SC 
FSC01 CLF FCH       CLEAR FENCE SC
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E101  JSB ERMS,I    REPORT ERROR
      DEF MS101 
      JMP CNAF,I    EXIT
      JSB TOS       TURN OFF ALL DEVICES
E102  JSB ERMS,I    REPORT ERROR
      DEF MS102 
      JMP CNAF,I    EXIT
MS101 ASC 18,E101 HI SC DID NOT INT AFTER LO SC/
MS102 ASC 15,E102 LO SC INT'D BEFORE FENCE/ 
      SPC 3 
* 
F01R  NOP 
      CLF INTP      TURN OFF INTS 
LSC03 STC LSC       SET HI CH 
LSC02 STF LSC                  TO INT 
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E103  JSB ERMS,I    REPORT ERROR
      DEF MS103 
      JMP CNAF,I    EXIT
MS103 ASC 18,E103 LO SC DID NOT INT AFTER FENCE/
      SPC 3 
H01R  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
      LDA F01R
      SZA,RSS       TEST FOR FENCE INT ?
      JMP E104      NO
      LDA L01R      YES 
      SZA           TEST FOR LO INT ? 
      JMP CNAF,I    YES 
E105  JSB ERMS,I    REPORT ERROR
      DEF MS105 
      JMP CNAF,I    EXIT
E104  JSB ERMS,I    NO, REPORT ERROR
      DEF MS104 
      JMP CNAF,I    EXIT
MS104 ASC 18,E104 HI SC INT'D BUT FENCE AND LO SC 
      OCT 6412
      ASC 09,     DID NOT INT/
MS105 ASC 17,E105 HI SC INT'D AFTER FENCE INT'D 
      OCT 6412
      ASC 14,     BUT BEFORE LO SC INT'D/ 
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 8
* 
*     INITIATION SECTION
* 
*         CNTL.FLG
*         LO/FENCE SET TO INT 
*     FENCE SET TO INT AFTER LOW
* 
TST08 EQU * 
LFPRT NOP 
      LDA LPRJ      SET 
LSC14 STA LSC           UP
      LDA FPRJ             INT
FSC25 STA FCH                  RTN  PTS 
      CLA           CLEAR HI CH 
      STA LPRP,I          RETURN POINT FLAG 
LSC15 STC LSC       SET LO SC 
LSC16 STF LSC                 TO INT
FSC26 OTA FCH       SET FENCE TO INT
FSC27 CLC FCH                AND LOWER PRIORITY 
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                  *
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E200  JSB ERMS,I    REPORT ERROR
      DEF MS200 
      JMP LFPRT,I  EXIT 
MS200 ASC 21,E200 NO INT RECEIVED FROM FENCE OR LO SC/
* 
*     COMPLETION SECTIONS 
* 
*         INTERRUPT SEQUENCE
* 
*            1. LO
*            2. FENCE 
* 
LPRR  NOP 
      CLF INTP      TURN OFF INTS 
LSC17 CLC LSC       TURN OFF LO SC
      STF INTP      TURN ON INTS
      NOP           DELAY 
      NOP                 * 
      NOP                   * 
      CLF INTP      TURN OFF INTS 
      JSB TOS       TURN OFF ALL DEVICES
E201  JSB ERMS,I    REPORT ERROR
      DEF MS201 
      JMP LFPRT,I   EXIT
MS201 ASC 18,E201 FENCE DID NOT INT AFTER LO SC/
      SPC 2 
FPRR  NOP 
      CLF INTP      TURN OFF INTS 
      JSB TOS 
      LDA LPRR
      SZA           TEST FOR LO INT ? 
      JMP LFPRT,I   YES 
E202  JSB ERMS,I    NO, REPROT ERROR
      DEF MS202 
      JMP LFPRT,I   EXIT
MS202 ASC 15,E202 FENCE INT'D BEFORE LO SC/ 
* 
      HED 12936 PRIVILEGED INT DIAG - TEST 9
* 
*     SCLP PROVIDES A SCOPE LOOP OF FENCE FLAG/CNTL 
*          SET AND THEN CLEARED WITH AND WITHOUT INTS ON
* 
TST09 EQU * 
SCLP  NOP 
      CLA 
FSC40 STA FCH 
FSC30 STC FCH       SET FENCE CONTROL 
      NOP 
FSC31 OTA FCH       SET FENCE FLAG
      NOP 
FSC32 CLC FCH       CLEAR FENCE CONTROL 
      NOP 
FSC33 CLF FCH       CLEAR FENCE FLAG
      STF INTP      TURN ON INT 
FSC34 STC FCH       SET FENCE CONTROL 
      NOP 
FSC35 OTA FCH       SET FENCE FLAG
      NOP 
FSC36 CLC FCH       CLEAR FENCE CONTROL 
      NOP 
FSC37 CLF FCH       CLEAR FENCE FLAG
      CLF INTP      TURN OFF INTS 
      LDB BT9       CHECK FOR EXIT
      LIA 1 
      AND B 
      SZA           TEST FOR EXIT 
      JMP SCLP,I
      JMP FSC30     NO
BT9   OCT 1000
FWAA  EQU * 
      JSB ERMS,I
      DEF MS030 
      JSB ERMS,I
      DEF MS031 
      JSB ERMS,I
      DEF MS032 
      JSB ERMS,I
      DEF MS033 
      JSB ERMS,I
      DEF MS034 
      JSB ERMS,I
      DEF MS035 
      JSB ERMS,I
      DEF MS036 
      JSB ERMS,I
      DEF MS040 
      JSB ERMS,I
      DEF MS041 
      JSB ERMS,I
      DEF MS042 
      JSB ERMS,I
      DEF MS043 
      JSB ERMS,I
      DEF MS044 
      JSB ERMS,I
      DEF MS050 
      JSB ERMS,I
      DEF MS051 
      JSB ERMS,I
      DEF MS052 
      JSB ERMS,I
      DEF MS053 
      JSB ERMS,I
      DEF MS054 
      JSB ERMS,I
      DEF MS060 
      JSB ERMS,I
      DEF MS061 
      JSB ERMS,I
      DEF MS062 
      JSB ERMS,I
      DEF MS063 
      JSB ERMS,I
      DEF MS064 
      JSB ERMS,I
      DEF MS100 
      JSB ERMS,I
      DEF MS101 
      JSB ERMS,I
      DEF MS102 
      JSB ERMS,I
      DEF MS103 
      JSB ERMS,I
      DEF MS104 
      JSB ERMS,I
      DEF MS105 
      JSB ERMS,I
      DEF MS200 
      JSB ERMS,I
      DEF MS201 
      JSB ERMS,I
      DEF MS202 
      HLT 66B 
      END 
                                                                                                      