TNS   NOP 
      SPC 2 
*     CHECK FOR THREE SYNC PATTERNS FOLLOWED BY A DATA PATTERN WITH 
*     AUTO-SYNC ON. 
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      CLA 
      STA DFLAG     (OUTPUT DATA FLAG IN SYNC CHAR) 
      LDA CW11
      JSB OTACH 
      JSB DELAY 
      LDA CW11      SEND, AUTO ON 150014
      STA CWX 
      JSB MCLR
      LDA TDATA 
      JSB OTACH     OUTPUT DATA TO BUFFER 
      LDA TSYNC 
      JSB OTACH     OUTPUT SYNC TO BUFFER 
      JSB SSNCH     SEND 1ST SYNC PATTERN 
E200  JSB ERROR     1ST SYNC INCORRECT
      JSB SW8      (HALT SELECTION) 
      JSB SW7      (LOOP) 
      JSB SSNCH     SEND 2ND SYNC PATTERN 
E201  JSB ERROR     2ND SYNC INCORRECT
      JSB SW8      (HALT) 
      JSB SW7      (LOOP) 
      CLA,INA 
      STA DFLAG     OTA DATA BEFORE LAST BIT TOGGLE 
      JSB SSNCH     SEND 3RD SYNC PATTERN 
E202  JSB ERROR     3RD SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSDTA     SEND DATA 
E203  JSB ERROR     DATA INCORRECT
      JSB SW8 
      JSB SW7 
      SKP 
*     CHECK FOR THREE SYNC PATTERNS FOLLOWED BY FOUR
*     MORE SYNC PATTERNS FOLLOWED BY A DATA PATTERN 
*     WITH AUTO-SYNC ON.
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      CLA 
      STA DFLAG 
      LDA CW11
      JSB OTACH 
      JSB DELAY 
      LDA CW11      SEND,AUTO ON   150014 
      STA CWX 
      JSB MCLR
      CLC 0 
      LDA TSYNC 
      JSB OTACH 
      JSB SSNCH 
E204  JSB ERROR     1ST SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E205  JSB ERROR     2ND SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E206  JSB ERROR     3RD SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E207  JSB ERROR     4TH SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E210  JSB ERROR     5TH SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E211  JSB ERROR     6TH SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      CLA,INA 
      STA DFLAG 
      JSB SSNCH 
E212  JSB ERROR     7TH SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSDTA 
E213  JSB ERROR     DATA INCORRECT
      JSB SW8 
      JSB SW7 
      SKP 
*     CHECK FOR DATA SEND TWICE FOLLOWED BY A 
*     RECEIVE MODE CONTROL WORD FOLLOWED BY THREE 
*     SYNCS.  THE BOARD SHOULD NOT SEND BUT FORCING 
*     A TOGGLE SHOULD RETURN ALL ONE'S. TEST WITH 
*     AUTO-SYNC ON. 
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW11
      JSB OTACH 
      JSB DELAY 
      LDA CW11      SEND, AUTO ON  150014 
      STA CWX 
      JSB MCLR
      LDA TSYNC 
      JSB OTACH 
      JSB SEND3     SEND 3 SYNCS WITH DATA
      CLA,INA 
      STA DFLAG 
      JSB SSDTA 
E214  JSB ERROR     1ST DATA INCORRECT
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSDTA 
E215  JSB ERROR     2ND DATA INCORRECT
      JSB SW8 
      JSB SW7 
      LDA CW12      RECEIVE MODE, AUTO-SYNC ON
      STA CWX 
      JSB OTACH 
      CLA 
      STA DFLAG 
      JSB SSNCH 
E216  JSB ERROR     1ST SYNC ERROR
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E217  JSB ERROR     2ND SYNC ERROR
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E220  JSB ERROR     3RD SYNC ERROR
      JSB SW8 
      JSB SW7 
      JSB SCHAR 
      LDA DIN 
      CPA TSNC2     ALL 1'S?
      RSS           YES 
E221  JSB ERROR     INPUT SHOULD BE 1'S 
      JSB SW8 
      JSB SW7 
      SKP 
*     CHECK FOR DATA SEND TWICE FOLLOWED BY FOUR
*     SYNCS WITH AUTO-SYNC ON.
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW11
      JSB OTACH 
      JSB DELAY 
      LDA CW11      SEND, AUTO ON  150014 
      STA CWX 
      JSB MCLR
      LDA TSYNC 
      JSB OTACH 
      JSB SEND3     SEND 3 SYNCS WITH DATA
      CLA,INA 
      STA DFLAG 
      JSB SSDTA 
E222  JSB ERROR     1ST DATA INCORRECT
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSDTA 
E223  JSB ERROR     2ND DATA INCORRECT
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSNCH 
E224  JSB ERROR     1ST SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E225  JSB ERROR     2ND SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E226  JSB ERROR     3RD SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      JSB SSNCH 
E227  JSB ERROR     4TH SYNC INCORRECT
      JSB SW8 
      JSB SW7 
      SKP 
*     CHECK FOR NO SYNC SENT WHEN AUTO-SYNC OFF. A
*     FORCED TOGGLE SHOULD TRANSFER 0'S.
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW13
      JSB OTACH 
      JSB DELAY 
      LDA CW13      SEND, AUTO OFF
      STA CWX 
      JSB MCLR
      LDA TSYNC 
      JSB OTACH 
      CLA 
      STA DFLAG 
      JSB SCHAR 
      LDA DIN 
      CPA TSNC3     ALL 0'S?
      RSS           YES 
E230  JSB ERROR     INPUT SHOULD BE 0'S 
      JSB SW8 
      JSB SW7 
      SKP 
*     CHECK FOR DATA SENT, DATA REPEAT. THEN SEND A 
*     RECEIVE MODE CONTROL WORD AND CHECK FOR ALL 
*     ONE,S BY FORCING A TOGGLE. TEST WITH AUTO-SYNC
*     OFF.
      SPC 2 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW13
      JSB OTACH 
      JSB DELAY 
      LDA CW13      SEND, AUTO OFF
      STA CWX 
      JSB MCLR
      CLC 0 
      LDA TSYNC 
      JSB OTACH 
      LDA TDATA 
      JSB OTACH 
      CLA 
      STA DFLAG 
      JSB SSDTA     SEND DATA (ONCE ONLY) 
E231  JSB ERROR     DATA ERROR
      JSB SW8 
      JSB SW7 
      CLA 
      STA DFLAG 
      JSB SSDTA     SEND SYNC (SHOULD = DATA) 
E232  JSB ERROR     SYNC CHAR NOT EQUAL TO DATA 
      JSB SW8 
      JSB SW7 
      LDA CW14      RECEIVE MODE, AUTO-SYNC OFF 
      STA CWX 
      JSB OTACH 
      JSB SCHAR 
      LDA DIN 
      CPA TSNC2     ALL 1'S?
      RSS           YES 
E233  JSB ERROR     INPUT SHOULD BE 1'S 
      JSB SW8 
      JSB SW7 
      JMP TNS,I     EXIT *****
      SKP 
SSNCH NOP           SEND SYNC 
      JSB SCHAR 
      LDA DIN 
      CPA TSNC1     SYNC OK?
      ISZ SSNCH     YES 
      JMP SSNCH,I 
      SPC 2 
SSDTA NOP           SEND DATA 
      JSB SCHAR 
      LDA DIN 
      CPA TDATA     DATA OK?
      ISZ SSDTA     YES 
      JMP SSDTA,I 
      SPC 2 
SCHAR NOP           SEND CHARACTER
      CLA 
      STA DIN       RESET DATA IN 
      LDA P7774 
      STA SNBB
FLOP  ISZ SNBB      NEXT TO LAST BIT? 
      JMP FLP       NO
      LDA DFLAG     YES 
      SZA,RSS       OUTPUT DATA?
      JMP FLP       NO
      LDA TDATA     YES 
      JSB OTACH 
FLP   LDA CWX       CONTROL WD
      JSB TOGLE     OUTPUT ONE BIT
      JSB LIACH     RETURN
      CMA 
      AND BT11        THE BIT 
      IOR DIN 
      RAR 
      STA DIN       STACK BITS
      LDB SNBB
      SZB           FINISHED? 
      JMP FLOP      NO
      ALF,ALF       YES, NORMALIZE BITS 
      RAL            (RT JUSTIFIED) 
      STA DIN 
      JMP SCHAR,I   EXIT
      SPC 2 
SEND3 NOP           SEND 3 SYNCS WITH A DATA OTA
      CLA              BEFORE LAST BIT
      STA DFLAG 
      JSB SCHAR 
      JSB SCHAR 
      CLA,INA 
      STA DFLAG 
      JSB SCHAR 
      JMP SEND3,I 
      HED ASON - SEND (AUTO-ON) - SEND INTERFACE DIAGNOSTIC 
ASON  NOP 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW3 
      JSB OTACH 
      JSB DELAY 
      LDA CW3       150017 CNTL WD - NO PARITY, AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW3 
      JSB INP       INITIALIZE PROGRAM
NTST  JSB TEST      SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP OTST      YES - GO TO NEXT TEST 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETNP     NO - INITIALIZE NEXT CHARACTER
      JMP NTST        SIZE AND REPEAT THE TEST
      SPC 2 
OTST  NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW5 
      JSB OTACH 
      JSB DELAY 
      LDA CW5       156016 CNTL WD - ODD PARITY,AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW5 
      JSB IOP       INITIALIZE PROGRAM
OTSOT JSB TEST      SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP ETST      YES - GO TO NEXT TEST 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETOP     NO - INITIALIZE NEXT CHARACTER
      JMP OTSOT       SIZE AND REPEAT TEST
      SPC 2 
ETST NOP            (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW7 
      JSB OTACH 
      JSB DELAY 
      LDA CW7       154016 CNTL WD, EVEN PARITY,AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW7 
      JSB IEP       INITIALIZE PROGRAM
ETSET JSB TEST      SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP ASON,I    YES - EXIT PROGRAM ******** 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETEP     NO - INITIALIZE NEXT CHARACTER
      JMP ETSET       SIZE AND REPEAT TEST
      SPC 2 
TEST  NOP 
      NOP           (EXTRA INSTRUCTION) 
      LDA TRW 
      JSB MCLR
      JSB SC3 
TLOOP JSB SDTA
      JSB SENDD     SEND DATA CHARACTER 
      LDA DIN       DATA IN FROM INTERFACE
      CPA WD1       DATA COMPARE OK?
      JMP CHST      YES 
      STA SAVE      NO, REPORT ERROR
      LDB MG53D     WORD RECEIVED 
      JSB DATA
      LDA WD1 
      STA SAVD
      LDB MG53C     WORD SENT 
      JSB DATA
      LDA CHCNT 
      STA SAVB
      IOR AC        ASCII 
      STA MG53B,I   NO. OF BITS IN WORD 
      LDA PAR 
      STA SAVA
      LDB MG53A     STUFF PROPER PARITY MODE INTO 
      JSB PARTY       MESSAGE 
      LDA E54 
      JSB MHLT5     RTN *+2 IF NO TTY SELECTED
E53   JSB ERROR     * DATA ERROR
CHST  JSB SW8      HALT AT END OF TEST (BIT 8)
      JSB SW7      LOOP ON LAST TEST (BIT 7)
      NOP           (EXTRA INSTRUCTION) 
      ISZ CNR       INCREMENT DATA PATTERN
      LDA PTNC,I
      ADA CNR 
      SZA           FINISHED? 
      JMP TLOOP     NO, SEND NEXT CHARACTER 
      JMP TEST,I    YES, EXIT 
      HED ASOFF - SEND (AUTO-OFF) - SEND INTERFACE DIAGNOSTIC 
ASOFF NOP 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW8 
      JSB OTACH 
      JSB DELAY 
      LDA CW8       151017 CNTL WD - NO PARITY MODE,
      JSB MCLR        AUTO OFF
      LDA CW8 
      JSB INP       INITIALIZE PROGRAM
FTST  JSB FTEST     SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP FOTST     YES, GO TO NEXT TEST
      NOP           (EXTRA INSTRUCTION) 
      JSB SETNP     NO, INITIALIZE NEXT CHARACTER 
      JMP FTST        SIZE AND REPEAT THE TEST
      SPC 2 
FOTST NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW9 
      JSB OTACH 
      JSB DELAY 
      LDA CW9       157016 CONTROL WORD - ODD PARITY
      JSB MCLR        MODE, AUTO OFF
      LDA CW9 
      JSB IOP       INITIALIZE PROGRAM
FOT   JSB FTEST     SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP FETST     YES, GO TO NEXT TEST
      NOP           (EXTRA INSTRUCTION) 
      JSB SETOP     NO, INITIALIZE NEXT CHARACTER 
      JMP FOT         SIZE AND REPEAT TEST
      SPC 2 
FETST NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW10
      JSB OTACH 
      JSB DELAY 
      LDA CW10      155016 CONTROL WORD, EVEN PARITY
      JSB MCLR        MODE, AUTO OFF
      LDA CW10
      JSB IEP       INITIALIZE PROGRAM
FET   JSB FTEST     SEND ALL PATTERNS 
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED WITH ALL CHAR SIZES? 
      JMP ASOFF,I   YES, EXIT PROGRAM ******* 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETEP     NO, INITIALIZE NEXT CHARACTER 
      JMP FET         SIZE AND REPEAT TEST
      SPC 2 
FTEST NOP 
      NOP           (EXTRA INSTRUCTION) 
      LDA TRW 
      JSB MCLR
      LDA SYNCH 
      JSB OTACH     OUTPUT SYNC WORD TO BUFFER
FLOOP JSB SDTA      OUTPUT DATA WD TO BUFFER
      JSB SENDD     SEND DATA CHARACTER 
      LDA DIN       DATA IN FROM INTERFACE
      CPA WD1       DATA COMPARE OK?
      JMP CHSF      YES 
      STA SAVE      NO, REPORT ERROR
      LDB MG67D     WORD RECEIVED 
      JSB DATA
      LDA WD1 
      STA SAVD
      LDB MG67C     WORD SENT 
      JSB DATA
      LDA CHCNT 
      STA SAVB
      IOR AC        ASCII 
      STA MG67B,I   NO. OF BITS IN WORD 
      LDA PAR 
      STA SAVA
      LDB MG67A     STUFF PARITY MODE INTO MESSAGE
      JSB PARTY 
      LDA E170
      JSB MHLT5     RTN *+2 IF NO TTY SELECTED
E167  JSB ERROR     * DATA ERROR
CHSF  JSB SW8      HALT AT END OF TEST (BIT 8)
      JSB SW7      LOOP ON LAST TEST (BIT 7)
      NOP           (EXTRA INSTRUCTION) 
      ISZ CNR       INCREMENT DATA PATTERN
      LDA PTNC,I
      ADA CNR 
      SZA           FINISHED? 
      JMP FLOOP     NO, SEND NEXT CHARACTER 
      JMP FTEST,I   YES, EXIT 
      SPC 2 
      SUP 
M10   ASC 18,E10. EXTERNAL PRESET DID NOT SET THE 
      ASC 03, FLAG
L10   EQU *+*-M10-M10 
      UNS 
      HED ASDTA - SYNC PATTERNS - SEND INTERFACE DIAGNOSTIC 
      ORG 4000B 
ASDTA NOP 
      NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW3 
      JSB OTACH 
      JSB DELAY 
      LDA CW3       150017 CNTL WD - NO PARITY, AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW3 
      JSB INP       INITIALIZE PROGRAM
ATEST JSB ASTST     SEND ALL SYNC PATTERNS
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINISHED? 
      JMP OST       YES 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETNP     NO - INITIALIZE 
      JMP ATEST       AND REPEAT
      SPC 2 
OST   NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW5 
      JSB OTACH 
      JSB DELAY 
      LDA CW5       156016 CNTL WD - ODD PARITY,AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW5 
      JSB IOP       INITIALIZE PROGRAM
OSTO  JSB ASTST     SEND ALL SYNC PATTERNS
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINI? 
      JMP EST       YES 
      NOP           (EXTRA INSTRUCTION) 
      JSB SETOP     NO - INITIALIZE 
      JMP OSTO        AND REPEAT
      SPC 2 
EST   NOP           (EXTRA INSTRUCTION) 
      JSB STN 
      LDA CW7 
      JSB OTACH 
      JSB DELAY 
      LDA CW7       154016 CNTL WD, EVEN PARITY,AUTO
      JSB MCLR      MASTER CLEAR INTERFACE
      LDA CW7 
      JSB IEP       INITIALIZE PROGRAM
ESTE  JSB ASTST     SEND ALL SYNC PATTERNS
      LDA MN8 
      ADA CHCNT 
      SZA,RSS       FINI? 
      JMP ASDTA,I   YES - EXIT *****
      NOP           (EXTRA INSTRUCTION) 
      JSB SETEP     NO - INITIALIZE 
      JMP ESTE        AND REPEAT
      SPC 2 
ASTST NOP 
      NOP           (EXTRA INSTRUCTION) 
      LDA TRW 
      JSB MCLR
      CLC 0 
ALOOP JSB SN        OUTPUT SYNC CHARACTER TO BUFFER 
      JSB SENCC     SEND SYNC CHARACTER 
      LDA DIN       SYNC IN FROM INTERFACE
      CPA WD1       SYNC OK?
      JMP AK        YES 
      STA SAVE      NO, REPORT ERROR
      LDB MG20D     WORD RECEIVED 
      JSB DATA
      LDA WD1 
      STA SAVD
      LDB MG20C     WORD SENT 
      JSB DATA
      LDA CHCNT 
      STA SAVB
      IOR AC        ASCII 
      STA MG20B,I   NO. OF BITS IN WORD 
      LDA PAR 
      STA SAVA
      LDB MG20A     STUFF PARITY MODE INTO MSG
      JSB PARTY 
      LDA E121
      JSB MHLT5     RTN *+2 IF NO TTY SELECTED
E120  JSB ERROR     * SYNC ERROR
AK    JSB SW8      HALT AT END OF TEST (BIT 8)
      JSB SW7      LOOP ON LAST TEST (BIT 7)
      NOP           (EXTRA INSTRUCTION) 
      ISZ CNR       INCREMENT DATA PATTERN
      LDA PTNC,I
      ADA CNR 
      SZA           FINISHED? 
      JMP ALOOP     NO, SEND NEXT CHARACTER 
      JMP ASTST,I   YES, EXIT 
      HED MESSAGES - SEND INTERFACE DIAGNOSTIC
      SUP 
AS0   ASC 2,  NO
AS1   ASC 2, ODD
AS2   ASC 2,EVEN
M0    ASC 18,E0. PRESET STATUS ERROR. STATUS IS 
M0A   ASC 11,XXXXXX AND SHOULD BE 
M0B   ASC 3,XXXXXX
L0    EQU *+*-M0-M0 
M1    ASC 17,E1. CLF DID NOT CLEAR FLAG, OR SFS 
      ASC 14, CAUSED SKIP WITH FLAG CLEAR 
L1    EQU *+*-M1-M1 
M2    ASC 18,E2. SFC DID NOT SKIP WITH FLAG CLEAR 
L2    EQU *+*-M2-M2 
M3    ASC 20,E3. STF DID NOT SET FLAG, OR SFC CAUSED
      ASC 9,SKIP WITH FLAG SET
L3    EQU *+*-M3-M3 
M4    ASC 17,E4. SFS DID NOT SKIP WITH FLAG SET 
L4    EQU *+*-M4-M4 
M5    ASC 11,E5. DID NOT INTERRUPT
L5    EQU *+*-M5-M5 
M6    ASC 19,E6. THE RETURN ADDRESS IS NOT CORRECT
L6    EQU *+*-M6-M6 
M11   ASC 7,H11. END BI/O 
L11   EQU *+*-M11-M11 
M12   ASC 18,E12. INTERNAL PRESET DID NOT DISABLE 
      ASC 06, INTERRUPTS
L12   EQU *+*-M12-M12 
M13   ASC 19,E13. EXTERNAL PRESET DID NOT SET FLAG
      OCT 6412
      ASC 18,AND INTERNAL PRESET DID NOT DISABLE
      ASC 05,INTERRUPTS 
L13   EQU *+*-M13-M13 
M14   ASC 17,E14. INTERRUPT ACKNOWLEDGE DID NOT 
      ASC 9, WORK. ABORT BI/O 
L14   EQU *+*-M14-M14 
M15   ASC 16,E15. CLC 0 DID NOT CLEAR CONTROL 
L15   EQU *+*-M15-M15 
M16   ASC 17,E16. EXTERNAL PRESET DID NOT CLEAR 
      ASC 04, CONTROL 
L16   EQU *+*-M16-M16 
M21   ASC 16,E21. STF 0 OR SFC 0 DID NOT WORK 
L21   EQU *+*-M21-M21 
M22   ASC 16,E22. STF 0 OR SFS 0 DID NOT WORK 
L22   EQU *+*-M22-M22 
M23   ASC 17,E23. CLC ON CHANNEL DID NOT CLEAR
      ASC 4,CONTROL 
L23   EQU *+*-M23-M23 
M24   ASC 20,E24. CLC CH,C DID NOT CLEAR FLAG OR SFC
      ASC 14,DID NOT SKIP WITH FLAG CLEAR 
L24   EQU *+*-M24-M24 
M30   ASC 18,E30. READY NOT RESET BY DATA OUTPUT
L30   EQU *+*-M30-M30 
M31   ASC 17,E31. STATUS ERROR - BIT 12 NOT = 1 
L31   EQU *+*-M31-M31 
M32   ASC 9,E32. FLAG NOT SET 
L32   EQU *+*-M32-M32 
M33   ASC 14,E33. STATUS ERROR - DATA IS
G33A  ASC 11,XXXXXX AND SHOULD BE 
G33B  ASC 3,XXXXXX
L33   EQU *+*-M33-M33 
M34   ASC 9,E34. FLAG NOT SET 
L34   EQU *+*-M34-M34 
M40   ASC 9,E40. FLAG NOT SET 
L40   EQU *+*-M40-M40 
M41   ASC 10,E41. FLAG NOT CLEAR
L41   EQU *+*-M41-M41 
M43   ASC 9,E43. FLAG NOT SET 
L43   EQU *+*-M43-M43 
M44   ASC 14,E44. STATUS ERROR - DATA IS
G44A  ASC 11,XXXXXX AND SHOULD BE 
G44B  ASC 3,XXXXXX
L44   EQU *+*-M44-M44 
M52   ASC 7,H52. END FCTST
L52   EQU *+*-M52-M52 
M53   ASC 18,E53. ERROR IN SEND DATA PATTERN TEST 
      ASC 10, WITH AUTO-SYNC ON.
      OCT 6412
G53A  ASC 13,XXXX PARITY MODE SELECTED, 
      ASC 9, CHARACTER SIZE IS
      OCT 6412
G53B  ASC 14,XX BITS, WORD RECEIVED WAS 
G53D  ASC 11,XXXXXX AND SHOULD BE 
G53C  ASC 3,XXXXXX
L53   EQU *+*-M53-M53 
M61   ASC 14,E61. STATUS ERROR - DATA IS
G61A  ASC 11,XXXXXX AND SHOULD BE 
G61B  ASC 3,XXXXXX
L61   EQU *+*-M61-M61 
M65   ASC 07,H65. END ASON
L65   EQU *+*-M65-M65 
M70   ASC 15,E70. PRESET FAILED, ABORT BI/O 
L70   EQU *+*-M70-M70 
M77   ASC 12,H77. DIAGNOSTIC COMPLETE 
L77   EQU *+*-M77-M77 
M120  ASC 17,E120. ERROR IN SYNC PATTERN TEST.
G20A  ASC 13,XXXX PARITY MODE SELECTED, 
      OCT 6412
      ASC 9,CHARACTER SIZE IS 
G20B  ASC 14,XX BITS, WORD RECEIVED WAS 
G20D  ASC 11,XXXXXX AND SHOULD BE 
      OCT 6412
G20C  ASC 3,XXXXXX
L120  EQU *+*-M120-M120 
M140  ASC 8,H140. END ASDTA 
L140  EQU *+*-M140-M140 
M167  ASC 19,E167. ERROR IN SEND DATA PATTERN TEST
      ASC 10,WITH AUTO-SYNC OFF.
      OCT 6412
G67A  ASC 13,XXXX PARITY MODE SELECTED, 
      ASC 9, CHARACTER SIZE IS
      OCT 6412
G67B  ASC 14,XX BITS, WORD RECEIVED WAS 
G67D  ASC 11,XXXXXX AND SHOULD BE 
G67C  ASC 3,XXXXXX
L167  EQU *+*-M167-M167 
M176  ASC 08,H176. END ASOFF
L176  EQU *+*-M176-M176 
M200  ASC 12,E200. 1ST SYNC INCORRECT 
L200  EQU *+*-M200-M200 
M201  ASC 12,E201. 2ND SYNC INCORRECT 
L201  EQU *+*-M201-M201 
M202  ASC 12,E202. 3RD SYNC INCORRECT 
L202  EQU *+*-M202-M202 
M203  ASC 10,E203. DATA INCORRECT 
L203  EQU *+*-M203-M203 
M204  ASC 12,E204. 1ST SYNC INCORRECT 
L204  EQU *+*-M204-M204 
M205  ASC 12,E205. 2ND SYNC INCORRECT 
L205  EQU *+*-M205-M205 
M206  ASC 12,E206. 3RD SYNC INCORRECT 
L206  EQU *+*-M206-M206 
M207  ASC 12,E207. 4TH SYNC INCORRECT 
L207  EQU *+*-M207-M207 
M210  ASC 12,E210. 5TH SYNC INCORRECT 
L210  EQU *+*-M210-M210 
M211  ASC 12,E211. 6TH SYNC INCORRECT 
L211  EQU *+*-M211-M211 
M212  ASC 12,E212. 7TH SYNC INCORRECT 
L212  EQU *+*-M212-M212 
M213  ASC 10,E213. DATA INCORRECT 
L213  EQU *+*-M213-M213 
M214  ASC 12,E214. 1ST DATA INCORRECT 
L214  EQU *+*-M214-M214 
M215  ASC 12,E215. 2ND DATA INCORRECT 
L215  EQU *+*-M215-M215 
M216  ASC 12,E216. 1ST SYNC INCORRECT 
L216  EQU *+*-M216-M216 
M217  ASC 12,E217. 2ND SYNC INCORRECT 
L217  EQU *+*-M217-M217 
M220  ASC 12,E220. 3RD SYNC INCORRECT 
L220  EQU *+*-M220-M220 
M221  ASC 14,E221. ALL ONE'S NOT RETURNED 
L221  EQU *+*-M221-M221 
M222  ASC 12,E222. 1ST DATA INCORRECT 
L222  EQU *+*-M222-M222 
M223  ASC 12,E223. 2ND DATA INCORRECT 
L223  EQU *+*-M223-M223 
M224  ASC 12,E224. 1ST SYNC INCORRECT 
L224  EQU *+*-M224-M224 
M225  ASC 12,E225. 2ND SYNC INCORRECT 
L225  EQU *+*-M225-M225 
M226  ASC 12,E226. 3RD SYNC INCORRECT 
L226  EQU *+*-M226-M226 
M227  ASC 12,E227. 4TH SYNC INCORRECT 
L227  EQU *+*-M227-M227 
M230  ASC 15,E230. ALL ZERO'S NOT RETURNED
L230  EQU *+*-M230-M230 
M231  ASC 10,E231. DATA INCORRECT 
L231  EQU *+*-M231-M231 
M232  ASC 13,E232. DATA DID NOT REPEAT
L232  EQU *+*-M232-M232 
M233  ASC 14,E233. ALL ONE'S NOT RETURNED 
L233  EQU *+*-M233-M233 
M270  ASC 07,H270. END TNS
L270  EQU *+*-M270-M270 
SM    ASC 18,H8. START SEND (ONLY) DATA INTERFACE 
      ASC 06, DIAGNOSTIC
SL    EQU *+*-SM-SM 
FWAM  EQU *         FIRST WORD AVAILABLE MEMORY 
      END 
                                                                                                                                                                                                                        