ASMB,A,B,L,C
* REV. A 75164 -TLD-
* 
* 
* SOURCE 09611-18012
* ABSOLT 09611-16012
* 
* 
*       * * *  RTEC PATCH  * * *
* 
* THIS OVERLAY MAKES RTE-C SELF CONFIGURING FOR SYSTEM TTY AND TBG
*  THIS PATCH RETRIEVES FROM THE SWITCH REGISTER
*  THE SELECT CODE OF THE TELETYPE (BITS 0 THRU 5)
*  AND THE SELECT CODE OF THE TBG (BITS 6 THRU 11). 
*  THE TBG SELECT CODE IS PUT IN LOCATION 1674. 
*  THE TELETYPE SELECT CODE IS PUT IN EQT 1.
* 
* 
      ORG 2 
      JMP TBG,I     JUMP TO OVERLAY 
* 
      ORG 1674B 
      DEF START     ADDR OF OVERLAY FOR JUMP
* 
      ORG 37600B
START EQU * 
      LIB SWREG     GET SELECT CODES IN SWR 
      SZB,RSS       = 0 IS ERROR
      JMP BADSC 
      LDA B 
      AND M7700      PICK OFF THE TBG CHANNEL,
      ALF,ALF        AND STORE IT IN
      RAL,RAL        RTE'S BASE PAGE
      JSB SCCHK     CHECK SELECT CODE 
      STA TBG        COMMUNICATION AREA.
      LDA B 
      AND M77        PICK OFF THE TTY'S SELECT CODE.
      JSB SCCHK     CHECK SELECT CODE 
      CPA TBG       CHECK FOR TTY = TBG 
      JMP BADSC     = MUST BE ERROR 
      STA TTYSC 
      LDB INTBA      STORE THE ADDRESS
      ADB A          OF THE TELETYPE EQT
      ADB MIN6       IN THE INTERRUPT 
      LDA EQTA       TABLE. 
      STA B,I 
      ADA .3
      STA EQT4
      LDA A,I        MERGE THE TELETYPE 
      AND M1777      SELECT CODE INTO 
      IOR TTYSC      THE 4TH ENTRY OF THE 
      STA EQT4,I     TELETYPE EQT (EQT 1).
      JMP L3,I       START UP RTEC. 
BADSC EQU * 
      CCB 
      OTB 1         SET SWR ALL 1'S ON ERROR
      HLT 
      JMP START     RETRY 
SCCHK NOP           CHECK FOR SC > 7
      STA TEMP      SAVE SC 
      ADA DM8       IF SC 
      SSA            < 10(8)
      JMP BADSC     THEN ERROR
      LDA TEMP      RESTORE SC
      JMP SCCHK,I   RETURN
* 
SWREG EQU 1 
A     EQU 0 
B     EQU 1 
TBG   EQU 1674B 
INTBA EQU 1654B 
EQTA  EQU 1650B 
L3    EQU 3 
TEMP  NOP 
DM8   DEC -8
TTYSC NOP 
EQT4  NOP 
M7700 OCT 7700
M77   OCT 77
M1777 OCT 177700
MIN6  OCT -6
.3    OCT 3 
      END 
                                                                                                                                                                              