ASMB,L
      HED ".VSRP" - RPL'ING OF:  VADD VSUB VMPY VDIV VSAD VSSB VSMY VSDV .
      NAM .VSRP,7 12824-1X046 REV.2026 800506 
      EXT .VECT 
      ENT VADD,VSUB,VMPY,VDIV,VSAD,VSSB,VSMY,VSDV 
**************************************************************
* 
*     NAME:   .VSRP 
*     SOURCE: 12824-18046 
*     RELOC:  PART OF 12824-12001 
*     PGMR:   BG,CG 
* 
*  ***********************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,  *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE    *
*  * WITHOUT THE PRIOR CONSENT OF HEWLETT-PACKARD COMPANY.   *
*  ***********************************************************
* 
**************************************************************
* 
A     EQU 0 
B     EQU 1 
* 
*     .VCT REPLACES CALLS TO VADD...VSDV WITH THE APPROPRIATE 
*     TWO-WORD OPCODE. IF THE MAIN OPCODE IS NOT RPL'D, IT
*     FAKES A JSB INSTEAD OF REPLACING THE ORIGINAL JSB.
* 
VADD  NOP 
      JSB COM 
      OCT 000000
* 
VSUB  NOP 
      JSB COM 
      OCT 000020
* 
VMPY  NOP 
      JSB COM 
      OCT 000040
* 
VDIV  NOP 
      JSB COM 
      OCT 000060
* 
VSAD  NOP 
      JSB COM 
      OCT 000400
* 
VSSB  NOP 
      JSB COM 
      OCT 000420
* 
VSMY  NOP 
      JSB COM 
      OCT 000440
* 
VSDV  NOP 
      JSB COM 
      OCT 000460
* 
COM   NOP 
      LDA COM,I     A = SUB-OPCODE. 
      LDB COM       GET ADDRESS + 1 OF ORIGINAL JSB.
      ADB =D-2
      LDB B,I 
      STA B,I       OVERLAY ORIGNAL RTN PTR WITH SUB-OPCODE.
      LDA OPCOD     A = MAIN OPCODE.
      SSA,RSS       SOFTWARE ?
      JMP SOFT      YES, SPECIAL CASE.
      ADB =D-1      NO. OVERLAY ORIGINAL JSB WITH MAIN OPCODE.
      STA B,I 
      JMP B,I       GO EXECUTE THE OPCODE.
* 
SOFT  STB A,I       FAKE A JSB TO THE SOFTWARE. FIRST, RTN ADDR.
      INA           THEN, 
      JMP A,I        THE ENTRY. 
* 
OPCOD DEF .VECT+0 
      END 
                                                                                                                                                                                                                                                        