ASMB,A,B,L,T,C
      HED RECEIVE (ONLY) INTERFACE DIAGNOSTIC 
      ORG 100B
      JMP CFGR      GO TO CONFIGURATION 
TTY.I BSS 1         TAPE INPUT
TTY.O BSS 1         LIST OUTPUT 
TTY.P BSS 1         PUNCH OUTPUT
TTY.K BSS 1         KEYBOARD INPUT
      DEF FWAM      FIRST WORD AVAILABLE MEMORY 
      ORG 126B
      OCT 103012    DSN 
      BSS 1 
EXRTN DEF RETR
      SKP 
* 
A     EQU 0 
B     EQU 1 
CH    EQU 10B 
FERC  ABS -FER
FER   DEF *+1       ERROR NUMBER TABLE
      DEF E1
      DEF E2
      DEF E3
      DEF E4
      DEF E5
      DEF E6
      DEF E10 
      DEF E12 
      DEF E13 
      DEF E14 
      DEF E15 
      DEF E16 
      DEF E21 
      DEF E22 
      DEF E23 
      DEF E24 
      DEF E25 
      DEF E31 
      DEF E32 
      DEF E33 
      DEF E34 
      DEF E35 
      DEF E41 
      DEF E42 
      DEF E43 
      DEF E44 
      DEF E50 
      DEF E51 
      DEF E53 
      DEF E61 
      DEF E67 
      DEF E100
      DEF E106
      DEF E107
      DEF E125
      DEF E134
      DEF E137
      DEF E150
      DEF E151
      DEF E152
      DEF E153
      DEF E160
      DEF E161
      DEF E162
LER   DEF * 
      SKP 
CHLT  DEF *         CODED HALT TABLE
      HLT 1 
      HLT 2 
      HLT 3 
      HLT 4 
      HLT 5 
      HLT 6 
      HLT 10B 
      HLT 12B 
      HLT 13B 
      HLT 14B 
      HLT 15B 
      HLT 16B 
      HLT 21B 
      HLT 22B 
      HLT 23B 
      HLT 24B 
      HLT 25B 
      HLT 31B 
      HLT 32B 
      HLT 33B 
      HLT 34B 
      HLT 35B 
      HLT 41B 
      HLT 42B 
      HLT 43B 
      HLT 44B 
      HLT 50B 
      HLT 51B 
      HLT 53B 
      HLT 61B 
      HLT 67B 
      OCT 103000    HLT 100 
      OCT 103006    HLT 106 
      OCT 103007    HLT 107B
      OCT 103025    HLT 125 
      OCT 103034    HLT 134 
      OCT 103037    HLT 137B
      OCT 103050
      OCT 103051
      OCT 103052
      OCT 103053
      OCT 103060
      OCT 103061
      SKP 
      SPC 2 
FMI   DEF *         MESSAGE ADDRESS TABLE 
      DEF M1
      DEF M2
      DEF M3
      DEF M4
      DEF M5
      DEF M6
      DEF M10 
      DEF M12 
      DEF M13 
      DEF M14 
      DEF M15 
      DEF M16 
      DEF M21 
      DEF M22 
      DEF M23 
      DEF M24 
      DEF M25 
      DEF M31 
      DEF M32 
      DEF M33 
      DEF M34 
      DEF M35 
      DEF M41 
      DEF M42 
      DEF M43 
      DEF M44 
      DEF M50 
      DEF M51 
      DEF M53 
      DEF M61 
      DEF M67 
      DEF M100
      DEF M106
      DEF M107
      DEF M125
      DEF M134
      DEF M137
      DEF M150
      DEF M151
      DEF M152
      DEF M153
      DEF M160
      DEF M161
      DEF M162
      SKP 
FML   DEF *         MESSAGE LENGTH TABLE
      DEF L1
      DEF L2
      DEF L3
      DEF L4
      DEF L5
      DEF L6
      DEF L10 
      DEF L12 
      DEF L13 
      DEF L14 
      DEF L15 
      DEF L16 
      DEF L21 
      DEF L22 
      DEF L23 
      DEF L24 
      DEF L25 
      DEF L31 
      DEF L32 
      DEF L33 
      DEF L34 
      DEF L35 
      DEF L41 
      DEF L42 
      DEF L43 
      DEF L44 
      DEF L50 
      DEF L51 
      DEF L53 
      DEF L61 
      DEF L67 
      DEF L100
      DEF L106
      DEF L107
      DEF L125
      DEF L134
      DEF L137
      DEF L150
      DEF L151
      DEF L152
      DEF L153
      DEF L160
      DEF L161
      DEF L162
      SKP 
FIRST DEF *+1       TABLE OF SELECT CODES TO BE 
      DEF CH0 
      DEF CH1         MODIFIED
      DEF CH2 
      DEF CH3 
      DEF CH4 
      DEF CH5 
      DEF CH6 
      DEF CH7 
      DEF CH8 
      DEF CH9 
      DEF CH10
      DEF CH11
      DEF CH12
      DEF CH13
      DEF CH14
      DEF CH15
      DEF CH16
      DEF CH17
      DEF CH18
      DEF CH19
      DEF CH20
      DEF CH21
      DEF CH22
      DEF CH23
      DEF CH24
      DEF CH25
      DEF CH26
      DEF CH27
      DEF CH28
      DEF CH29
      DEF CH30
      DEF CH31
      DEF CH32
      DEF CH33
      DEF CH34
      DEF CH35
      DEF CH37
      DEF CH38
      DEF CH39
      DEF CH41
      DEF CH43
      DEF HLTC
      DEF DCH 
LAST  DEF *-1 
      SKP 
A0077 OCT 77        COMMON CONSTANTS AND SYMBOLS
A0002 OCT 2 
A0003 OCT 3 
A0100 OCT 100 
THLT  OCT 106002    TRAP CELL HALT
P0000 OCT 170000
P7700 OCT 177700
NSYNC OCT 223 
SYNC  OCT 1 
NOTTP NOP 
SAVA  NOP 
SAVB  NOP 
SAVC  NOP 
SAVD  NOP 
SAVE  NOP 
HLTA  OCT 106000    A REG TRAP CELL HALT
HLTB  OCT 106001    B REG 
HLTC  OCT 106000    SELECTED CHANNEL
DCH   NOP 
IO    NOP 
SRP   NOP 
CNT1  NOP           * ERROR 
CNT2  NOP           * COUNTERS
SETXX NOP 
SWB   NOP 
CRL   OCT 2 
CRI   DEF *+1 
      OCT 6400      CARRIAGE RETURN 
TABL  DEF *+1 
      DEC -2
      DEC -4
      DEC -8
      DEC -16 
      DEC -32 
      DEC -64 
      DEC -128
      DEC -256
AC    OCT 20060 
BT158 OCT 100400
PTNC  NOP 
WD1   NOP 
CHCNT NOP 
PAR   NOP 
CNR   NOP 
TRW   NOP 
BTNM  NOP 
A0377 OCT 377 
TEMPA NOP 
P7400 OCT 177400
P7770 OCT 177770
A0017 OCT 17
NB4   OCT 177757
NBT5  OCT 177737
MN9   DEC -9
MN8   DEC -8
      SKP 
BP1   OCT 32000 
BP2   OCT 101000
BP3   OCT 12000 
BT0   OCT 1 
BT4   OCT 20
BT5   OCT 40
BT6   OCT 100 
BT8   OCT 400 
BT9   OCT 1000
BT10  OCT 2000
BT11  OCT 4000
BT12  OCT 10000 
BT13  OCT 20000 
BT14  OCT 40000 
BT15  OCT 100000
CW1   OCT 140010
CW2   OCT 150010
CW3   OCT 140510
CW4   OCT 140550
CW5   OCT 140450
CW6   OCT 140020
CW7   OCT 146020
CW8   OCT 144020
CW9   OCT 140220
CW10  OCT 146220
CW11  OCT 144220
CW12  OCT 140020
CW13  OCT 146020
CW14  OCT 144020
CW15  OCT 040001
CW16  OCT 141010
CW17  OCT 140037
CWX   NOP 
      SKP 
J1    JSB *+1,I 
      DEF IJ1 
J2    JSB *+1,I 
      DEF IJ2 
J3    JSB *+1,I 
      DEF IJ3 
J4    JSB *+1,I 
      DEF IJ4 
E26   HLT 26B 
E36   HLT 36B 
E45   HLT 45B 
E54   HLT 54B 
E62   HLT 62B 
E101  OCT 103001
E126  OCT 103026
E140  OCT 103040
TTSKI DEF TTSK      INDIRECT ADDRESSES
JSB1  JSB R1,I      INTERRUPT ROUTINE 
      SKP 
ERROR DEF ERR 
ADDRS DEF INTPT+1 
SW09I DEF SW09
SW10I DEF SW10
SWRPI DEF SWRPT 
BRAI  DEF BRP1
BRBI  DEF BRP2
BRCI  DEF BRP3
SWAI  DEF SWSA
SWBI  DEF SWRC
DELAY DEF DELY
DATAI DEF DATA
AS0M  DEF AS0 
AS1M  DEF AS1 
AS2M  DEF AS2 
MI7   DEF M7
LM7   DEF L7
MI11  DEF M11 
LM11  DEF L11 
MSG25 DEF G25 
MSG35 DEF G35 
MSG44 DEF G44 
MG53A DEF G53A
MG53B DEF G53B
MG53C DEF G53C
MG53D DEF G53D
MI52  DEF M52 
LM52  DEF L52 
MG61  DEF G61 
MI70  DEF M70 
LM70  DEF L70 
MI77  DEF M77 
LM77  DEF L77 
MG00A DEF G00A
MG00B DEF G00B
MG00C DEF G00C
MG00D DEF G00D
MI110 DEF M110
LM110 DEF L110
MG25A DEF G25A
MG25B DEF G25B
MG25C DEF G25C
MG37A DEF G37A
MG37B DEF G37B
MG37C DEF G37C
MI145 DEF M145
LM145 DEF L145
MI154 DEF M154
LM154 DEF L154
MI163 DEF M163
LM163 DEF L163
R1    DEF RETRN 
STR   DEF START 
SML   DEF SL
SMI   DEF SM
      SKP 
B2ASC NOP           OCTAL ASCII 
      AND A0077 
      LDB A 
      BRS,BRS 
      BRS 
      BLF,BLF 
      AND A0007 
      IOR B 
      IOR D0060 
      JMP B2ASC,I 
A0007 OCT 7 
D0060 OCT 30060     ASCII PREFIXES
      SPC 2 
PARTY NOP           STUFF PARITY MODE INTO MESSAGE
      STB ADRS      PAR IN A, ADDRESS IN B
      LDB AS0M
      SZA 
      JMP YE
      LDA B,I       NO PARITY 
YA    STA ADRS,I
      INB 
      LDA B,I 
      ISZ ADRS
      STA ADRS,I
      JMP PARTY,I   EXIT
YE    CPA A0002 
      JMP YO
      LDB AS1M      EVEN PARITY 
      LDA B,I 
      JMP YA
YO    LDB AS2M      ODD PARITY
      LDA B,I 
      JMP YA
ADRS  NOP 
      SPC 2 
SWR   NOP 
      LIA 1 
      JMP SWR,I 
      SPC 2 
OTACH NOP 
CH15  OTA CH
      JMP OTACH,I 
      SPC 1 
LIACH NOP 
CH16  LIA CH
      JMP LIACH,I 
      HED CONFIGURATION PROGRAM - RECEIVE INTERFACE DIAGNOSTIC
      ORG 1744B 
CFGR  CLC 0,C       CONFIGURATION ROUTINE 
      LIA 1         SW REG
      AND A0077 
      ADA MN8 
      SSA,RSS       SC > 7 ?
      JMP *+3 
E73   HLT 73B       SELECT CODE INPUT ERROR 
      JMP CFGR
      LIA 1 
      AND A0077 
      STA IO
      LDB FIRST     MODIFY I/O INSTRUCTIONS 
      STB SRP 
L     LDB SRP,I 
      LDA B,I 
      AND P7700 
      IOR IO
      STA B,I 
      CPB LAST,I    FINISHED? 
      JMP *+3       YES 
      ISZ SRP 
      JMP L 
      CLA 
      LDB 112B
      SZB,RSS 
      CCA 
      STA NOTTP     TELEPRINTER AVAILABLE BIT 
H74   HLT 74B       **END OF CONFIGURATION**
      HED INITIALIZATION PROGRAM - RECEIVE INTERFACE DIAGNOSTIC 
START CLC 0,C       TURN EVERYTHING OFF 
      LDB A0002     TRAP CELL LOCATION
      LDA THLT      TRAP CELL HALT
      STA B,I 
      INB 
      INA 
      CPB A0100     TRAP CELL HALTS COMPLETE? 
      RSS           YES 
      JMP *-5       NO, REPEAT
      JSB SW09I,I   OMIT START MESSAGE? 
      RSS           NO
      JMP BI/O      YES 
      JSB TTSKI,I 
      LDA CRL 
      LDB CRI 
      JSB TTY.O,I   OUTPUT CR,LF
      JSB TTSKI,I 
      LDA SML 
      LDB SMI 
      JSB TTY.O,I   START DATA SET DIAGNOSTIC 
      JMP BI/O
      HED BI/O - BASIC I/O - RECEIVE INTERFACE DIAGNOSTIC 
*         TEST ABILITY TO SET AND CLEAR THE CHANNEL FLAG
      SPC 2 
BI/O  CLC 0,C 
      CLF 0 
      LDA CW1       MASTER CLEAR - 140010 
      JSB OTACH     CLEAR SP CHAR, ERROR
      JSB DELAY,I 
      JSB LIACH 
      AND P7400 
      SZA,RSS       STATUS = 0? 
      JMP HT        YES 
      STA SAVA      NO, REPORT ERROR
      CLB 
      STB SAVB
      LDB MSG25 
      JSB DATAI,I 
      LDA E26 
      JSB BRAI,I    RTN *+2 IF NO TTP SELECTED
E25   JSB ERROR,I   * STATUS NOT = 0
HT    LDA HLTA      TRAP CELL HALTS 
      LDB HLTB
CH0   STF CH
CH1   CLF CH        CLEAR CHANNEL FLAG
CH2   SFS CH
      RSS           ** CLF DID NOT CLEAR FLAG OR SFS
E1    JSB ERROR,I     CAUSED SKIP WITH FLAG CLEAR 
CH7   CLF CH
CH3   SFC CH
E2    JSB ERROR,I   * SFC NO SKIP WITH FLAG CLEAR 
CH4   STF CH
CH5   SFC CH
      RSS           ** STF DID NOT SET FLAG OR SFC
E3    JSB ERROR,I     CAUSED SKIP WITH FLAG SET 
CH10  STF CH
CH6   SFS CH
E4    JSB ERROR,I   * SFS NO SKIP WITH FLAG SET 
CH18  STF CH
CH19  CLC CH,C
CH20  SFC CH        * ERROR = CLC CH,C DID NOT CLEAR
E24   JSB ERROR,I   * FLAG OR SFC DID NOT SKIP
      SKP 
*     TEST ABILITY TO ENABLE AND DISABLE INTERRUPT SYSTEM 
      SPC 2 
      STF 0         ENABLE INTS 
      CLF 0         DISABLE INTS
      SFS 0         IS INTERRUPT SYSTEM ON? 
      RSS           NO
E17   HLT 17B       * CLF 0 DID NOT DISABLE INTS OR 
      CLF 0         * SFS 0 CAUSED BAD SKIP 
      SFC 0         IS INT SYSTEM ON? 
E20   HLT 20B       * CLF 0 DID NOT DISABLE INTS OR 
      STF 0         * SFC 0 CAUSED BAD SKIP 
      SFC 0         IS INT SYSTEM ON? 
      RSS           YES 
E21   JSB ERROR,I   * STF 0 DID NOT ENABLE INTS OR
      STF 0         * SFC 0 CAUSED BAD SKIP 
      SFS 0         IS INT SYSTEM ON? 
E22   JSB ERROR,I   * STF 0 DID NOT ENABLE INTS OR
      CLF 0         * SFS 0 CAUSED BAD SKIP 
      SKP 
*     TEST INTERRUPT CAPABILITY 
      SPC 2 
      LDA JSB1      SET INTERRUPT TRAP CELL 
      STA DCH,I 
      LDA HLTA      TRAP CELL HALTS 
      LDB HLTB
CH8   STC CH        SET CHANNEL TO REQUEST
CH9   STF CH          AN INTERRUPT
      STF 0         ENABLE INTERRUPTS 
      STC 1         * INTERRUPTS
      STF 1            SHOULD 
      CLC 1            BE 
      CLF 1            DELAYED
      JMP *+1,I        UNTIL
      DEF *+1            .
      JSB *+1,I          .
      DEF *+1            .
      NOP                .
INTPT NOP           *  HERE 
E5    JSB ERROR,I   * DID NOT INTERRUPT 
      JMP TCR 
      SPC 1 
RETRN NOP           INTERRUPT SUBROUTINE
      CLF 0         DISABLE INTERRUPTS
      LDA J1        IJ1 INTERRUPT ROUTINE 
      STA DCH,I 
      STF 0         TEST INTERRUPT ACKNOWLEDGE
      NOP           * SHOULD NOT
      NOP              INTERRUPT HERE 
      CLF 0         DISABLE INT 
      LDA RETRN     DID INTERRUPT OCCUR AT THE
      CPA ADDRS       CORRECT MEM LOCATION? 
      RSS 
E6    JSB ERROR,I   * RETURN ADDRESS IS INCORRECT 
      STB RETRN     CHANGE RETRN
      JMP TCR 
      SPC 1 
IJ1   NOP 
      CLF 0 
E14   JSB ERROR,I   * INTERRUPT ACKNOWLEDGE DID NOT 
      JMP GOOD      * WORK. TEST ABORTED
      SKP 
*     TEST CONTROL RESET
      SPC 2 
TCR   LDA J2        IJ2 INTERRUPT ROUTINE 
      STA DCH,I 
      LDA HLTA
      LDB HLTB
CH11  STC CH        SET CONTROL 
CH12  STF CH
      CLC 0         SHOULD CLEAR ALL CONTROL BITS 
      STF 0         ENABLE
      NOP           ** SHOULD NOT 
      NOP              INTERRUPT HERE 
      CLF 0         DISABLE INTS
TCR2  LDA J4
      STA DCH,I     IJ4 INTERRUPT ROUTINE 
      LDA HLTA
      LDB HLTB
CH33  STC CH
CH34  STF CH
CH17  CLC CH        CLEAR CHANNEL CONTROL BIT 
      STF 0         ENABLE INTS 
      NOP           ** SHOULD NOT 
      NOP             INTERRUPT HERE
      CLF 0 
      JMP PRSET 
      SPC 1 
IJ2   NOP 
      CLF 0 
E15   JSB ERROR,I   * CLC 0 DID NOT CLEAR CONTROL 
      JMP TCR2      * FLIP-FLOP 
IJ4   NOP 
      CLF 0 
E23   JSB ERROR,I   * CLC 0 ON CHANNEL DID NOT CLEAR
      JMP PRSET     * CONTROL FLIP-FLOP 
      SKP 
*     PRESET TEST 
      SPC 2 
PRSET JSB SW10I,I   OMIT TEST?
      RSS           NO
      JMP GOOD      YES 
      JSB TTSKI,I 
      LDA LM7 
      LDB MI7 
      JSB TTY.O,I 
      LDA HLTA
      LDB HLTB
CH13  STC CH,C      SET CONTROL, CLEAR FLAG 
      STF 0         ENABLE INTS 
H7    HLT 7         ** PRESS PRESETS, THEN PRESS RUN
CH14  SFS CH        IS FLAG SET?
      JMP *+4       NO
      SFC 0         YES, IS INT SYSTEM DISABLED?
E12   JSB ERROR,I   * PRESET DID NOT DISABLE INTS 
      JMP CL        YES 
      SFC 0 
      JMP E13 
E10   JSB ERROR,I   * PRESET DID NOT SET FLAG 
      JMP GOOD
E13   JSB ERROR,I   * PRESET DID NOT SET FLAG AND 
      JMP GOOD      * DID NOT DISABLE INTS
CL    LDA J3        IJ3 INTERRUPT ROUTINE 
      STA DCH,I     CHECK FOR A CLC 0 BY PRESET 
      LDA HLTA
      LDB HLTB
      STF 0         ENABLE INTS 
      NOP           SHOULD NOT INTERRUPT HERE 
      NOP 
      CLF 0 
      JMP GOOD
      SPC 1 
IJ3   NOP 
      CLF 0 
E16   JSB ERROR,I   * PRESET DID NOT CLEAR CONTROL
      SPC 1 
GOOD  CLC 0,C       TURN EVERYTHING OFF 
      LDA HLTC
      STA DCH,I     RESET TRAP CELL HALT
      JSB SWAI,I    CONTINUE AUTOMATIC? 
      JMP EBIO      YES 
      JSB TTSKI,I   RUN SEMI-AUTO 
      LDA LM11
      LDB MI11
      JSB TTY.O,I   LIST
H11   HLT 11B       END BI/O
EBIO  JSB SWBI,I    RECYCLE TEST? 
      JMP BI/O      YES, REPEAT 
      JMP FCTST     NO, EXIT
      HED FCTST - FUNCTION-STATUS - RECEIVE INTERFACE DIAGNOSTIC
FCTST NOP 
TST1  LDA CW2       150010  SET CD
      JSB OTACH 
      JSB DELAY,I 
      JSB LIACH 
      AND BT11      CE,CD = 1?
      SZA,RSS 
E31   JSB ERROR,I   * CD,CE NOT 1 
CH21  CLF CH
CH22  SFS CH        FLAG SHOULD BE SET (AGAIN) BY CE
E32   JSB ERROR,I   * FLAG NOT SET
      SPC 2 
TST2  LDA CW1       140010  RESET CD
      JSB OTACH     . 
      JSB DELAY,I 
      JSB LIACH 
      AND BT11
      SZA           CD,CE = 0?
E33   JSB ERROR,I   * NOT ZERO
CH23  CLF CH
CH24  SFC CH        FLAG SHOULD STAY CLEAR
E34   JSB ERROR,I   * FLAG NOT CLEAR
      SPC 2 
TST3  LDA CW3       140510 SET SA 
      JSB OTACH       STATUS FLAGS ENABLED
      JSB DELAY,I 
      JSB LIACH 
      AND BP1 
      CPA BP3       CF,SA,BB = 1; CC,TEST = 0?
      JMP CH25      YES 
      STA SAVA      NO, REPORT ERROR
      LDB BP3 
      STB SAVB
      LDB MSG35 
      JSB DATAI,I 
      LDA E36 
      JSB BRAI,I    RTN *+2 IF NO TTP SELECTED
E35   JSB ERROR,I   * STATUS ERROR
CH25  CLF CH
CH26  SFS CH        FLAG SHOULD BE SET (AGAIN) BY CC
E41   JSB ERROR,I   * FLAG NOT SET
      SPC 2 
TST4  LDA CW4       140550 SET TEST 
      JSB OTACH 
      JSB DELAY,I 
      JSB LIACH 
      AND BT13
      SZA,RSS       CC,TEST = 1?
E42   JSB ERROR,I   * STATUS ERROR BIT 13 
CH27  CLF CH
CH28  SFC CH        FLAG SHOULD STAY CLEAR
E43   JSB ERROR,I   * FLAG SHOULD BE CLEAR
      SPC 2 
TST5  LDA CW5       140450  RESET SA
      JSB OTACH 
      JSB DELAY,I 
      JSB LIACH 
      AND BP1 
      CPA BT13      CF,SA,BB = 0; TEST = 1? 
      JMP CH29      YES 
      STA SAVA      NO, REPORT ERROR
      LDB BT13
      STB SAVB
      LDB MSG44 
      JSB DATAI,I 
      LDA E45 
      JSB BRAI,I    RTN *+2 IF NO TTP SELECTED
E44   JSB ERROR,I   * STATUS ERROR
CH29  CLF CH
CH30  SFS CH        CF SHOULD HOLD FLAG SET 
E50   JSB ERROR,I   * FLAG SHOULD BE SET
      SPC 2 
TST6  LDA CW1       140010
      JSB OTACH     DISABLE STATUS LINE FLAGS 
CH31  CLF CH
CH32  SFC CH        FLAGS SHOULD STAY CLEAR 
E51   JSB ERROR,I   * FLAG SET
      SPC 3 
      JSB SWAI,I    CONTINUE AUTOMATIC? 
      JMP EFCT      YES 
      JSB TTSKI,I   NO
      LDA LM52
      LDB MI52
      JSB TTY.O,I 
H52   HLT 52B       END FCTST 
EFCT  JSB SWBI,I    RECYCLE TEST? 
      JMP FCTST     YES 
      JMP RECVP     NO, EXIT
      HED RECVP - RECEIVE PATTERN - RECEIVE INTERFACE DIAGNOSTIC
RECVP NOP 
      LDA CW1       MASTER CLEAR - 140010 
      JSB OTACH 
      JSB DELAY,I 
      SPC 2 
      LDA CW6       NO PARITY RECEIVE - 140020
      JSB INP 
RECNP JSB RCV       RECEIVE ALL PATTERNS
      JSB SETNP       FOR 8 BITS
      LDA MN9         OF DATA 
      ADA CHCNT 
      SZA 
      JMP RECNP 
      SPC 2 
      LDA CW7       ODD PARITY RECEIVE - 146020 
      JSB IOP 
RECOP JSB RCV       RECEIVE ALL PATTERNS
      JSB SETOP       FOR 7 BITS
      LDA MN8         OF DATA 
      ADA CHCNT 
      SZA 
      JMP RECOP 
      SPC 2 
      LDA CW8       EVEN PARITY RECEIVE - 144020
      JSB IEP 
RECEP JSB RCV       RECEIVE ALL PATTERNS
      JSB SETEP       FOR 7 BITS
      LDA MN8         OF DATA 
      ADA CHCNT 
      SZA 
      JMP RECEP 
      SPC 2 
      JSB SWAI,I    CONTINUE AUTO?
      JMP ESEND     YES 
      JSB TTSKI,I   NO
      LDA LM70
      LDB MI70
      JSB TTY.O,I   LIST
H70   HLT 70B       END RECVP 
ESEND JSB SWBI,I    RECYCLE TEST? 
      JMP RECVP     YES 
      JMP SPCHR     NO, EXIT
      SKP 
RCV   NOP 
      JSB PRTY      READY DATA OUT
      JSB SEND      SEND DATA OUT AND 
      JSB LIACH       RETURN IT HERE
      STA TEMPA 
      AND A0377 
      CPA WD1       DATA COMPARE OK?
      JMP CHSTT     YES 
      STA SAVE      NO, REPORT ERROR
      LDB MG53D     WORD RECEIVED 
      JSB DATAI,I 
      LDA WD1 
      STA SAVD
                                                                                                                                                          