100  REM RELAY REGISTER TEST
110  REM
120  REM      SOURCE:  09601-18007 REV.B
130  REM      ERS:     A-09601-18007-1
140  REM
150  REM      AUTHOR - W.M.PARRISH       8 74 
160  REM      VERSION - 10 NOV 75  C.LEHNER 
170  REM
200  PRINT
210  PRINT "RELAY REGISTER RTE-B VERIFICATION TEST" 
220  PRINT
230  PRINT "FUNCTIONS:" 
240  PRINT "   1)  CHANGE STATUS OF A SINGLE BIT" 
250  PRINT "   2)  OUTPUT BCD WORD" 
251  PRINT "   3)  OUTPUT ALL ZEROS (RELAYS OPEN)"
252  PRINT "   4)  OUTPUT ALL 1'S   (RELAYS CLOSED)"
253  PRINT "   5)  BCD READBACK (READBACK CARDS ONLY)"
254  PRINT "   6)  NEW UNIT NUMBER" 
255  PRINT "  ANYTHING ELSE STOPS THE PROGRAM"
260  PRINT
270  PRINT "IF THIS CARD IS NOT CONFIGURED FOR FREE-RUN OUTPUT" 
280  PRINT "THEN THIS PROGRAM WILL HAVE TO BE ABORTED AND RESTARTED"
290  PRINT "AFTER EACH OUTPUT OPERATION.  (OR 12V APPLIED BETWEEN"
295  PRINT "PINS V AND 18 TO SET FLAG.)  TO AVOID GETTING THE"
300  PRINT "INSTRUCTIONS ON SUBSEQUENT OUTPUT OPERATIONS, TYPE "
310  PRINT " 5 GOTO 360 AFTER ABORTING THE PROGRAM FIRST TIME." 
320  PRINT
360  PRINT "UNIT NUMBER"; 
370  INPUT U
380  IF U=0 THEN 470
400  PRINT "FUNCTION";
410  INPUT F
420  IF F=1 THEN 1000 
430  IF F=2 THEN 2000 
440  IF F=3 THEN 3000 
450  IF F=4 THEN 4000 
460  IF F=5 THEN 5000 
470  IF F=6 THEN 360
480  PRINT
482  PRINT "END OF TEST"
484  PRINT
486  STOP 
1000  PRINT "SINGLE-BIT TEST" 
1010  PRINT "BIT #";
1020  INPUT B 
1030  PRINT "1=ON,0=OFF"; 
1040  INPUT S 
1050  GPRSB(U,1,B,S)
1060  GOTO 400
2000  PRINT "BCD OUTPUT"
2010  PRINT "NUMBER TO BE OUTPUT (0-9999)"; 
2020  INPUT N 
2030  GPRMB(U,3,N)
2040  GOTO 400
3000  PRINT "ALL 0'S OUT" 
3010  GPRMB(U,1,0)
3020  GOTO 400
4000  PRINT "ALL 1'S OUT" 
4010  ISETC("177777",Z) 
4020  GPRMB(U,1,Z)
4030  GOTO 400
5000  PRINT "BCD OUTPUT / INPUT"
5010  PRINT "NUMBER OUT (0-9999)";
5020  INPUT N 
5030  PRINT "APPLY 12V BETWEEN PINS V AND 18 TO SET FLAG" 
5040  GPRIO(U,3,N,M)
5050  PRINT "NUMBER IN = ";M
5060  GOTO 400
                                                                                                                                                                                                                                                            