      LDB MG53C     WORD SENT 
      JSB DATAI,I 
      LDA CHCNT 
      STA SAVB
      IOR AC        ASCII 
      STA MG53B,I   NO. OF BITS IN WORD 
      LDA PAR 
      STA SAVA
      LDB MG53A     STUFF PROPER PARITY MODE INTO 
      JSB PARTY       MESSAGE 
      LDA E54 
      JSB BRCI,I    RTN *+2 IF NO TTP SELECTED
E53   JSB ERROR,I   * ERROR * 
CHSTT LDA TEMPA     CHECK STATUS
      AND BT158     100400
      CPA BT15      15 SHOULD BE 1, BIT 8 = 0 
      JMP CH37      (STATUS OK) 
      STA SAVA      REPORT STATUS ERROR 
      LDB MG61
      JSB DATAI,I 
      LDA BT15
      STA SAVB
      LDA E62 
      JSB BRAI,I    RTN *+2 IF NO TTP SELECTED
E61   JSB ERROR,I   * STATUS ERROR
CH37  SFS CH        CHECK FLAG
E67   JSB ERROR,I   * FLAG NOT SET - ERROR
      ISZ CNR       INCREMENT PATTERN 
      LDA PTNC,I    PATTERN COUNT 
      ADA CNR 
      SZA           FINISHED WITH ALL PATTERNS? 
      JMP RCV+1     NO, REPEAT
      JMP RCV,I     YES, EXIT 
      SKP 
PRTY  NOP           SET PARITY BIT INTO DATA
      LDA CNR 
      STA WD1 
      LDA CHCNT 
      CMA,INA 
      STA CHC 
      STA CHD 
      LDA PAR       0 = NO, 1 = ODD, 2 = EVEN PARITY
      SZA,RSS 
      JMP PRTY,I    NO PARITY, EXIT 
      CPA A0002 
      JMP EVN       EVEN PARITY 
      JSB PADD      ODD PARITY
      CMA 
EVEN  AND BT0 
      ALR 
      ISZ CHD 
      JMP *-2 
      IOR WD1       INCLUDE APPROPRIATE PARITY BIT
      STA WD1 
      JMP PRTY,I
EVN   JSB PADD
      JMP EVEN
      SPC 2 
PADD  NOP 
      LDB WD1       DATA TO B 
      CLA 
      ADA B 
      BRS 
      ISZ CHC 
      JMP *-3 
      JMP PADD,I    PARITY BIT IN A0
CHC   NOP 
CHD   NOP 
      SKP 
SEND  NOP           SEND BITS TO INTERFACE (RETRIEVE
      LDA BTNM       LATER) 
      IOR P7770 
      STA CHE       NO. OF BITS BEFORE FINAL SET
      LDA BTNM
      CMA,INA 
      STA CHF       NO. OF BITS IN FINAL SET
      AND A0007     IF 8 BIT MODE SELECTED, OMIT
      LDB WD1       SEND FIRST SET
      SZA,RSS         FIRST PART AND SEND ONLY FINAL
      JMP CLCC
      CLC 0 
HERE1 JSB SENDC 
      BRS 
      ISZ CHE 
      JMP HERE1 
CLCC  CLC 0 
HERE2 JSB SENDC     SEND FINAL SET
      BRS 
      ISZ CHF 
      JMP HERE2 
      JMP SEND,I
CHE   NOP 
CHF   NOP 
      SPC 2 
SENDC NOP           CHARACTER IN B
      JSB DEL10 
CH35  CLF CH
      LDA TRW 
      SLB,RSS 
      IOR BT6       DATA BIT
      IOR BT5         WITH CLOCK = 1
      JSB OTACH 
      AND NBT5      DATA BIT WITH CLOCK = 0 
      JSB OTACH 
      JSB DEL10 
      JMP SENDC,I 
      SKP 
INP   NOP           NO PARITY INITIALIZATION
      STA CWX 
      CLA,INA 
      STA CHCNT     CHARACTER SIZE, START WITH 1 BIT
      STA BTNM      BITS PLUS PARITY
      CLA 
      STA PAR       0 = NO PARITY 
      STA CNR       PATTERN COUNTER = 0 
      LDA TABL      MAX COUNT OF PATTERNS REQUIRED
      STA PTNC        FOR DIFFERENT CHAR. SIZES 
      LDA CHCNT 
      CMA,INA 
      AND A0017 
      IOR CWX       BASIC CONTROL WORD
      STA TRW 
      JMP INP,I 
      SPC 2 
IOP   NOP           ODD PARITY INITIALIZATION 
      STA CWX 
      CLA 
      STA CNR 
      CLA,INA 
      STA CHCNT 
      STA PAR       1 = ODD PARITY
      LDA TABL
      STA PTNC
      LDA CHCNT 
      CMA 
      AND A0017 
      IOR CWX 
      STA TRW 
      LDA A0002 
      STA BTNM
      JMP IOP,I 
      SPC 2 
IEP   NOP           EVEN PARITY INITIALIZATION
      JSB IOP 
      ISZ PAR 
      JMP IEP,I 
      SKP 
SETNP NOP           SET NO PARITY TABLES
      ISZ CHCNT 
      ISZ PTNC
      CLA 
      STA CNR 
      LDA CHCNT 
      CMA,INA 
      AND A0017 
      IOR CWX 
      STA TRW 
      LDA CHCNT 
      STA BTNM
      JMP SETNP,I 
      SPC 2 
SETOP EQU * 
SETEP NOP           SET EVEN PARITY TABLES
      ISZ CHCNT 
      ISZ PTNC
      CLA 
      STA CNR 
      LDA CHCNT 
      CMA 
      AND A0017 
      IOR CWX 
      STA TRW 
      LDA CHCNT 
      INA 
      STA BTNM
      JMP SETEP,I 
      SKP 
DEL10 NOP           DELAY AT LEAST 10 MICROSECONDS
      NOP 
      NOP 
      NOP 
      NOP 
      NOP 
      NOP 
      JMP DEL10,I 
      HED SPCHR - SPECIAL CHARACTER - RECEIVE INTERFACE DIAGNOSTIC
SPCHR NOP 
      LDA CW9       140220 - SPECIAL CHAR FLG ENABLD
      JSB INP 
SPNP  JSB SPRN      NO PARITY MODE
      JSB SETNP 
      LDA MN9 
      ADA CHCNT     REPEAT 8 TIMES
      SZA 
      JMP SPNP
      SPC 2 
      LDA CW10      146220 - SPECIAL CHAR FLG ENABLD
      JSB IOP 
SPOP  JSB SPRN      ODD PARITY MODE 
      JSB SETOP 
      LDA MN8 
      ADA CHCNT     REPEAT 7 TIMES
      SZA 
      JMP SPOP
      SPC 2 
      LDA CW11      144220 - SPECIAL CHAR FLG ENABLD
      JSB IEP 
SPEP  JSB SPRN
      JSB SETEP 
      LDA MN8 
      ADA CHCNT     REPEAT 7 TIMES
      SZA 
      JMP SPEP
      SPC 2 
      LDA CW9       SET SPECIAL CHARACTER BUT SEND
      JSB INP         DIFFERENT DATA
      JSB PRTY
      LDA WD1 
      JSB OTACH     SET SP CHAR 
      CMA 
      STA WD1 
      JSB SEND      SEND DATA 
      JSB LIACH     INPUT STATUS
      AND BT9 
      CPA BT9       IS SPECIAL CHARACTER BIT SET? 
E107  JSB ERROR,I   * YES, REPORT ERROR * 
      JSB SWAI,I    CONTINUE AUTO?
      JMP SPF       YES 
      JSB TTSKI,I   NO
      LDA LM110 
      LDB MI110 
      JSB TTY.O,I   LIST
H110  OCT 103010    HLT - END SPCHR 
SPF   JSB SWBI,I    RECYCLE TEST? 
      JMP SPCHR     YES 
      JMP SYNCH     NO
      SKP 
SPRN  NOP 
      JSB PRTY      READY DATA
      LDA WD1 
      JSB OTACH     SET DATA TO SPECIAL CHARACTER 
      JSB SEND      SEND DATA TO INTERFACE
      JSB LIACH     RETURN DATA HERE
      STA TEMPA 
      AND BP2 
      CPA BP2       BIT 15,9 = 1? 
      JMP CH38      YES, CHECK FLAG 
      STA SAVE      NO, REPORT ERROR
      LDB MG00D 
      JSB DATAI,I   STATUS INTO MSG 
      LDA PAR 
      STA SAVA
      LDB MG00A     STUFF PROPER PARITY MODE INTO 
      JSB PARTY       MESSAGE 
      LDA CHCNT     NO. OF BITS 
      STA SAVB
      IOR AC
      STA MG00B,I 
      LDA WD1       DATA WORD 
      STA SAVD
      LDB MG00C 
      JSB DATAI,I 
      LDA E101
      JSB BRCI,I    RTN *+2 IF NO TTP SELECTED
E100  JSB ERROR,I   * STATUS ERROR
CH38  SFS CH        CHECK FLAG
E106  JSB ERROR,I   * FLAG NOT SET
      ISZ CNR       INCREMENT PATTERN 
      LDA PTNC,I    PATTERN COUNT 
      ADA CNR 
      SZA           FINISHED WITH ALL PATTERNS? 
      JMP SPRN+1    NO, REPEAT
      JMP SPRN,I    YES, EXIT 
      HED SYNCH - SYNC CHARACTER - RECEIVE INTERFACE DIAGNOSTIC 
SYNCH NOP 
      LDA CW12      140020 - SYNC CODE FLAG ENABLED 
      JSB INP 
SYNP  JSB SYRN      NO PARITY MODE
      JSB SETNP 
      LDA MN9 
      ADA CHCNT     REPEAT 8 TIMES
      SZA 
      JMP SYNP
      SPC 2 
      LDA CW13      146020
      JSB IOP 
SYOP  JSB SYRN      ODD PARITY MODE 
      JSB SETOP 
      LDA MN8 
      ADA CHCNT     REPEAT 7 TIMES
      SZA 
      JMP SYOP
      SPC 2 
      LDA CW14      144020
      JSB IEP 
SYEP  JSB SYRN      EVEN PARITY MODE
      JSB SETEP 
      LDA MN8 
      ADA CHCNT     REPEAT 7 TIMES
      SZA 
      JMP SYEP
      JSB SWAI,I    CONTINUE AUTO?
      JMP SPY       YES 
      JSB TTSKI,I   NO
      LDA LM145 
      LDB MI145 
      JSB TTY.O,I   LIST
H145  OCT 103045    HLT - END SYNCH 
SPY   JSB SWBI,I    RECYCLE TEST? 
      JMP SYNCH     YES 
      JMP LOCKN     NO
      SKP 
SYRN  NOP 
      JSB PRTY      READY DATA
      LDA WD1 
      IOR BT14      CONTROL WORD
      JSB OTACH     SET DATA TO SYNC CODE 
      JSB SEND      SEND DATA TO INTERFACE
      JSB LIACH     RETURN DATA HERE
      SSA           BIT 15 SET? 
      JMP CH39      YES, CHECK FLAG 
      LDA PAR       NO, REPORT ERROR
      STA SAVA
      LDB MG25A     STUFF PROPER PARITY MODE INTO 
      JSB PARTY       MESSAGE 
      LDA CHCNT     NO. OF BITS 
      STA SAVB
      IOR AC
      STA MG25B,I 
      LDA WD1       DATA WORD 
      STA SAVD
      LDB MG25C 
      JSB DATAI,I 
      LDA E126
      JSB BRBI,I    RTN *+2 IF NO TTP SELECTED
E125  JSB ERROR,I   * STATUS ERROR, BIT 15 NOT SET
CH39  SFS CH        CHECK FLAG
E134  JSB ERROR,I   * FLAG NOT SET
      LDA TRW 
      AND NB4       REMOVE BIT 4 FROM CONTROL WORD
      STA TRW 
      JSB SEND      SEND DATA AGAIN 
      JSB LIACH 
      SSA,RSS       IS BIT 15 SET?
      JMP E137+1    NO
      LDA PAR       YES, REPORT ERROR 
      STA SAVA
      LDB MG37A     STUFF PROPER PARITY MODE INTO 
      JSB PARTY       MESSAGE 
      LDA CHCNT     NO. OF BITS 
      STA SAVB
      IOR AC
      STA MG37B,I 
      LDA WD1       DATA WORD 
      STA SAVD
      LDB MG37C 
      JSB DATAI,I 
      LDA E140
      JSB BRBI,I    RTN *+2 IF NO TTP SELECTED
E137  JSB ERROR,I   * STATUS ERROR, BIT 15 SET. 
      LDA TRW 
      IOR BT4       ADD BIT 4 TO CONTROL WORD 
      STA TRW 
      ISZ CNR       INCREMENT PATTERN 
      LDA PTNC,I    PATTERN COUNT 
      ADA CNR 
      SZA           FINISHED WITH ALL PATTERNS? 
      JMP SYRN+1    NO, REPEAT
      JMP SYRN,I    YES, EXIT 
      HED LOCKN - LOCK-ON DATA TEST - RECEIVE INTERFACE DIAGNOSTIC
LOCKN NOP 
      LDA CW15           040001 
      JSB OTACH     SET SYNC PATTERN IN INTERFACE 
      LDA MN8 
      STA CHE 
      LDA CW16      141010
      STA TRW 
      LDB NSYNC     SEND NON-SYNC PATTERN 
      CLC 0 
RPT1  JSB SENDC 
      BRS 
      ISZ CHE 
      JMP RPT1
      JSB LIACH     GET STATUS
      AND BT14
      CPA BT14
      RSS 
E150  JSB ERROR,I   * BIT 14 NOT SET
CH41  SFC CH
E151  JSB ERROR,I   * FLAG SET AND SHOULD BE CLEAR
      CLE 
TRP   LDA MN8 
      STA CHE 
      LDB SYNC      SEND 1ST SYNC PATTERN 
      CLC 0 
RPT2  JSB SENDC 
      BRS 
      ISZ CHE 
      JMP RPT2
      CME 
      SEZ 
      JMP TRP       SEND 2ND SYNC PATTERN 
      JSB LIACH     INPUT STATUS
      AND BT14
      SZA 
E152  JSB ERROR,I   * BIT 14 SET AND SHOULD BE 0
CH43  SFC CH
E153  JSB ERROR,I   * FLAG SET AND SHOULD BE CLEAR
      JSB SWAI,I    CONTINUE AUTO?
      JMP LOC       YES 
      JSB TTSKI,I   NO
      LDA LM154 
      LDB MI154 
      JSB TTY.O,I 
H154  OCT 103054    HLT - END LOCKN 
LOC   JSB SWBI,I    RECYCLE TEST? 
      JMP LOCKN     YES 
      JMP ERRFF     NO
      HED ERRFF - ERROR FLIP-FLOP - RECEIVE INTERFACE DIAGNOSTIC
ERRFF NOP 
      LDA CW8       EVEN PARITY RECEIVE CONTROL WORD
      JSB IOP       ODD PARITY SETUP
      JSB PRTY
      JSB SEND      SEND INCORRECT PARITY DATA TO 
      JSB LIACH       FORCE ERROR FLIP-FLOP TO SET
      AND BT8 
      SZA,RSS       ERROR BIT SET?
E160  JSB ERROR,I   * NO, ERROR BIT NOT SET 
      SPC 2 
      LDA CW7       ODD PARITY RECEIVE CONTROL WORD 
      JSB IEP       EVEN PARITY SETUP 
      JSB PRTY
      JSB SEND
      JSB LIACH 
      AND BT8 
      SZA,RSS       ERROR BIT SET?
E161  JSB ERROR,I   * NO, REPORT ERROR IN ERROR BIT 
      SPC 2 
      LDA CW17      NO PARITY, ONE BIT CHARACTER
      STA TRW         SIZE CONTROL WORD 
      CLC 0 
      JSB SENDC     SEND ANY CHARACTER TWICE WITHOUT
      LDA TRW         A CLF - THIS SHOULD FORCE THE 
      SLB,RSS         ERROR FLIP-FLOP TO SET
      IOR BT6       DATA BIT
      IOR BT5         WITH CLOCK = 1
      JSB OTACH 
      AND NBT5      DATA BIT WITH CLOCK = 0 
      JSB OTACH 
      JSB DEL10 
      JSB LIACH     GET STATUS
      AND BT8 
      SZA,RSS       ERROR BIT SET?
E162  JSB ERROR,I   * NO, REPORT ERROR
      JSB SWAI,I    CONTINUE AUTO?
      JMP ERSD      YES 
      JSB TTSKI,I   NO
      LDA LM163 
      LDB MI163 
      JSB TTY.O,I   LIST
H163  OCT 103063    HLT - END ERRFF 
ERSD  JSB SWBI,I    RECYCLE TEST? 
      JMP ERRFF     YES 
      JMP END       NO, EXIT
      HED END - COMMON SUBROUTINES - RECEIVE INTERFACE DIAGNOSTIC 
END   NOP 
      JSB SW09I,I   OMIT STOP MESSAGE?
      RSS           NO
      JMP RETR-1
      JSB TTSKI,I 
      LDA LM77
      LDB MI77
      JSB TTY.O,I   TELL OPERATOR TEST IS FINISHED
      JMP EXRTN,I 
RETR  JSB SWRPI,I   REPEAT TEST AUTO? 
H77   HLT 77B       NO
      JMP STR,I 
      SPC 2 
***       SUBROUTINES       *** 
      SPC 2 
DATA  NOP           CHANGE DATA IN A TO ASCII AND 
      STA DX          STORE IN LOCATION IN B
      STB DADD
      JSB B2ASC     CHANGE TWO LEAST SIG CH TO ASCII
      LDB DADD
      ADB A0002     MODIFY ADDRESS
      STA B,I       STORE TWO CHARACTERS
      LDA DX
      ALF,ALF 
      RAL,RAL 
      JSB B2ASC     CHANGE NEXT TWO CH TO ASCII 
      LDB DADD
      INB           MODIFY ADDRESS
      STA B,I       STORE TWO CHARACTERS
      LDA DX
      AND P0000 
      ALF 
      JSB B2ASC     CHANGE TWO MOST SIG CH TO ASCII 
      STA DADD,I    STORE FINAL TWO CHARACTERS
      JMP DATA,I    EXIT
DX    BSS 1         DATA TO BE CONVERTED
DADD  BSS 1         ADDRESS WHERE ASCII CH MUST GO
      SPC 2 
DELY  NOP           DELAYS A FEW HUNDRED MSEC 
      CLA 
      INA,SZA 
      JMP *-1 
      JMP DELY,I
      SPC 2 
SWEH  NOP           CHECK SW REG BIT 14 FOR HALT
      LDB SWEH        ON ERRORS 
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT14
      SZA 
      JMP B,I       NO HALT - RETURN *+2
      JMP SWEH,I    HLT ON ERRORS - RETURN *+1
      SPC 1 
SWTP  NOP           CHECK SW REG BIT 11 FOR TTP 
      LDB SWTP        SUPPRESSED
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT11
      SZA 
      JMP SWTP,I    TTP IS SUPPRESSED - RTN *+1 
      LDA NOTTP 
      SZA 
      JMP SWTP,I    TTP NOT AVAILABLE, RTN *+1
      JMP B,I       NOT SUPPRESSED  - RETURN *+2
      SPC 1 
SWRC  NOP           CHECK SW REG BIT 13 FOR RECYCLE 
      LDB SWRC        LAST TEST 
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT13
      SZA 
      JMP SWRC,I    RECYCLE LAST TEST - RETURN *+1
      JMP B,I       NO RECYCLE  RETURN *+2
      SPC 1 
SWSA  NOP           CHECK SW REG BIT 15 FOR HALT AT 
      LDB SWSA        END OF TEST 
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      SSA 
      JMP B,I       RUN SEMI-AUTO - RETURN *+2
      JMP SWSA,I    CONTINUE AUTO - RETURN *+1
      SPC 1 
SWRPT NOP           CHECK SW REG BIT 12 FOR HALT AT 
      LDB SWRPT       END OF DIAGNOSTIC 
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT12
      SZA,RSS 
      JMP SWRPT,I   BIT SET - RETURN *+1 AND HALT 
      JMP B,I       REPEAT TEST - RETURN *+2
      SPC 2 
SW09  NOP           CHECK TO OMIT START AND STOP
      LDB SW09        MESSAGES
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT9 
      SZA,RSS       OMIT MESSAGE? 
      JMP SW09,I    NO
      JMP B,I       YES 
      SPC 2 
SW10  NOP           CHECK TO OMIT PRESET AND CKFRQ
      LDB SW10        TESTS 
      INB 
      JSB SWR       LDA WITH INTERNAL OR EXT SW REG 
      AND BT10
      SZA           OMIT TEST?
      JMP SW10,I    NO
      JMP B,I       YES 
      SPC 2 
*     TWO ERRORS PLUS SW REG
      SPC 2 
BRP1  NOP           ** REPORT ERROR VIA SW REG
      JSB INR         AND A REG 
      JMP BRP1,I    RTN *+1 
      LDA SAVA
      JSB EY4R
      LDA SAVB
      JSB EY4R
      LDA SAVC
      JSB EY4R
      ISZ BRP1
      JMP BRP1,I    RETURN *+2
      SPC 2 
*     THREE ERRORS PLUS SW REG
      SPC 2 
BRP2  NOP           ** REPORT ERROR VIA SW REG
      JSB INR         AND A REG 
      JMP BRP2,I    RTN *+1 
      LDA SAVA
      JSB EY4R
      LDA SAVB
      JSB EY4R
      LDA SAVD
      JSB EY4R
      LDA SAVC
      JSB EY4R
      ISZ BRP2
      JMP BRP2,I    RETURN *+2
      SPC 2 
*     FOUR ERRORS PLUS SW REG 
      SPC 2 
BRP3  NOP           ** REPORT ERROR VIA SW REG
      JSB INR         AND A REG 
      JMP BRP3,I    RTN *+1 
      LDA SAVA
      JSB EY4R
      LDA SAVB
      JSB EY4R
      LDA SAVD
      JSB EY4R
      LDA SAVE
      JSB EY4R
      LDA SAVC      RESTORE SW REG
      JSB EY4R
      ISZ BRP3
      JMP BRP3,I    RETURN *+2
      SPC 2 
INR   NOP           ** RETURN *+2 IF NO 
      STA EY4         TTP SELECTED
      LDA NOTTP 
      SZA,RSS 
      JMP INR,I     RTN *+1 
      LIA 1 
      STA SAVC      SAVE SW REG 
      ISZ INR 
      JMP INR,I     RTN *+2 
      SPC 2 
EY4R  NOP           ** OUTPUT TO SWITCH REGISTER
      OTA 1 
      LDB SAVC
      RBL 
      SSB,RSS       HALT SELECTED?
EY4   HLT 0         YES 
      ISZ EY4 
      JMP EY4R,I
      SPC 2 
ERR   NOP           ERROR REPORTING ROUTINE 
      CLF 0         DISABLE INTERRUPTS
      CCB 
      ADB ERR 
      LDA FER       FIND ERROR NUMBER BASED ON RETRN
      CPB A,I       ADDRESS AND TABLE 
      JMP *+5       FOUND IT
      INA 
      CPA LER       END OF TABLE? 
      JMP ERR,I     YES, EXIT ERROR ROUTINE 
      JMP *-5       CONTINUE SEARCH 
      ADA FERC      NORMALIZE NUMBER
      STA SETXX 
      JSB SWTP      TTP SUPPRESSED? 
      JMP NOH       YES 
      LDA SETXX     NO
      LDB FMI       MESSAGE ADDRESS TABLE 
      ADB A 
      LDB B,I       MESSAGE ADDRESS INTO B
      ADA FML 
      LDA A,I       MESSAGE LENGTH INTO A 
      JSB TTY.O,I   TYPE MESSAGE
NOH   ISZ CNT2      COUNT ALL ERRORS
      RSS 
      ISZ CNT1
      NOP 
      LDB CHLT      CODED HALT TABLE
      ADB SETXX 
      LDB B,I       CODED HALT IN B 
      STB EXX 
      JSB SWEH      ERROR HALT? 
EXX   HLT 0         YES, SO HALT
      JMP ERR,I 
      SPC 2 
TTSK  NOP           CHECKS FOR PRINTOUT SELECTION 
      CLF 0         DISABLE INTERRUPTS
      LDB TTSK
      ADB A0003     MODIFY RETURN ADDRESS 
      STB SWB 
      JSB SWTP      TTP SUPPRESSED? 
      JMP SWB,I     YES, SKIP PRINTOUT
      JMP TTSK,I    NO, EXIT AND PRINT
      SPC 2 
***       MESSAGES        *** 
      SPC 2 
      SUP 
AS0   ASC 2,  NO
AS1   ASC 2, ODD
AS2   ASC 2,EVEN
M1    ASC 17,E1. CLF DID NOT CLEAR FLAG, OR SFS 
      ASC 14, CAUSED SKIP WITH FLAG CLEAR 
L1    EQU *+*-M1-M1 
M2    ASC 18,E2. SFC DID NOT SKIP WITH FLAG CLEAR 
L2    EQU *+*-M2-M2 
M3    ASC 20,E3. STF DID NOT SET FLAG, OR SFC CAUSED
      ASC 9,SKIP WITH FLAG SET
L3    EQU *+*-M3-M3 
M4    ASC 17,E4. SFS DID NOT SKIP WITH FLAG SET 
L4    EQU *+*-M4-M4 
M5    ASC 11,E5. DID NOT INTERRUPT
L5    EQU *+*-M5-M5 
M6    ASC 19,E6. THE RETURN ADDRESS IS NOT CORRECT
L6    EQU *+*-M6-M6 
M7    ASC 20,H7. PRESS INTERNAL AND EXTERNAL PRESET,
      ASC 07,THEN PRESS RUN 
L7    EQU *+*-M7-M7 
M10   ASC 18,E10. EXTERNAL PRESET DID NOT SET THE 
      ASC 03, FLAG
L10   EQU *+*-M10-M10 
M11   ASC 7,H11. END BI/O 
L11   EQU *+*-M11-M11 
M12   ASC 18,E12. INTERNAL PRESET DID NOT DISABLE 
      ASC 06, INTERRUPTS
L12   EQU *+*-M12-M12 
M13   ASC 19,E13. EXTERNAL PRESET DID NOT SET FLAG
      OCT 6412
      ASC 18,AND INTERNAL PRESET DID NOT DISABLE
      ASC 05,INTERRUPTS 
L13   EQU *+*-M13-M13 
M14   ASC 17,E14. INTERRUPT ACKNOWLEDGE DID NOT 
      ASC 10, WORK. TEST ABORTED. 
L14   EQU *+*-M14-M14 
M15   ASC 16,E15. CLC 0 DID NOT CLEAR CONTROL 
      ASC 5, FLIP-FLOP
L15   EQU *+*-M15-M15 
M16   ASC 17,E16. EXTERNAL PRESET DID NOT CLEAR 
      ASC 04, CONTROL 
L16   EQU *+*-M16-M16 
M21   ASC 16,E21. STF 0 OR SFC 0 DID NOT WORK 
L21   EQU *+*-M21-M21 
M22   ASC 16,E22. STF 0 OR SFS 0 DID NOT WORK 
L22   EQU *+*-M22-M22 
M23   ASC 17,E23. CLC ON CHANNEL DID NOT CLEAR
      ASC 4,CONTROL 
L23   EQU *+*-M23-M23 
M24   ASC 20,E24. CLC CH,C DID NOT CLEAR FLAG OR SFC
      ASC 14,DID NOT SKIP WITH FLAG CLEAR 
L24   EQU *+*-M24-M24 
M25   ASC 11,E25. STATUS BITS ARE 
G25   ASC 14,XXXXXX AND SHOULD BE 000000
L25   EQU *+*-M25-M25 
M31   ASC 19,E31. INCORRECT STATUS. BIT 11 NOT SET
L31   EQU *+*-M31-M31 
M32   ASC 9,E32. FLAG NOT SET 
L32   EQU *+*-M32-M32 
M33   ASC 17,E33. INCORRECT STATUS. BIT 11 SET
L33   EQU *+*-M33-M33 
M34   ASC 17,E34. FLAG SET AND SHOULD BE CLEAR
L34   EQU *+*-M34-M34 
M35   ASC 11,E35. STATUS BITS ARE 
G35   ASC 14,XXXXXX AND SHOULD BE 012000
L35   EQU *+*-M35-M35 
M41   ASC 9,E41. FLAG NOT SET 
L41   EQU *+*-M41-M41 
M42   ASC 19,E42. INCORRECT STATUS. BIT 13 NOT SET
L42   EQU *+*-M42-M42 
M43   ASC 17,E43. FLAG SET AND SHOULD BE CLEAR
L43   EQU *+*-M43-M43 
M44   ASC 11,E44. STATUS BITS ARE 
G44   ASC 14,XXXXXX AND SHOULD BE 020000
L44   EQU *+*-M44-M44 
M50   ASC 9,E50. FLAG NOT SET 
L50   EQU *+*-M50-M50 
M51   ASC 17,E51. FLAG SET AND SHOULD BE CLEAR
L51   EQU *+*-M51-M51 
M52   ASC 7,H52. END FCTST
L52   EQU *+*-M52-M52 
M53   ASC 18,E53. ERROR IN RECEIVE PATTERN TEST.
G53A  ASC 13,XXXX PARITY MODE SELECTED, 
      OCT 6412
      ASC 9,CHARACTER SIZE IS 
G53B  ASC 14,XX BITS, WORD RECEIVED WAS 
G53D  ASC 11,XXXXXX AND SHOULD BE 
      OCT 6412
G53C  ASC 3,XXXXXX
L53   EQU *+*-M53-M53 
M61   ASC 17,E61. STATUS ERROR IN RECEIVE TEST. 
      ASC 5, STATUS IS
      OCT 6412
G61   ASC 14,XXXXXX AND SHOULD BE 100000
L61   EQU *+*-M61-M61 
M67   ASC 19,E67. FLAG NOT SET AFTER RECEIVE CYCLE
L67   EQU *+*-M67-M67 
M70   ASC 7,H70. END RECVP
L70   EQU *+*-M70-M70 
M77   ASC 17,H77. DIAGNOSTIC HAS BEEN COMPLETED 
L77   EQU *+*-M77-M77 
SM    ASC 12,H8. START RECEIVE (ONLY) 
      ASC 11, INTERFACE DIAGNOSTIC
SL    EQU *+*-SM-SM 
M100  ASC 20,E100. ERROR IN SPECIAL CHARACTER TEST. 
G00A  ASC 13,XXXX PARITY MODE SELECTED, 
      OCT 6412
      ASC 9,CHARACTER SIZE IS 
G00B  ASC 11,XX BITS, DATA WORD IS
G00C  ASC 13,XXXXXX. STATUS RECEIVED IS 
      OCT 6412
G00D  ASC 14,XXXXXX AND SHOULD BE 101000
L100  EQU *+*-M100-M100 
M106  ASC 16,E106. FLAG NOT SET AFTER SPECIAL 
      ASC 8, CHARACTER TEST 
L106  EQU *+*-M106-M106 
M107  ASC 17,E107. SPECIAL CHARACTER BIT IS SET 
L107  EQU *+*-M107-M107 
M110  ASC 8,H110. END SPCHR 
L110  EQU *+*-M110-M110 
M125  ASC 19,E125. ERROR IN SYNC CODE TEST. BIT 15
      ASC 6,IS NOT SET. 
G25A  ASC 8,XXXX PARITY MODE
      OCT 6412
      ASC 14,SELECTED, CHARACTER SIZE IS
G25B  ASC 11,XX BITS, DATA WORD IS
G25C  ASC 4,XXXXXX. 
L125  EQU *+*-M125-M125 
M134  ASC 20,E134. FLAG NOT SET AFTER SYNC CODE TEST
L134  EQU *+*-M134-M134 
M137  ASC 19,E137. ERROR IN SYNC CODE TEST. BIT 15
      ASC 4,IS SET. 
G37A  ASC 13,XXXX PARITY MODE SELECTED, 
      OCT 6412
      ASC 9,CHARACTER SIZE IS 
G37B  ASC 11,XX BITS, DATA WORD IS
G37C  ASC 4,XXXXXX. 
L137  EQU *+*-M137-M137 
M145  ASC 8,H145. END SYNCH 
L145  EQU *+*-M145-M145 
M150  ASC 10,E150. BIT 14 NOT SET 
L150  EQU *+*-M150-M150 
M151  ASC 17,E151. FLAG SET AND SHOULD BE CLEAR 
L151  EQU *+*-M151-M151 
M152  ASC 18,E152. BIT 14 SET AND SHOULD BE CLEAR 
L152  EQU *+*-M152-M152 
M153  ASC 17,E153. FLAG SET AND SHOULD BE CLEAR 
L153  EQU *+*-M153-M153 
M154  ASC 8,H154. END LOCKN 
L154  EQU *+*-M154-M154 
M160  ASC 18,E160. ERROR BIT 8 NOT SET WITH EVEN
      OCT 6412
      ASC 20,PARITY CONTROL WORD AND ODD PARITY DATA
L160  EQU *+*-M160-M160 
M161  ASC 17,E161. ERROR BIT 8 NOT SET WITH ODD 
      ASC 10, PARITY CONTROL WORD 
      OCT 6412
      ASC 10,AND EVEN PARITY DATA 
L161  EQU *+*-M161-M161 
M162  ASC 20,E162. ERROR BIT 8 NOT SET WITH TWO DATA
      OCT 6412
      ASC 17,TRANSFERS WITHOUT A CLF ON CHANNEL 
L162  EQU *+*-M162-M162 
M163  ASC 8,H163. END ERRFF 
L163  EQU *+*-M163-M163 
FWAM  EQU *         FIRST WORD AVAILABLE MEMORY 
      END 
                                                                                                                                                                                                                                                    