ASMB,L
      HED "WVMOV" - SINGLE PRECISION VECTOR MOVE FROM EMA.
      NAM WVMOV,7 12824-1X023 REV.2026 800506 
* 
      ENT WVMOV 
**************************************************************
* 
*     NAME:   WVMOV 
*     SOURCE: 12824-18023 
*     RELOC:  PART OF 12824-12001 
*     PGMR:   BG,CG 
* 
*  ***********************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,  *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE    *
*  * WITHOUT THE PRIOR CONSENT OF HEWLETT-PACKARD COMPANY.   *
*  ***********************************************************
* 
**************************************************************
      EXT VMOV,.WCOM,.ENTR
* 
A     EQU 0 
B     EQU 1 
* 
*                   FOR DETAILS SEE ".WCOM" . 
      SPC 3 
*                   SWAP V1 & V2 BEFORE INTERFACE.
* 
V1    DEF *-* 
IX1   DEF *-* 
V2    DEF *-* 
IX2   DEF *-* 
N     DEF *-* 
WVMOV NOP 
      JSB .ENTR     COPY PARAM ADDRESSES. 
      DEF V1
      JSB MOVE1     CALL INTERFACE BUT SWAP V1 & V2.
      DEF *+5+1 
      DEF V2,I
      DEF IX2,I 
      DEF V1,I
      DEF IX1,I 
      DEF N,I 
      JMP WVMOV,I   EXIT. 
* 
*                   INTERFACE CALL. 
* 
MOVE1 NOP 
      JSB .WCOM 
      DEF MOVE2     (GO THRU SECOND SWAP) 
      BYT 2,1 
      ABS 511+0     2 WORDS / ELEMENT, NO FLAGS.
* 
*                   SWAP V1 & V2 BETWEEN INTERFACE & MICROCODE. 
* 
V1A   DEF *-* 
IX1A  DEF *-* 
V2A   DEF *-* 
IX2A  DEF *-* 
NA    DEF *-* 
MOVE2 NOP 
      JSB .ENTR     COPY PARAM ADDRESSES. 
      DEF V1A 
      JSB VMOV      CALL MICROCODE WITH SWAPPED V1 & V2.
      DEF *+5+1 
      DEF V2A,I 
      DEF IX2A,I
      DEF V1A,I 
      DEF IX1A,I
      DEF NA,I
* 
*                   UPDATE NON-EMA ADDRESS. 
* 
      LDA IX1A,I    COMPUTE OFFSET. 
      MPY NA,I
      ALS 
      ADA V1A       ADD BASE. 
      LDB MOVE2     FIND ADDRESS IN CALLING SEQ.
      ADB =D-5
      STA B,I       STORE NEW ADDR. 
      JMP MOVE2,I   EXIT. 
      END 
                                                                                                                                                  